[gentoo-commits] gentoo-x86 commit in media-gfx/k3d: metadata.xml ChangeLog k3d-0.7.11.0.ebuild

[Markus Meier (maekke)]

maekke      09/03/23 22:58:33

  Modified:             metadata.xml ChangeLog
  Added:                k3d-0.7.11.0.ebuild
  Log:
  version bump by Ryoichiro Suzuki in bug #263245
  (Portage version: 2.2_rc26/cvs/Linux i686)

Revision  Changes    Path
1.3                  media-gfx/k3d/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/k3d/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/k3d/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/k3d/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/k3d/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	22 Aug 2008 22:17:33 -0000	1.2
+++ metadata.xml	23 Mar 2009 22:58:33 -0000	1.3
@@ -3,8 +3,11 @@
 <pkgmetadata>
 <herd>graphics</herd>
 <use>
-	<flag name='plib'>
-		build plib-based import/export library
-	</flag>
+	<flag name='3ds'>Enable support for 3D Studio models</flag>
+	<flag name='cuda'>Use nvidia cuda toolkit for speeding up
+	computations</flag>
+	<flag name='gts'>Add Support for the GNU Triangulated Surface Library
+	<pkg>sci-libs/gts</pkg></flag>
+	<flag name='plib'>build plib-based import/export library</flag>
 </use>
 </pkgmetadata>



1.42                 media-gfx/k3d/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/k3d/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/k3d/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/k3d/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/k3d/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	15 Mar 2009 16:00:00 -0000	1.41
+++ ChangeLog	23 Mar 2009 22:58:33 -0000	1.42
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/k3d
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/k3d/ChangeLog,v 1.41 2009/03/15 16:00:00 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/k3d/ChangeLog,v 1.42 2009/03/23 22:58:33 maekke Exp $
+
+*k3d-0.7.11.0 (23 Mar 2009)
+
+  23 Mar 2009; Markus Meier <maekke@g.o>
+  +files/k3d-0.7.11.0-fix-potfiles.patch, metadata.xml,
+  +k3d-0.7.11.0.ebuild:
+  version bump by Ryoichiro Suzuki in bug #263245
 
   15 Mar 2009; Markus Meier <maekke@g.o> k3d-0.6.7.0-r1.ebuild:
   drop librsvg dep, only needed if you call "make icons" wrt bug #258065



1.1                  media-gfx/k3d/k3d-0.7.11.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/k3d/k3d-0.7.11.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/k3d/k3d-0.7.11.0.ebuild?rev=1.1&content-type=text/plain

Index: k3d-0.7.11.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/k3d/k3d-0.7.11.0.ebuild,v 1.1 2009/03/23 22:58:33 maekke Exp $

EAPI="2"

inherit eutils cmake-utils

MY_P="${PN}-source-${PV}"

DESCRIPTION="A free 3D modeling, animation, and rendering system"
HOMEPAGE="http://www.k-3d.org/"
SRC_URI="mirror://sourceforge/k3d/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="3ds cuda gnome graphviz gts imagemagick jpeg nls openexr png python tiff truetype" #TODO cgal tbb

RDEPEND="
	dev-libs/boost
	>=dev-cpp/glibmm-2.6
	>=dev-cpp/gtkmm-2.6
	dev-libs/expat
	>=dev-libs/libsigc++-2.2
	media-libs/mesa
	virtual/glu
	virtual/opengl
	>=x11-libs/gtkglext-1.0.6-r3
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libXmu
	x11-libs/libXt
	3ds? ( media-libs/lib3ds )
	gnome? ( gnome-base/libgnome )
	graphviz? ( media-gfx/graphviz )
	gts? ( sci-libs/gts )
	imagemagick? ( media-gfx/imagemagick )
	jpeg? ( media-libs/jpeg )
	openexr? ( media-libs/openexr )
	png? ( media-libs/libpng )
	python? ( >=dev-lang/python-2.3 dev-python/cgkit )
	tiff? ( media-libs/tiff )
	truetype? ( >=media-libs/freetype-2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S="${WORKDIR}/${MY_P}"

DOCS="AUTHORS README"

# k3d_use_enable()
#
# $1: use flag. ON|OFF is determined by this.
# $2: part of cmake variable name which appended to the base variable name
#     that is -DK3D_BUILD_$2
#
# e.g.) k3d_use_enable gnome GNOME_MODULE #=> -DK3D_BUILD_GNOME_MODULE=ON
#
k3d_use_enable() {
	echo "-DK3D_BUILD_$2=$(use $1 && echo ON || echo OFF)"
}

k3d_use_module() {
	echo "-DK3D_BUILD_$2_MODULE=$(use $1 && echo ON || echo OFF)"
}

src_prepare() {
	epatch "${FILESDIR}/${P}-fix-potfiles.patch" || die "epatch failed"
	[[ -f CMakeCache.txt ]] && rm CMakeCache.txt
}

src_configure() {
	mycmakeargs="
		-DK3D_BUILD_SVG_IO_MODULE=ON
		-DK3D_BUILD_CGAL_MODULE=OFF
		$(k3d_use_module 3ds 3DS_IO)
		$(k3d_use_module cuda CUDA)
		$(k3d_use_module gnome GNOME)
		$(k3d_use_module graphviz GRAPHVIZ)
		$(k3d_use_module gts GTS)
		$(k3d_use_module gts GTS_IO)
		$(k3d_use_module imagemagick IMAGEMAGICK_IO)
		$(k3d_use_module jpeg JPEG_IO)
		$(k3d_use_enable nls NLS)
		$(k3d_use_module openexr OPENEXR_IO)
		$(k3d_use_module png PNG_IO)
		$(k3d_use_module python PYTHON)
		$(k3d_use_module python PYUI)
		$(k3d_use_module tiff TIFF_IO)
		$(k3d_use_module truetype FREETYPE2)"

	cmake-utils_src_configure
}