[gentoo-commits] gentoo-x86 commit in media-sound/xwax: ChangeLog xwax-0.10_beta1.ebuild

[Joe Sapp (nixphoeni)]

nixphoeni    11/05/07 17:58:08

  Modified:             ChangeLog
  Added:                xwax-0.10_beta1.ebuild
  Log:
  Added new beta version
  
  (Portage version: 2.1.9.45/cvs/Linux x86_64)

Revision  Changes    Path
1.33                 media-sound/xwax/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/xwax/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	7 May 2011 17:52:41 -0000	1.32
+++ ChangeLog	7 May 2011 17:58:08 -0000	1.33
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/xwax
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/ChangeLog,v 1.32 2011/05/07 17:52:41 nixphoeni Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/ChangeLog,v 1.33 2011/05/07 17:58:08 nixphoeni Exp $
+
+*xwax-0.10_beta1 (07 May 2011)
+
+  07 May 2011; Joe Sapp <nixphoeni@g.o> +xwax-0.10_beta1.ebuild:
+  Added new beta version
 
   07 May 2011; Joe Sapp <nixphoeni@g.o> -xwax-0.7.ebuild:
   Removed old version



1.1                  media-sound/xwax/xwax-0.10_beta1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/xwax-0.10_beta1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/xwax-0.10_beta1.ebuild?rev=1.1&content-type=text/plain

Index: xwax-0.10_beta1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/xwax-0.10_beta1.ebuild,v 1.1 2011/05/07 17:58:08 nixphoeni Exp $

EAPI=4
inherit toolchain-funcs versionator

MY_PV="${PV/_/-}"
TYPE="$(version_format_string '$3')"

DESCRIPTION="Digital vinyl emulation software"
HOMEPAGE="http://www.xwax.co.uk/"
SRC_URI="http://www.xwax.co.uk/testing/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="testing"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="alsa jack oss cdda mp3 +fallback"
REQUIRED_USE="|| ( cdda mp3 fallback )
	|| ( alsa jack oss )"

RDEPEND="media-libs/libsdl
	media-libs/sdl-ttf
	media-fonts/dejavu
	alsa? ( media-libs/alsa-lib )
	jack? ( media-sound/jack-audio-connection-kit )
	cdda? ( media-sound/cdparanoia )
	mp3? ( || ( media-sound/mpg123 media-sound/mpg321 ) )
	fallback? ( virtual/ffmpeg )"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${PN}-${MY_PV}"

DOCS="README CHANGES"

pkg_setup() {
	ewarn "Please note that XWAX_DECODERS is deprecated in favor of USE flags."
	ewarn "Sorry for the inconvenience."
}

src_prepare() {
	# Remove the forced optimization from 'CFLAGS' and 'LDFLAGS' in
	# the Makefile
	# Also replace VERSION so we don't have to depend on git...
	sed -i -e 's:\(^CFLAGS.*\)-O[0-9]\(.*\):\1\2:' \
		-e 's:\(^LDFLAGS.*\)-O[0-9]\(.*\):\1\2:' \
		-e "s:\(^VERSION =\).*:\1 ${PV}:" \
		Makefile || die "sed failed"

	# Fix name for importer and scanner
	sed -i -e "s:\(xwax-import\):\1-${TYPE}:g" \
		-e "s:\(xwax-scan\):\1-${TYPE}:g" \
		xwax.c || die "patching xwax.c failed"

	# Replace any decoder commands in the import script, if necessary
	if [[ `use mp3` ]]; then
		# mpg123 is upstream's default
		if has_version media-sound/mpg123; then
			TO="mpg123"
			FROM="mpg321"
		# Otherwise, use mpg321
		else
			TO="mpg321"
			FROM="mpg123"
		fi
		debug-print "found ${TO}"
		sed -i -e "s:${FROM}:${TO}:g" import || \
			die "problem converting xwax-import to use ${TO}"
	fi
}

src_configure() {
	tc-export CC
	econf \
		--prefix "${EROOT}usr" \
		$(use_enable alsa) \
		$(use_enable jack) \
		$(use_enable oss)
}

src_compile() {
	# EXECDIR is the default directory in which xwax will look for
	# the 'xwax-import' and 'xwax-scan' scripts
	emake EXECDIR="${EROOT}usr/bin"
}

src_install() {
	# This is easier than setting all the environment variables
	# needed, running the sed script required to get the man directory
	# correct, and removing the GPL-2 after a 'make install' run
	newbin xwax xwax-${TYPE} || die "failed to install xwax"
	newbin import xwax-import-${TYPE} || die "failed to install xwax-import"
	newbin scan xwax-scan-${TYPE} || die "failed to install xwax-scan"
	newman xwax.1 xwax-${TYPE}.1 || die "failed to install man page"

	dodoc ${DOCS} || die "failed to install docs"
}

pkg_postinst() {
	ewarn "Note that this is a testing package and is probably unsuitable for"
	ewarn "live shows."
}