[gentoo-commits] gentoo-x86 commit in net-libs/libproxy: libproxy-0.4.11-r2.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/06/08 07:46:55

  Modified:             ChangeLog
  Added:                libproxy-0.4.11-r2.ebuild
  Log:
  Enable multilib support, as dependency of net-libs/glib-networking.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.110                net-libs/libproxy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libproxy/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libproxy/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libproxy/ChangeLog?r1=1.109&r2=1.110

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libproxy/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog	22 Feb 2014 22:57:54 -0000	1.109
+++ ChangeLog	8 Jun 2014 07:46:55 -0000	1.110
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libproxy
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/ChangeLog,v 1.109 2014/02/22 22:57:54 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/ChangeLog,v 1.110 2014/06/08 07:46:55 mgorny Exp $
+
+*libproxy-0.4.11-r2 (08 Jun 2014)
+
+  08 Jun 2014; Michał Górny <mgorny@g.o> +libproxy-0.4.11-r2.ebuild:
+  Enable multilib support, as dependency of net-libs/glib-networking.
 
   22 Feb 2014; Pacho Ramos <pacho@g.o> libproxy-0.4.11-r1.ebuild:
   Fix wrong commit, bug 502160



1.1                  net-libs/libproxy/libproxy-0.4.11-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libproxy/libproxy-0.4.11-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libproxy/libproxy-0.4.11-r2.ebuild?rev=1.1&content-type=text/plain

Index: libproxy-0.4.11-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libproxy/libproxy-0.4.11-r2.ebuild,v 1.1 2014/06/08 07:46:55 mgorny Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )

inherit cmake-multilib eutils flag-o-matic mono python-r1

DESCRIPTION="Library for automatic proxy configuration management"
HOMEPAGE="http://code.google.com/p/libproxy/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="gnome kde mono networkmanager perl python spidermonkey test webkit"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

# NOTE: mozjs/spidermonkey might still cause problems like #373397 ?
# NOTE: webkit-gtk:3, not :2, needed for libjavascriptcoregtk support
RDEPEND="gnome? ( >=dev-libs/glib-2.26:2[${MULTILIB_USEDEP}] )
	kde? ( >=kde-base/kdelibs-4.4.5 )
	mono? ( dev-lang/mono )
	networkmanager? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
	perl? ( dev-lang/perl )
	python? ( ${PYTHON_DEPS} )
	spidermonkey? ( >=dev-lang/spidermonkey-1.8.5:0= )
	webkit? ( >=net-libs/webkit-gtk-1.6:3= )"
DEPEND="${RDEPEND}
	kde? ( dev-util/automoc )
	virtual/pkgconfig[${MULTILIB_USEDEP}]"
# avoid dependency loop, bug #467696
PDEPEND="networkmanager? ( net-misc/networkmanager )"

src_prepare() {
	# Gentoo's spidermonkey doesn't set Version: in mozjs18[57].pc
	epatch "${FILESDIR}/${P}-mozjs.pc.patch"

	# get-pac-test freezes when run by the ebuild, succeeds when building
	# manually; virtualx.eclass doesn't help :(
	epatch "${FILESDIR}/${PN}-0.4.10-disable-pac-test.patch"

	epatch "${FILESDIR}"/${P}-macosx.patch

	# prevent dependency loop with networkmanager, libsoup, glib-networking; bug #467696
	epatch "${FILESDIR}/${PN}-0.4.11-avoid-nm-build-dep.patch"
}

src_configure() {
	[[ ${CHOST} == *-solaris* ]] && append-libs -lsocket -lnsl

	use python && python_setup
	multilib-minimal_src_configure
}

multilib_src_configure() {
	# WITH_VALA just copies the .vapi file over and needs no deps,
	# hence always enable it unconditionally
	local mycmakeargs=(
			-DPERL_VENDORINSTALL=ON
			-DCMAKE_C_FLAGS="${CFLAGS}"
			-DCMAKE_CXX_FLAGS="${CXXFLAGS}"
			$(cmake-utils_use_with gnome GNOME3)
			$(multilib_is_native_abi && cmake-utils_use_with kde KDE4 \
				|| echo -DWITH_KDE4=OFF)
			$(multilib_is_native_abi && cmake-utils_use_with mono DOTNET \
				|| echo -DWITH_DOTNET=OFF)
			$(cmake-utils_use_with networkmanager NM)
			$(multilib_is_native_abi && cmake-utils_use_with perl PERL \
				|| echo -DWITH_PERL=OFF)
			$(multilib_is_native_abi && cmake-utils_use_with python PYTHON \
				|| echo -DWITH_PYTHON=OFF)
			$(multilib_is_native_abi && cmake-utils_use_with spidermonkey MOZJS \
				|| echo -DWITH_MOZJS=OFF)
			$(multilib_is_native_abi && cmake-utils_use_with webkit WEBKIT \
				|| echo -DWITH_WEBKIT=OFF)
			$(multilib_is_native_abi && cmake-utils_use_with webkit WEBKIT3 \
				|| echo -DWITH_WEBKIT3=OFF)
			-DWITH_VALA=ON
			$(cmake-utils_use test BUILD_TESTING)
	)
	cmake-utils_src_configure
}

multilib_src_install_all() {
	DOCS="AUTHORS ChangeLog NEWS README"
	einstalldocs

	if use python; then
		python_foreach_impl python_domodule bindings/python/libproxy.py || die
	fi
}