[gentoo-commits] repo/gentoo:master commit in: sci-libs/orocos-bfl/

[David Seifert]

commit:     5ff80052f3b98b6e9ab08ddf4c1d11238a2187fc
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 27 22:44:31 2022 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Feb 27 22:44:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5ff80052

sci-libs/orocos-bfl: [QA] port to cmake.eclass

Closes: https://bugs.gentoo.org/770592
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-libs/orocos-bfl/orocos-bfl-0.8.0.ebuild | 43 +++++++++++++++--------------
 1 file changed, 22 insertions(+), 21 deletions(-)

diff --git a/sci-libs/orocos-bfl/orocos-bfl-0.8.0.ebuild b/sci-libs/orocos-bfl/orocos-bfl-0.8.0.ebuild
index bc79a85db067..ad5ae2e60d63 100644
--- a/sci-libs/orocos-bfl/orocos-bfl-0.8.0.ebuild
+++ b/sci-libs/orocos-bfl/orocos-bfl-0.8.0.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=8
 
-inherit cmake-utils
+inherit cmake
 
 DESCRIPTION="Bayesian Filtering Library"
 HOMEPAGE="https://orocos.org/bfl"
@@ -12,54 +12,55 @@ SRC_URI="https://people.mech.kuleuven.be/~tdelaet/bfl_tar/${P}-src.tar.bz2"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS="~amd64 ~arm"
-IUSE="doc examples static-libs test"
+IUSE="doc test"
 RESTRICT="!test? ( test )"
 
 RDEPEND="dev-libs/boost:="
 DEPEND="${RDEPEND}
+	test? ( dev-util/cppunit )"
+BDEPEND="
 	virtual/pkgconfig
 	doc? (
 		app-doc/doxygen
 		virtual/latex-base
-	)
-	test? ( dev-util/cppunit )"
+	)"
 
 src_prepare() {
-	cmake-utils_src_prepare
+	cmake_src_prepare
 
 	sed -e 's:/lib:/${CMAKE_INSTALL_LIBDIR}:' \
-		-i "${S}/"{,src/,src/bindings/rtt/}CMakeLists.txt || die
+		-i {,src/,src/bindings/rtt/}CMakeLists.txt || die
 }
 
 src_configure() {
 	local mycmakeargs=(
-		"-DLIBRARY_TYPE=$(usex static-libs both shared)"
-		"-DBUILD_EXAMPLES=$(usex examples ON OFF)"
-		"-DBUILD_TESTS=$(usex test ON OFF)"
+		-DLIBRARY_TYPE=shared
+		# installs test binaries
+		-DBUILD_EXAMPLES=NO
+		-DBUILD_TESTS=$(usex test)
 	)
-	cmake-utils_src_configure
+	cmake_src_configure
 }
 
 src_compile() {
-	cmake-utils_src_compile
+	cmake_src_compile
+
 	if use doc ; then
-		cd "${BUILD_DIR}"
+		cd "${BUILD_DIR}" || die
 		doxygen || die
 		cd "${S}/docs" || die
 		pdflatex getting_started_guide || die
 		pdflatex getting_started_guide || die
+
+		HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
 	fi
 }
 
 src_test() {
-	cd "${BUILD_DIR}"
-	emake check
+	cmake_build check
 }
 
 src_install() {
-	cmake-utils_src_install
-	if use doc ; then
-		dohtml -r "${BUILD_DIR}/doc/html/"
-		dodoc "${S}/docs/getting_started_guide.pdf"
-	fi
+	cmake_src_install
+	use doc && dodoc docs/getting_started_guide.pdf
 }