[gentoo-commits] gentoo-x86 commit in media-sound/hydrogen: ChangeLog hydrogen-0.9.4.ebuild hydrogen-0.9.4_rc2.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    09/12/27 10:56:34

  Modified:             ChangeLog
  Added:                hydrogen-0.9.4.ebuild
  Removed:              hydrogen-0.9.4_rc2.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.84                 media-sound/hydrogen/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/hydrogen/ChangeLog?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/hydrogen/ChangeLog?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/hydrogen/ChangeLog?r1=1.83&r2=1.84

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/hydrogen/ChangeLog,v
retrieving revision 1.83
retrieving revision 1.84
diff -u -r1.83 -r1.84
--- ChangeLog	27 Dec 2009 09:34:49 -0000	1.83
+++ ChangeLog	27 Dec 2009 10:56:34 -0000	1.84
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/hydrogen
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/hydrogen/ChangeLog,v 1.83 2009/12/27 09:34:49 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/hydrogen/ChangeLog,v 1.84 2009/12/27 10:56:34 ssuominen Exp $
+
+*hydrogen-0.9.4 (27 Dec 2009)
+
+  27 Dec 2009; Samuli Suominen <ssuominen@g.o>
+  +hydrogen-0.9.4.ebuild:
+  Version bump wrt #298360, thanks to Ben de Groot for reporting.
 
   27 Dec 2009; Joseph Jezak <josejx@g.o> hydrogen-0.9.3-r4.ebuild:
   Marked ppc stable for bug #281590.



1.1                  media-sound/hydrogen/hydrogen-0.9.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/hydrogen/hydrogen-0.9.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/hydrogen/hydrogen-0.9.4.ebuild?rev=1.1&content-type=text/plain

Index: hydrogen-0.9.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/hydrogen/hydrogen-0.9.4.ebuild,v 1.1 2009/12/27 10:56:34 ssuominen Exp $

EAPI=2
inherit eutils multilib

DESCRIPTION="Advanced drum machine"
HOMEPAGE="http://www.hydrogen-music.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2 ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="alsa flac jack ladspa lash oss"

RDEPEND="x11-libs/qt-gui:4
	app-arch/libarchive
	alsa? ( media-libs/alsa-lib )
	flac? ( media-libs/flac[cxx] )
	jack? ( media-sound/jack-audio-connection-kit )
	ladspa? ( media-libs/liblrdf )
	lash? ( media-sound/lash )"
DEPEND="${RDEPEND}
	dev-util/scons"

src_prepare() {
	sed -i \
		-e '/cppflags +=/d' \
			Sconstruct || die
}

src_compile() {
	export QTDIR="/usr/$(get_libdir)"

	local myconf="libarchive=1 portaudio=0 portmidi=0"

	use alsa || myconf="${myconf} alsa=0"
	use flac || myconf="${myconf} flac=0"
	use jack || myconf="${myconf} jack=0"
	use ladspa || myconf="${myconf} lrdf=0"
	use lash && myconf="${myconf} lash=1"
	use oss || myconf="${myconf} oss=0"

	scons \
		prefix=/usr \
		DESTDIR="${D}" \
		optflags="${CXXFLAGS}" \
		${myconf} || die
}

src_install() {
	dobin hydrogen || die
	insinto /usr/share/hydrogen
	doins -r data || die
	doicon data/img/gray/h2-icon.svg
	domenu hydrogen.desktop
	dosym /usr/share/hydrogen/data/doc /usr/share/doc/${PF}/html
	dodoc AUTHORS ChangeLog README.txt
}