[gentoo-commits] gentoo-x86 commit in net-print/gnome-cups-manager: ChangeLog gnome-cups-manager-0.33-r2.ebuild

[Gilles Dartiguelongue (eva)]

eva         10/08/29 21:21:53

  Modified:             ChangeLog
  Added:                gnome-cups-manager-0.33-r2.ebuild
  Log:
  Do not add CFLAGS to CXXFLAGS, bug #234028. Fix automagic samba support, bug #288392.
  
  (Portage version: 2.2_rc68/cvs/Linux x86_64)

Revision  Changes    Path
1.96                 net-print/gnome-cups-manager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/gnome-cups-manager/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/gnome-cups-manager/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/gnome-cups-manager/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/gnome-cups-manager/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	20 Jul 2010 15:39:48 -0000	1.95
+++ ChangeLog	29 Aug 2010 21:21:53 -0000	1.96
@@ -1,6 +1,15 @@
 # ChangeLog for net-print/gnome-cups-manager
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/gnome-cups-manager/ChangeLog,v 1.95 2010/07/20 15:39:48 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/gnome-cups-manager/ChangeLog,v 1.96 2010/08/29 21:21:53 eva Exp $
+
+*gnome-cups-manager-0.33-r2 (29 Aug 2010)
+
+  29 Aug 2010; Gilles Dartiguelongue <eva@g.o>
+  +gnome-cups-manager-0.33-r2.ebuild,
+  +files/gnome-cups-manager-0.33-automagic-samba.patch,
+  +files/gnome-cups-manager-0.33-cxxflags-separation.patch:
+  Do not add CFLAGS to CXXFLAGS, bug #234028. Fix automagic samba support,
+  bug #288392.
 
   20 Jul 2010; Jeroen Roovers <jer@g.o>
   gnome-cups-manager-0.33-r1.ebuild:



1.1                  net-print/gnome-cups-manager/gnome-cups-manager-0.33-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/gnome-cups-manager/gnome-cups-manager-0.33-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/gnome-cups-manager/gnome-cups-manager-0.33-r2.ebuild?rev=1.1&content-type=text/plain

Index: gnome-cups-manager-0.33-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/gnome-cups-manager/gnome-cups-manager-0.33-r2.ebuild,v 1.1 2010/08/29 21:21:53 eva Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit autotools eutils gnome2 flag-o-matic

DESCRIPTION="GNOME CUPS Printer Management Interface"
HOMEPAGE="http://www.gnome.org/"

SRC_URI="${SRC_URI}
	mirror://gentoo/${PN}-patches-${PV}-r1.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="samba"

# FIXME: samba support is automatic
COMMON=">=x11-libs/gtk+-2.3.1
	>=dev-libs/glib-2.3.1
	>=gnome-base/libgnome-2.14
	>=gnome-base/libgnomeui-2.14
	>=gnome-base/libglade-2
	>=gnome-base/libbonobo-2
	>=net-print/libgnomecups-0.2.3
	gnome-base/gnome-keyring
	samba? ( net-fs/samba[smbclient] )"

RDEPEND="${COMMON}
	x11-libs/gksu"

DEPEND="${COMMON}
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35"

DOCS="ChangeLog NEWS README"

pkg_setup() {
	G2CONF="${G2CONF} --disable-static $(use_enable samba)"
}

src_prepare() {
	gnome2_src_prepare

	# Do not add CFLAGS to CPPFLAGS, bug #234028
	epatch "${FILESDIR}/${PN}-0.33-cxxflags-separation.patch"

	# Fix automagic samba support, bug #288392
	epatch "${FILESDIR}/${PN}-0.33-automagic-samba.patch"

	# Apply ubuntu patchset
	rm "${WORKDIR}"/patches/140_all_ui_tooltip.patch || \
		die "removing patch failed"
	export EPATCH_SOURCE="${WORKDIR}/patches" \
		EPATCH_SUFFIX="patch" \
		EPATCH_MULTI_MSG="Applying Ubuntu patches (enhancements) ..."
	epatch

	intltoolize --force --copy --automake || die
	eautoreconf
}

src_install() {
	gnome2_src_install
	# debian-specific.
	rm "${D}"/usr/sbin/gnome-cups-switch
}