[gentoo-commits] gentoo-x86 commit in media-sound/guayadeque: guayadeque-0.3.6_pre1887.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        13/12/28 22:29:09

  Modified:             ChangeLog
  Added:                guayadeque-0.3.6_pre1887.ebuild
  Log:
  media-sound/guayadeque: Version Bump; unbundle wxsqlite; handle (optional) gstreamer support, #482012
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.22                 media-sound/guayadeque/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/guayadeque/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/guayadeque/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/guayadeque/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/guayadeque/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	18 Jul 2013 06:11:38 -0000	1.21
+++ ChangeLog	28 Dec 2013 22:29:09 -0000	1.22
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/guayadeque
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/guayadeque/ChangeLog,v 1.21 2013/07/18 06:11:38 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/guayadeque/ChangeLog,v 1.22 2013/12/28 22:29:09 jlec Exp $
+
+*guayadeque-0.3.6_pre1887 (28 Dec 2013)
+
+  28 Dec 2013; Justin Lecher <jlec@g.o>
+  +guayadeque-0.3.6_pre1887.ebuild,
+  +files/guayadeque-0.3.6_pre1887-underlinking.patch:
+  Version Bump; unbundle wxsqlite; handle (optional) gstreamer support, #482012
 
   18 Jul 2013; Justin Lecher <jlec@g.o> guayadeque-0.3.5.ebuild,
   metadata.xml:



1.1                  media-sound/guayadeque/guayadeque-0.3.6_pre1887.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/guayadeque/guayadeque-0.3.6_pre1887.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/guayadeque/guayadeque-0.3.6_pre1887.ebuild?rev=1.1&content-type=text/plain

Index: guayadeque-0.3.6_pre1887.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/guayadeque/guayadeque-0.3.6_pre1887.ebuild,v 1.1 2013/12/28 22:29:09 jlec Exp $

EAPI=5

WX_GTK_VER="2.8"

inherit cmake-utils eutils wxwidgets

DESCRIPTION="Music management program designed for all music enthusiasts"
HOMEPAGE="http://guayadeque.org/"
#SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
SRC_URI="http://sourceforge.net/code-snapshots/svn/g/gu/guayadeque/code/guayadeque-code-1887.zip -> ${P}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ayatana ipod +minimal"

# No test available, Making src_test fail
RESTRICT="test"

# Missing
# gstreamer0.10-fluendo-mp3 #120237
# gstreamer0.10-plugins-bad-multiverse ??
# gstreamer0.10-plugins-base-apps ??

GST_VERSION=0.10
GST_DEPS="
	dev-perl/GStreamer
	media-libs/gnonlin:${GST_VERSION}
	media-plugins/gst-plugins-alsa:${GST_VERSION}
	media-plugins/gst-plugins-ffmpeg:${GST_VERSION}
	media-plugins/gst-plugins-gio:${GST_VERSION}
	media-plugins/gst-plugins-gnomevfs:${GST_VERSION}
	media-plugins/gst-plugins-libnice:${GST_VERSION}
	media-plugins/gst-plugins-pulse:${GST_VERSION}
	media-plugins/gst-plugins-soup:${GST_VERSION}
	media-plugins/gst-plugins-x:${GST_VERSION}
	media-libs/gst-plugins-bad:${GST_VERSION}
	media-libs/gst-plugins-base:${GST_VERSION}
	media-libs/gst-plugins-good:${GST_VERSION}
	media-libs/gst-plugins-ugly:${GST_VERSION}
"

RDEPEND="${GST_DEPS}
	dev-db/sqlite:3
	dev-db/wxsqlite3
	dev-libs/glib:2
	media-libs/flac
	media-libs/gstreamer:${GST_VERSION}[introspection]
	>=media-libs/taglib-1.6.4
	net-misc/curl
	sys-apps/dbus
	x11-libs/wxGTK:2.8[X]
	ayatana? ( >=dev-libs/libindicate-0.7 )
	ipod? ( media-libs/libgpod )
	!minimal? ( ${GST_DEPS} )"
DEPEND="${RDEPEND}
	app-arch/unzip
	sys-devel/gettext
	virtual/pkgconfig"

# echo $(cat po/CMakeLists.txt | grep ADD_SUBDIRECTORY | sed 's#ADD_SUBDIRECTORY( \(\w\+\) )#\1#')
LANGS="es uk it de fr is nb th cs ru hu sv nl pt_BR pt el sk pl tr ja sr bg ca_ES hr"
for l in ${LANGS}; do
	IUSE="$IUSE linguas_${l}"
done

S="${WORKDIR}"/guayadeque-code-1887/Trunk

PATCHES=( "${FILESDIR}"/${P}-underlinking.patch )

src_prepare() {
	for l in ${LANGS} ; do
		if ! use linguas_${l} ; then
			sed \
				-e "/${l}/d" \
				-i po/CMakeLists.txt || die
		fi
	done

	if ! use ipod; then
		sed \
			-e '/PKG_CHECK_MODULES( LIBGPOD/,/^ENDIF/d' \
			-i CMakeLists.txt || die
	fi

	if ! use ayatana; then
		sed \
			-e '/PKG_CHECK_MODULES( LIBINDICATE/,/^ENDIF/d' \
			-i CMakeLists.txt || die
	fi

	rm -rf src/wx/wxsql* src/wxsqlite3 || die

	cmake-utils_src_prepare

	# otherwise cmake checks for svn
	esvn_clean

	sed 's:-O2::g' -i CMakeLists.txt || die

	sed \
		-e '/Encoding/d' \
		-i guayadeque.desktop || die
}

pkg_postinst() {
	local pkg
	if use minimal; then
		elog "If you are missing functionalities consider setting USE=-minimal"
		elog "or install any of the following packages:"
		for pkg in ${GST_DEPS}; do
			elog "\t ${pkg}"
		done
	fi
}