[gentoo-commits] gentoo-x86 commit in dev-python/pyro: pyro-4.14.ebuild ChangeLog

[Amadeusz Zolnowski (aidecoe)]

aidecoe     12/06/01 13:16:04

  Modified:             ChangeLog
  Added:                pyro-4.14.ebuild
  Log:
  Version bump wrt bug #416809.
  
  This version comes with several bug fixes and one workaround for threadpool
  scaling problem.  I have restricted the test for this version because it fails
  anyway because of the latest problem which is not fully solved:
  
    FAIL: testPoolGrowth (PyroTests.test_threadpool.ThreadpoolTests)
  
  (Portage version: 2.1.10.63/cvs/Linux x86_64)

Revision  Changes    Path
1.68                 dev-python/pyro/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyro/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyro/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyro/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pyro/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	1 Jun 2012 12:07:14 -0000	1.67
+++ ChangeLog	1 Jun 2012 13:16:04 -0000	1.68
@@ -1,6 +1,16 @@
 # ChangeLog for dev-python/pyro
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyro/ChangeLog,v 1.67 2012/06/01 12:07:14 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyro/ChangeLog,v 1.68 2012/06/01 13:16:04 aidecoe Exp $
+
+*pyro-4.14 (01 Jun 2012)
+
+  01 Jun 2012; Amadeusz Żołnowski <aidecoe@g.o> +pyro-4.14.ebuild,
+  pyro-4.11.ebuild:
+  Version bump wrt bug #416809.  This version comes with several bug fixes and
+  one workaround for threadpool scaling problem.  I have restricted the test for
+  this version because it fails anyway because of the latest problem which is
+  not fully solved:    FAIL: testPoolGrowth
+  (PyroTests.test_threadpool.ThreadpoolTests)
 
 *pyro-4.11 (01 Jun 2012)
 



1.1                  dev-python/pyro/pyro-4.14.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyro/pyro-4.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pyro/pyro-4.14.ebuild?rev=1.1&content-type=text/plain

Index: pyro-4.14.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pyro/pyro-4.14.ebuild,v 1.1 2012/06/01 13:16:04 aidecoe Exp $

EAPI="3"
PYTHON_DEPEND="*:2.6"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.[45]"

inherit distutils

MY_PN="Pyro4"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Advanced and powerful Distributed Object Technology system written entirely in Python"
HOMEPAGE="http://www.xs4all.nl/~irmen/pyro/ http://pypi.python.org/pypi/Pyro4"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="4"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples test"

RDEPEND="!dev-python/pyro:0"
DEPEND="${RDEPEND}
	dev-python/setuptools
	test? (
		dev-python/coverage
		dev-python/nose
	)"

S="${WORKDIR}/${MY_P}"

PYTHON_MODNAME="Pyro4"
RESTRICT="test"

src_prepare() {
	distutils_src_prepare

	sed -e '/sys.path.insert/a sys.path.insert(1,"PyroTests")' -i tests/run_suite.py

	# Disable tests requiring network connection.
	sed \
		-e "s/testBCstart/_&/" \
		-e "s/testDaemonPyroObj/_&/" \
		-e "s/testLookupAndRegister/_&/" \
		-e "s/testMulti/_&/" \
		-e "s/testRefuseDottedNames/_&/" \
		-e "s/testResolve/_&/" \
		-i tests/PyroTests/test_naming.py
	sed \
		-e "s/testOwnloopBasics/_&/" \
		-e "s/testStartNSfunc/_&/" \
		-i tests/PyroTests/test_naming2.py

	sed \
		-e "s/testServerConnections/_&/" \
	    -e "s/testServerParallelism/_&/" \
		-i tests/PyroTests/test_server.py

	sed \
		-e "s/testBroadcast/_&/" \
		-e "s/testGetIP/_&/" \
		-i tests/PyroTests/test_socket.py
}

src_test() {
	cd tests

	testing() {
		"$(PYTHON)" run_suite.py
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -r docs/* || die "Installation of documentation failed"
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples || die "Installation of examples failed"
	fi
}

pkg_postinst() {
	ewarn "A temporary workaround for a thread pool scaling problem (lock-up)"
	ewarn "is in effect: the thread pool is fixed at THREADPOOL_MINTHREADS"
	ewarn "threads.  THREADPOOL_MAXTHREADS can still be set but has no effect"
	ewarn "at the moment, until the thread pool implementation has been fixed."
}