[gentoo-commits] gentoo-x86 commit in net-analyzer/pmacct: pmacct-0.12.1.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         10/05/11 05:24:03

  Modified:             ChangeLog
  Added:                pmacct-0.12.1.ebuild
  Log:
  Version bump thanks to Marcin Mirosław (bug #318843).
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.65                 net-analyzer/pmacct/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	1 Mar 2010 23:39:16 -0000	1.64
+++ ChangeLog	11 May 2010 05:24:03 -0000	1.65
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/pmacct
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/ChangeLog,v 1.64 2010/03/01 23:39:16 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/ChangeLog,v 1.65 2010/05/11 05:24:03 jer Exp $
+
+*pmacct-0.12.1 (11 May 2010)
+
+  11 May 2010; Jeroen Roovers <jer@g.o> +pmacct-0.12.1.ebuild:
+  Version bump thanks to Marcin Mirosław (bug #318843).
 
 *pmacct-0.12.0-r1 (01 Mar 2010)
 



1.1                  net-analyzer/pmacct/pmacct-0.12.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/pmacct-0.12.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/pmacct/pmacct-0.12.1.ebuild?rev=1.1&content-type=text/plain

Index: pmacct-0.12.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/pmacct-0.12.1.ebuild,v 1.1 2010/05/11 05:24:03 jer Exp $

EAPI="2"

inherit eutils toolchain-funcs

DESCRIPTION="A network tool to gather ip traffic informations"
HOMEPAGE="http://www.pmacct.net/"
SRC_URI="http://www.pmacct.net/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="64bit debug ipv6 mysql postgres sqlite threads ulog"

RDEPEND="net-libs/libpcap
	mysql? ( virtual/mysql )
	postgres? ( virtual/postgresql-base )
	sqlite? ( =dev-db/sqlite-3* )"
DEPEND="${RDEPEND}"

src_prepare() {
	cp -av configure{,.org}
	cp -av configure.in{,.org}
	epatch "${FILESDIR}"/${PN}-0.12.0-gentoo.patch
}

src_configure() {
	tc-export CC
	econf \
		$(use_enable 64bit) \
		$(use_enable debug) \
		$(use_enable ipv6) \
		$(use_enable mysql) \
		$(use_enable postgres pgsql) \
		$(use_enable sqlite sqlite3) \
		$(use_enable threads) \
		$(use_enable ulog) \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc ChangeLog CONFIG-KEYS EXAMPLES FAQS KNOWN-BUGS README UPGRADE \
		docs/SIGNALS docs/PLUGINS docs/INTERNALS TODO TOOLS \
		|| die "dodoc failed"

	for dirname in examples sql; do
		docinto ${dirname}
		dodoc ${dirname}/* || die "dodoc ${dirname} failed"
	done

	newinitd "${FILESDIR}"/pmacctd-init.d pmacctd || die "newinitd failed"
	newconfd "${FILESDIR}"/pmacctd-conf.d pmacctd || die "newconfd failed"

	insinto /etc
	newins "${S}/examples/pmacctd-imt.conf.example" pmacctd.conf || \
		die "newins failed"
}