[gentoo-commits] gentoo-x86 commit in media-video/avidemux: metadata.xml ChangeLog avidemux-2.4.4-r2.ebuild avidemux-2.5.1-r2.ebuild avidemux-2.5.1-r1.ebuild avidemux-2.5.0.ebuild

[Ben de Groot (yngwin)]

yngwin      09/09/30 14:40:11

  Modified:             metadata.xml ChangeLog avidemux-2.4.4-r2.ebuild
  Added:                avidemux-2.5.1-r2.ebuild
  Removed:              avidemux-2.5.1-r1.ebuild avidemux-2.5.0.ebuild
  Log:
  Remove old, except stable. Cleanup wrt amr. Specify x264 dep to fix bug 286801. Re-adding ~ppc keyword.
  (Portage version: 2.2_rc42/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 media-video/avidemux/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/metadata.xml?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/metadata.xml?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/metadata.xml?r1=1.9&r2=1.10

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/avidemux/metadata.xml,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- metadata.xml	24 Sep 2009 15:50:25 -0000	1.9
+++ metadata.xml	30 Sep 2009 14:40:11 -0000	1.10
@@ -7,8 +7,10 @@
     <name>Ben de Groot</name>
   </maintainer>
   <use>
-    <flag name="aften">Enable A/52 (AC-3) audio encoder support</flag>
-    <flag name="amrnb">Enable Narrow Band Adaptive Multi-Rate Audio support</flag>
-    <flag name="opencore-amr">Enable Band Adaptive Multi-Rate format support</flag>
+    <flag name='aften'>Enable A/52 (AC-3) audio encoder support</flag>
+    <flag name='amr'>Enable Adaptive Multi-Rate format support through
+      <pkg>media-libs/opencore-amr</pkg></flag>
+	<flag name='amrnb'>Enables Adaptive Multi-Rate Audio support (Narrow Band)
+      through <pkg>media-libs/amrnb</pkg></flag>
   </use>
 </pkgmetadata>



1.154                media-video/avidemux/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/ChangeLog?rev=1.154&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/ChangeLog?rev=1.154&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/ChangeLog?r1=1.153&r2=1.154

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v
retrieving revision 1.153
retrieving revision 1.154
diff -u -r1.153 -r1.154
--- ChangeLog	27 Sep 2009 10:27:02 -0000	1.153
+++ ChangeLog	30 Sep 2009 14:40:11 -0000	1.154
@@ -1,6 +1,14 @@
 # ChangeLog for media-video/avidemux
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.153 2009/09/27 10:27:02 ayoy Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.154 2009/09/30 14:40:11 yngwin Exp $
+
+*avidemux-2.5.1-r2 (30 Sep 2009)
+
+  30 Sep 2009; Ben de Groot <yngwin@g.o> avidemux-2.4.4-r2.ebuild,
+  -avidemux-2.5.0.ebuild, -avidemux-2.5.1-r1.ebuild,
+  +avidemux-2.5.1-r2.ebuild, metadata.xml:
+  Remove old, except stable. Cleanup wrt amr. Specify x264 dep to fix bug
+  286801. Re-adding ~ppc keyword.
 
   27 Sep 2009; Dominik Kapusta <ayoy@g.o> avidemux-2.5.0.ebuild,
   avidemux-2.5.1-r1.ebuild:



1.6                  media-video/avidemux/avidemux-2.4.4-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/avidemux-2.4.4-r2.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/avidemux-2.4.4-r2.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/avidemux-2.4.4-r2.ebuild?r1=1.5&r2=1.6

Index: avidemux-2.4.4-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.4.4-r2.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- avidemux-2.4.4-r2.ebuild	28 Jun 2009 12:18:43 -0000	1.5
+++ avidemux-2.4.4-r2.ebuild	30 Sep 2009 14:40:11 -0000	1.6
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.4.4-r2.ebuild,v 1.5 2009/06/28 12:18:43 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.4.4-r2.ebuild,v 1.6 2009/09/30 14:40:11 yngwin Exp $
 
 EAPI="2"
 
@@ -36,7 +36,7 @@
 	truetype? ( media-libs/freetype
 		media-libs/fontconfig )
 	vorbis? ( media-libs/libvorbis )
-	x264? ( media-libs/x264 )
+	x264? ( <media-libs/x264-0.0.20090908 )
 	xv? ( x11-libs/libXv )
 	xvid? ( media-libs/xvid )
 	gtk? ( x11-libs/gtk+:2 )



1.1                  media-video/avidemux/avidemux-2.5.1-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/avidemux-2.5.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/avidemux/avidemux-2.5.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: avidemux-2.5.1-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.5.1-r2.ebuild,v 1.1 2009/09/30 14:40:11 yngwin Exp $

EAPI="2"

inherit cmake-utils

MY_P=${PN}_${PV}

DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks"
HOMEPAGE="http://fixounet.free.fr/avidemux"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz
	mirror://gentoo/${P}-patches-1.tar.bz2"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="+aac +aften +alsa amr +dts esd jack libsamplerate +mp3 nls oss
	pulseaudio +sdl +truetype +vorbis +x264 +xv +xvid gtk +qt4"

RDEPEND="dev-libs/libxml2
	aac? ( media-libs/faac
		media-libs/faad2 )
	aften? ( media-libs/aften )
	alsa? ( media-libs/alsa-lib )
	amr? ( media-libs/opencore-amr )
	dts? ( media-libs/libdca )
	mp3? ( media-sound/lame )
	esd? ( media-sound/esound )
	jack? ( media-sound/jack-audio-connection-kit )
	libsamplerate? ( media-libs/libsamplerate )
	oss? ( media-libs/alsa-oss )
	pulseaudio? ( media-sound/pulseaudio )
	sdl? ( media-libs/libsdl )
	truetype? ( media-libs/freetype:2
		media-libs/fontconfig )
	vorbis? ( media-libs/libvorbis )
	x264? ( <media-libs/x264-0.0.20090908 )
	xv? ( x11-libs/libXv )
	xvid? ( media-libs/xvid )
	gtk? ( x11-libs/gtk+:2 )
	qt4? ( >=x11-libs/qt-gui-4.5.1:4 )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	dev-util/pkgconfig
	>=dev-util/cmake-2.6.4"

S=${WORKDIR}/${MY_P}

AVIDEMUX_LANGS="bg ca cs de el es fr it ja pt_BR ru sr sr@latin tr zh_TW"
for L in ${AVIDEMUX_LANGS}; do
	IUSE="${IUSE} linguas_${L}"
done

PATCHES=( "${WORKDIR}/patches/${PV}-i18n.patch"
	"${WORKDIR}/patches/${PV}-multilib.patch"
	"${WORKDIR}/patches/${PV}-coreImage-parallel-build.patch"
	# adds plugins as a build target and adjusts include paths
	"${WORKDIR}/patches/${PV}-build-plugins.patch" )

src_prepare() {
	base_src_prepare

	local po_files=
	local qt_ts_files=
	local avidemux_ts_files=
	for lingua in ${LINGUAS}; do
		if has ${lingua} ${AVIDEMUX_LANGS}; then
			if [[ -e ${S}/po/${lingua}.po ]]; then
				po_files="${po_files} \${po_subdir}/${lingua}.po"
			fi
			if [[ -e ${S}/po/qt_${lingua}.ts ]]; then
				qt_ts_files="${qt_ts_files} \${ts_subdir}/qt_${lingua}.ts"
			fi
			if [[ -e ${S}/po/${PN}_${lingua}.ts ]]; then
				avidemux_ts_files="${avidemux_ts_files} \${ts_subdir}/${PN}_${lingua}.ts"
			fi
		fi
	done

	sed -i -e "s!FILE(GLOB po_files .*)!SET(po_files ${po_files})!" \
		"${S}/cmake/Po.cmake" || die "sed failed"
	sed -i -e "s!FILE(GLOB.*qt.*)!SET(ts_files ${qt_ts_files})!" \
	    -e "s!FILE(GLOB.*avidemux.*)!SET(ts_files ${avidemux_ts_files})!" \
		"${S}/cmake/Ts.cmake" || die "sed failed"
}

src_configure() {
	mycmakeargs="${mycmakeargs}
		-DAVIDEMUX_SOURCE_DIR='${S}'
		-DAVIDEMUX_INSTALL_PREFIX='${S}_build'
		-DAVIDEMUX_CORECONFIG_DIR='${S}_build/config'"

	# CMakeLists.txt
	use gtk || mycmakeargs="${mycmakeargs} -DGTK=0"
	use qt4 || mycmakeargs="${mycmakeargs} -DQT4=0"

	# cmake/admCheckMiscLibs.cmake
	use nls || mycmakeargs="${mycmakeargs} -DGETTEXT=0"
	use sdl || mycmakeargs="${mycmakeargs} -DSDL=0"
	use xv || mycmakeargs="${mycmakeargs} -DXVIDEO=0"

	# cmake/admCheckAudioDeviceLibs.cmake
	use alsa || mycmakeargs="${mycmakeargs} -DALSA=0"
	use esd || mycmakeargs="${mycmakeargs} -DESD=0"
	use jack || mycmakeargs="${mycmakeargs} -DJACK=0"
	use oss || mycmakeargs="${mycmakeargs} -DOSS=0"
	use pulseaudio || mycmakeargs="${mycmakeargs} -DPULSEAUDIOSIMPLE=0"

	# cmake/admCheckAudioEncoderLibs.cmake
	use aften || mycmakeargs="${mycmakeargs} -DAFTEN=0"
	use mp3 || mycmakeargs="${mycmakeargs} -DLAME=0"
	use aac || mycmakeargs="${mycmakeargs} -DFAAC=0"
	use vorbis || mycmakeargs="${mycmakeargs} -DVORBIS=0"

	# plugins/ADM_audioDecoders
	use aac || mycmakeargs="${mycmakeargs} -DFAAD=0"
	use dts || mycmakeargs="${mycmakeargs} -DLIBDCA=0"

	# opencore
	use amr || mycmakeargs="${mycmakeargs} -DOPENCORE_AMRNB=0 -DOPENCORE_AMRWB=0"

	# plugins/ADM_videoFilters
	use truetype || mycmakeargs="${mycmakeargs} -DFREETYPE2=0 -DFONTCONFIG=0"

	# plugins/ADM_videoEncoder
	use xvid || mycmakeargs="${mycmakeargs} -DXVID=0"
	use x264 || mycmakeargs="${mycmakeargs} -DX264=0"

	cmake-utils_src_configure
}

src_compile() {
	# first build the application
	cmake-utils_src_compile
	# and then go on with plugins
	emake -C "${CMAKE_BUILD_DIR}/plugins" || die "building plugins failed"
}

src_install() {
	# install the application
	cmake-utils_src_install
	# install plugins
	emake -C "${CMAKE_BUILD_DIR}/plugins" DESTDIR="${D}" install \
		|| die "installing plugins failed"

	dodoc AUTHORS || die "dodoc failed"
	newicon ${PN}_icon.png ${PN}.png || die "installing icon failed"

	if use qt4; then
		sed -i "s/\(${PN}2_\)gtk/\1qt4/" ${PN}2.desktop || die "sed failed"
		domenu ${PN}2.desktop || die "installing desktop file failed"
	fi

	if use gtk; then
		domenu ${PN}2-gtk.desktop || die "installing desktop file failed"
	fi
}