[gentoo-commits] gentoo-x86 commit in net-misc/plowshare: plowshare-0.8.ebuild metadata.xml ChangeLog

[Mounir Lamouri (volkmar)]

volkmar     09/09/28 00:04:05

  Added:                plowshare-0.8.ebuild metadata.xml ChangeLog
  Log:
  Initial commit.
  (Portage version: 14420-svn/cvs/Linux ppc)

Revision  Changes    Path
1.1                  net-misc/plowshare/plowshare-0.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/plowshare-0.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/plowshare-0.8.ebuild?rev=1.1&content-type=text/plain

Index: plowshare-0.8.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/plowshare-0.8.ebuild,v 1.1 2009/09/28 00:04:04 volkmar Exp $

EAPI="2"

DESCRIPTION="Command-line downloader and uploader for file-sharing websites"
HOMEPAGE="http://code.google.com/p/plowshare/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tgz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~ppc"
IUSE="+javascript +megaupload view-captcha"

RDEPEND="
	javascript? ( dev-lang/spidermonkey )
	megaupload? ( dev-lang/python
		dev-python/imaging )
	view-captcha? ( media-gfx/aview )
	app-shells/bash
	app-text/recode
	app-text/tesseract
	media-gfx/imagemagick[tiff]
	net-misc/curl
	sys-apps/util-linux"
DEPEND=""

# NOTES:
# dev-lang/spidermonkey is actually any javascript interpreter using /usr/bin/js

src_prepare() {
	if ! use megaupload; then
		sed -i -e "s: megaupload::" src/upload.sh src/download.sh \
			|| die "sed failed"
		rm src/modules/megaupload.sh || die "rm failed"
	fi
	if ! use javascript; then
		sed -i -e "s: mediafire::" src/upload.sh src/download.sh \
			|| die "sed failed"
		sed -i -e "s: zshare::" src/upload.sh src/download.sh \
			|| die "sed failed"
		rm src/modules/{mediafire,zshare}.sh
	fi
}

src_test() {
	./test/test_lib.sh || die "test failed"
}

src_install() {
	insinto /usr/share/${PN}
	doins src/lib.sh || die "doins failed"

	insinto /usr/share/${PN}/modules
	doins -r src/modules/* || die "doins failed"

	exeinto /usr/share/${PN}
	doexe src/{download,upload}.sh || die "doexe failed"

	dosym /usr/share/${PN}/download.sh /usr/bin/plowdown
	dosym /usr/share/${PN}/upload.sh /usr/bin/plowdup

	dodoc CHANGELOG README || die "dodoc failed"
}

pkg_postinst() {
	if ! use javascript; then
		ewarn "Without javascript you will not be able to use zshare and mediafire"
	fi
}



1.1                  net-misc/plowshare/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>no-herd</herd>
	<maintainer>
		<email>volkmar@g.o</email>
		<name>Mounir Lamouri</name>
	</maintainer>
	<use>
		<flag name="megaupload">Enable megaupload module</flag>
		<flag name="view-captcha">View captcha with aview</flag>
	</use>
</pkgmetadata>




1.1                  net-misc/plowshare/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-misc/plowshare
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v 1.1 2009/09/28 00:04:04 volkmar Exp $

*plowshare-0.8 (28 Sep 2009)

  28 Sep 2009; Mounir Lamouri <volkmar@g.o> +plowshare-0.8.ebuild,
  +metadata.xml:
  Initial commit.