[gentoo-commits] gentoo-x86 commit in x11-wm/notion: notion-9999.ebuild metadata.xml ChangeLog Manifest

[Michael Weber (xmw)]

xmw         12/06/20 18:52:52

  Added:                notion-9999.ebuild metadata.xml ChangeLog Manifest
  Log:
  Initial import based on Hobbits work (bug 422481)
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  x11-wm/notion/notion-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/notion/notion-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/notion/notion-9999.ebuild?rev=1.1&content-type=text/plain

Index: notion-9999.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/notion/notion-9999.ebuild,v 1.1 2012/06/20 18:52:51 xmw Exp $

EAPI="4"

EGIT_REPO_URI="git://notion.git.sourceforge.net/gitroot/notion/notion"
EGIT_HAS_SUBMODULES="1"

inherit eutils git-2 toolchain-funcs

DESCRIPTION="Notion is a tiling, tabbed window manager for the X window system"
HOMEPAGE="http://notion.sourceforge.net"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS=""
IUSE="nls xinerama +xrandr"

RDEPEND="dev-lang/lua
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libXext
	nls? ( sys-devel/gettext )
	xinerama? ( x11-libs/libXinerama )
	xrandr? ( x11-libs/libXrandr )"

DEPEND="${RDEPEND}
		dev-util/pkgconfig"

src_prepare() {
	sed -e "/^CFLAGS=/s:=:+=:" \
		-e "/^CFLAGS/{s:-Os:: ; s:-g::}" \
		-e "/^LDFLAGS=/{s:=:+=: ; s:-Wl,--as-needed::}" \
		-e "/^CC=/s:=:?=:" \
		-e "s:^\(PREFIX=\).*$:\1${ROOT}usr:" \
		-e "s:^\(ETCDIR=\).*$:\1${ROOT}etc/notion:" \
		-e "s:^\(LIBDIR=\).*:\1\$(PREFIX)/$(get_libdir):" \
		-e "s:^\(DOCDIR=\).*:\1\$(PREFIX)/share/doc/${PF}:" \
		-e "s:^\(LUA_DIR=\).*$:\1\$(PREFIX)/usr:" \
		-e "s:^\(VARDIR=\).*$:\1${ROOT}var/cache/${PN}:" \
		-e "s:^\(X11_PREFIX=\).*:\1\$(PREFIX)/usr:" \
		-i system.mk || die
	sed -e "/_install:/,+3s:\(\$(BINDIR)\):\$(DESTDIR)\1:" \
		-i mod_notionflux/notionflux/Makefile || die
	export STRIPPROG=cat

	use nls || export DEFINES=" -DCF_NO_LOCALE -DCF_NO_GETTEXT"

	if ! use xinerama ; then
		sed -e 's/mod_xinerama//g' -i modulelist.mk || die
	fi

	if ! use xrandr ; then
		sed -e 's/mod_xrandr//g' -i modulelist.mk || die
	fi

	tc-export CC
}

src_install() {
	emake DESTDIR="${D}" install

	exeinto /etc/X11/Sessions
	doexe "${FILESDIR}"/notion
	
	insinto /usr/share/xsessions
	doins "${FILESDIR}"/notion.desktop
}

pkg_postinst() {
	elog "If you want notion to have an ability to view a file based on its"
	elog "guessed MIME type you need 'run-mailcap' program in your system."
}



1.1                  x11-wm/notion/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/notion/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/notion/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>proxy-maintainers</herd>
<maintainer>
	<email>little_hobbit@×××××××.com</email>
</maintainer>
<maintainer>
	<email>xmw@g.o</email>
	<name>Michael Weber</name>
	<description>Proxy maintainer</description>
</maintainer>
<use>
	<flag name="xrandr">Add support for xrandr</flag>
</use>
</pkgmetadata>



1.1                  x11-wm/notion/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/notion/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/notion/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for x11-wm/notion
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/notion/ChangeLog,v 1.1 2012/06/20 18:52:51 xmw Exp $

*notion-9999 (20 Jun 2012)

  20 Jun 2012; Michael Weber <xmw@g.o> +notion-9999.ebuild,
  +files/notion, +files/notion.desktop, +metadata.xml:
  Initial import based on Hobbits work (bug 422481)




1.1                  x11-wm/notion/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/notion/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/notion/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
AUX notion 26 RMD160 1f8bcf9b6f3bb95de7dba24b5a027229be309422 SHA1 465c3c47149133067b1b03741d611f94b7a9dea7 SHA256 70ff05ede1d85ff4bf8d5100aa7ace3bb89ac09596543c6829fb1f65fddb546c
AUX notion.desktop 223 RMD160 71ac6451675586c6fc9c8213893684e71dbcc9d1 SHA1 d1b4cc5a5d644dbeff891afff32d2e7855d6c37c SHA256 4581319c329385f0bc5c18fe0037a4820ab1650a3af7ffe403a87e7fe5bf0987
EBUILD notion-9999.ebuild 1905 RMD160 59d127f24dca99d72fbf70cbcd95d5272cc73e39 SHA1 10ca14ddcdf8010bc414f98e9ee9c14fe707c3f5 SHA256 f65f4019c99bd41f01c0bc022788813d9d8547170a38abee60467127f42a109d
MISC ChangeLog 317 RMD160 9bc0cd01fc4df7d0f63ee97eac010f92eef3af4c SHA1 c2c21ec0218814938e2f400b913d7427a80df20c SHA256 02bbfccd19e39fb380c66a4b5f2e6efe1dd0fd30d86a28cef433044e5ec5693d
MISC metadata.xml 434 RMD160 99e646d4f23f32a60d340a928775267e58bbb174 SHA1 5086b5d722e2f7236b3fa97834c3b04c5fccaf18 SHA256 32b95389735b11aedde8ebee47b81131b101922e926c8eface1b4f70057f53c9