[gentoo-commits] gentoo-x86 commit in net-irc/xchat: metadata.xml ChangeLog xchat-2.8.8.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    10/06/01 08:13:55

  Modified:             metadata.xml ChangeLog
  Added:                xchat-2.8.8.ebuild
  Log:
  Version bump reported by Lev Panov (bug #322307)
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  net-irc/xchat/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/xchat/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/xchat/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/xchat/metadata.xml?r1=1.6&r2=1.7

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/xchat/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml	6 Apr 2010 22:06:41 -0000	1.6
+++ metadata.xml	1 Jun 2010 08:13:55 -0000	1.7
@@ -2,6 +2,10 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>net-irc</herd>
+  <maintainer>
+    <email>polynomial-c@g.o</email>
+    <name>Lars Wendler</name>
+  </maintainer>
 <use>
 <flag name='ntlm'>Enable NTLM authentication</flag>
 <flag name='xchatdccserver'>Enables support for the /dccserver command via a patch</flag>



1.280                net-irc/xchat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/xchat/ChangeLog?rev=1.280&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/xchat/ChangeLog?rev=1.280&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/xchat/ChangeLog?r1=1.279&r2=1.280

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/xchat/ChangeLog,v
retrieving revision 1.279
retrieving revision 1.280
diff -u -r1.279 -r1.280
--- ChangeLog	25 Apr 2010 17:46:16 -0000	1.279
+++ ChangeLog	1 Jun 2010 08:13:55 -0000	1.280
@@ -1,6 +1,13 @@
 # ChangeLog for net-irc/xchat
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat/ChangeLog,v 1.279 2010/04/25 17:46:16 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat/ChangeLog,v 1.280 2010/06/01 08:13:55 polynomial-c Exp $
+
+*xchat-2.8.8 (01 Jun 2010)
+
+  01 Jun 2010; Lars Wendler <polynomial-c@g.o> +xchat-2.8.8.ebuild,
+  metadata.xml:
+  Version bump reported by Lev Panov (bug #322307). Added myself as
+  maintainer.
 
   25 Apr 2010; Raúl Porcel <armin76@g.o> xchat-2.8.6-r3.ebuild:
   Add ~arm



1.1                  net-irc/xchat/xchat-2.8.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/xchat/xchat-2.8.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/xchat/xchat-2.8.8.ebuild?rev=1.1&content-type=text/plain

Index: xchat-2.8.8.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat/xchat-2.8.8.ebuild,v 1.1 2010/06/01 08:13:55 polynomial-c Exp $

EAPI=2

inherit eutils versionator gnome2 autotools

DESCRIPTION="Graphical IRC client"
SRC_URI="http://www.xchat.org/files/source/$(get_version_component_range 1-2)/${P}.tar.bz2
	mirror://sourceforge/${PN}/${P}.tar.bz2
	xchatdccserver? ( mirror://gentoo/${PN}-dccserver-0.6.patch.bz2 )"
HOMEPAGE="http://www.xchat.org/"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="dbus ipv6 libnotify mmx nls ntlm perl python spell ssl tcl xchatnogtk xchatdccserver xft"

RDEPEND=">=dev-libs/glib-2.6.0
	!xchatnogtk? ( >=x11-libs/gtk+-2.10.0 )
	ssl? ( >=dev-libs/openssl-0.9.6d )
	perl? ( >=dev-lang/perl-5.8.0 )
	python? ( >=dev-lang/python-2.2 )
	tcl? ( dev-lang/tcl )
	dbus? ( >=dev-libs/dbus-glib-0.71 )
	spell? ( app-text/gtkspell )
	libnotify? ( x11-libs/libnotify )
	ntlm? ( net-libs/libntlm )
	!<net-irc/xchat-gnome-0.9"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.16
	nls? ( sys-devel/gettext )"

pkg_setup() {
	# Added for to fix a sparc seg fault issue by Jason Wever <weeve@g.o>
	if [[ ${ARCH} = sparc ]] ; then
		replace-flags "-O[3-9]" "-O2"
	fi
}

src_prepare() {
	use xchatdccserver && epatch "${DISTDIR}"/xchat-dccserver-0.6.patch.bz2

	# use libdir/xchat/plugins as the plugin directory
	if [ $(get_libdir) != "lib" ] ; then
		sed -i -e 's:${prefix}/lib/xchat:${libdir}/xchat:' \
			"${S}"/configure.in || die
	fi

	# xchat sourcecode ships with po/Makefile.in.in from gettext-0.17
	# which fails with >=gettext-0.18
	cp /usr/share/gettext/po/Makefile.in.in "${S}"/po/ || die

	eautoreconf
}

src_configure() {
	# xchat's configure script uses sys.path to find library path
	# instead of python-config (#25943)
	unset PYTHONPATH

	econf \
		--enable-shm \
		$(use_enable dbus) \
		$(use_enable ipv6) \
		$(use_enable mmx) \
		$(use_enable nls) \
		$(use_enable ntlm) \
		$(use_enable perl) \
		$(use_enable python) \
		$(use_enable spell spell gtkspell) \
		$(use_enable ssl openssl) \
		$(use_enable tcl) \
		$(use_enable !xchatnogtk gtkfe) \
		$(use_enable xft)
}

src_install() {
	USE_DESTDIR=1 gnome2_src_install || die "make install failed"

	# install plugin development header
	insinto /usr/include/xchat
	doins src/common/xchat-plugin.h || die "doins failed"

	dodoc ChangeLog README* || die "dodoc failed"
}

pkg_postinst() {
	elog
	elog "XChat binary has been renamed from xchat-2 to xchat."
	elog

	if has_version net-irc/xchat-systray
	then
		elog "XChat now includes it's own systray icon, you may want to remove net-irc/xchat-systray."
		elog
	fi
}