[gentoo-commits] gentoo-x86 commit in net-analyzer/flow-tools: flow-tools-0.68.5.1-r4.ebuild ChangeLog flow-tools-0.68.5.1-r3.ebuild

[Jeroen Roovers (jer)]

jer         14/08/23 09:35:02

  Modified:             ChangeLog
  Added:                flow-tools-0.68.5.1-r4.ebuild
  Removed:              flow-tools-0.68.5.1-r3.ebuild
  Log:
  Convert sed script to patch. Fix syslog calls without format (bug #520520).
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.71                 net-analyzer/flow-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/ChangeLog?r1=1.70&r2=1.71

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/flow-tools/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog	11 Jul 2014 12:24:50 -0000	1.70
+++ ChangeLog	23 Aug 2014 09:35:02 -0000	1.71
@@ -1,6 +1,13 @@
 # ChangeLog for net-analyzer/flow-tools
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/flow-tools/ChangeLog,v 1.70 2014/07/11 12:24:50 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/flow-tools/ChangeLog,v 1.71 2014/08/23 09:35:02 jer Exp $
+
+*flow-tools-0.68.5.1-r4 (23 Aug 2014)
+
+  23 Aug 2014; Jeroen Roovers <jer@g.o> -flow-tools-0.68.5.1-r3.ebuild,
+  +flow-tools-0.68.5.1-r4.ebuild, +files/flow-tools-0.68.5.1-run.patch,
+  +files/flow-tools-0.68.5.1-syslog.patch:
+  Convert sed script to patch. Fix syslog calls without format (bug #520520).
 
 *flow-tools-0.68.5.1-r3 (11 Jul 2014)
 



1.1                  net-analyzer/flow-tools/flow-tools-0.68.5.1-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/flow-tools-0.68.5.1-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/flow-tools/flow-tools-0.68.5.1-r4.ebuild?rev=1.1&content-type=text/plain

Index: flow-tools-0.68.5.1-r4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/flow-tools/flow-tools-0.68.5.1-r4.ebuild,v 1.1 2014/08/23 09:35:02 jer Exp $

EAPI=5
inherit eutils user

DESCRIPTION="library and programs to collect, send, process, and generate reports from NetFlow data"
HOMEPAGE="http://code.google.com/p/flow-tools/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.bz2"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug mysql postgres ssl static-libs"

RDEPEND="sys-apps/tcp-wrappers
	sys-libs/zlib
	mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	ssl? ( dev-libs/openssl )"

DEPEND="${RDEPEND}
	sys-devel/flex
	sys-devel/bison"

DOCS=( ChangeLog README SECURITY TODO )

pkg_setup() {
	enewgroup flows
	enewuser flows -1 -1 /var/lib/flows flows
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-run.patch
	epatch "${FILESDIR}"/${P}-syslog.patch
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		$(usex mysql --with-mysql '') \
		$(usex postgres --with-postgresql=yes --with-postgresql=no) \
		$(usex ssl --with-openssl '') \
		--sysconfdir=/etc/flow-tools
}

src_install() {
	default

	prune_libtool_files

	exeinto /var/lib/flows/bin
	doexe "${FILESDIR}"/linkme

	keepdir /var/lib/flows/ft

	newinitd "${FILESDIR}/flowcapture.initd" flowcapture
	newconfd "${FILESDIR}/flowcapture.confd" flowcapture

	fowners flows:flows /var/lib/flows
	fowners flows:flows /var/lib/flows/bin
	fowners flows:flows /var/lib/flows/ft

	fperms 0755 /var/lib/flows
	fperms 0755 /var/lib/flows/bin
}

pkg_preinst() {
	enewgroup flows
	enewuser flows -1 -1 /var/lib/flows flows
}