[gentoo-commits] gentoo-x86 commit in sci-chemistry/refmac: ChangeLog refmac-5.6.0097.ebuild

[Justin Lecher (jlec)]

jlec        11/01/04 08:55:21

  Modified:             ChangeLog
  Added:                refmac-5.6.0097.ebuild
  Log:
  Version Bump
  
  (Portage version: 2.2.0_alpha12/cvs/Linux x86_64)

Revision  Changes    Path
1.32                 sci-chemistry/refmac/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/refmac/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/refmac/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/refmac/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/refmac/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	31 Dec 2010 16:08:51 -0000	1.31
+++ ChangeLog	4 Jan 2011 08:55:21 -0000	1.32
@@ -1,6 +1,12 @@
 # ChangeLog for sci-chemistry/refmac
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/refmac/ChangeLog,v 1.31 2010/12/31 16:08:51 jlec Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/refmac/ChangeLog,v 1.32 2011/01/04 08:55:21 jlec Exp $
+
+*refmac-5.6.0097 (04 Jan 2011)
+
+  04 Jan 2011; Justin Lecher <jlec@g.o>
+  +files/5.6.0097-allow-dynamic-linking.patch, +refmac-5.6.0097.ebuild:
+  Version Bump
 
   31 Dec 2010; Justin Lecher <jlec@g.o> refmac-5.5.0110-r2.ebuild:
   Depend correct ccp4-libs version to make test work



1.1                  sci-chemistry/refmac/refmac-5.6.0097.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/refmac/refmac-5.6.0097.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/refmac/refmac-5.6.0097.ebuild?rev=1.1&content-type=text/plain

Index: refmac-5.6.0097.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/refmac/refmac-5.6.0097.ebuild,v 1.1 2011/01/04 08:55:21 jlec Exp $

EAPI="2"

inherit base toolchain-funcs versionator

MY_PV="$(get_version_component_range 1-2)_source_v${PV}"

DESCRIPTION="Macromolecular crystallographic refinement program"
HOMEPAGE="http://www.ysbl.york.ac.uk/~garib/refmac/"
SRC_URI="${HOMEPAGE}data/refmac_experimental/${PN}${MY_PV}.tar.gz
	test? ( http://dev.gentooexperimental.org/~jlec/distfiles/test-framework.tar.gz )"

SLOT="0"
LICENSE="ccp4"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="test"

RDEPEND="
	sci-libs/ccp4-libs
	sci-libs/mmdb
	>sci-libs/monomer-db-1
	virtual/blas
	virtual/lapack"
DEPEND="${RDEPEND}"

S="${WORKDIR}"

PATCHES=(
	"${FILESDIR}"/${PV}-allow-dynamic-linking.patch
	)

src_prepare() {
	base_src_prepare
	use test && epatch "${FILESDIR}"/5.5-test.log.patch
}

src_compile() {
	emake \
		FC=$(tc-getFC) \
		CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		COPTIM="${CFLAGS}" \
		FOPTIM="${FFLAGS:- -O2}" \
		VERSION="" \
		XFFLAGS="-fno-second-underscore" \
		LLIBCCP="-lccp4f -lccp4c -lccif -lmmdb -lstdc++" \
		LLIBLAPACK="$(pkg-config --libs lapack blas)" \
		|| die
}

src_test() {
	einfo "Starting tests ..."
	export PATH="${WORKDIR}/test-framework/scripts:${S}:${PATH}"
	export CCP4_TEST="${WORKDIR}"/test-framework
	export CCP4_SCR="${T}"
	ln -sf refmac "${S}"/refmac5
	sed '/^ANISOU/d' -i ${CCP4_TEST}/data/pdb/1vr7.pdb
	ccp4-run-thorough-tests -v test_refmac5 || die
}

src_install() {
	for i in refmac libcheck FreeTwin header2matr; do
		exeinto /usr/libexec/ccp4/bin/
		doexe ${i} || die
		dosym ../libexec/ccp4/bin/${i} /usr/bin/${i}
	done
	dosym refmac /usr/bin/refmac5 || die
}