[gentoo-commits] gentoo-x86 commit in sec-policy/selinux-base-policy: ChangeLog selinux-base-policy-20070928.ebuild

[Chris PeBenito (pebenito)]

pebenito    07/11/27 02:45:52

  Modified:             ChangeLog
  Added:                selinux-base-policy-20070928.ebuild
  Log:
  update selinux policy to current refpolicy release
  (Portage version: 2.1.4_rc3)

Revision  Changes    Path
1.59                 sec-policy/selinux-base-policy/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sec-policy/selinux-base-policy/ChangeLog?rev=1.59&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sec-policy/selinux-base-policy/ChangeLog?rev=1.59&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sec-policy/selinux-base-policy/ChangeLog?r1=1.58&r2=1.59

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sec-policy/selinux-base-policy/ChangeLog,v
retrieving revision 1.58
retrieving revision 1.59
diff -u -r1.58 -r1.59
--- ChangeLog	4 Jun 2007 00:26:41 -0000	1.58
+++ ChangeLog	27 Nov 2007 02:45:51 -0000	1.59
@@ -1,6 +1,12 @@
 # ChangeLog for sec-policy/selinux-base-policy
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sec-policy/selinux-base-policy/ChangeLog,v 1.58 2007/06/04 00:26:41 pebenito Exp $
+# $Header: /var/cvsroot/gentoo-x86/sec-policy/selinux-base-policy/ChangeLog,v 1.59 2007/11/27 02:45:51 pebenito Exp $
+
+*selinux-base-policy-20070928 (26 Nov 2007)
+
+  26 Nov 2007; Chris PeBenito <pebenito@g.o>
+  +selinux-base-policy-20070928.ebuild:
+  New SVN snapshot.
 
   04 Jun 2007; Chris PeBenito <pebenito@g.o>
   selinux-base-policy-20070329.ebuild:



1.1                  sec-policy/selinux-base-policy/selinux-base-policy-20070928.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sec-policy/selinux-base-policy/selinux-base-policy-20070928.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sec-policy/selinux-base-policy/selinux-base-policy-20070928.ebuild?rev=1.1&content-type=text/plain

Index: selinux-base-policy-20070928.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sec-policy/selinux-base-policy/selinux-base-policy-20070928.ebuild,v 1.1 2007/11/27 02:45:51 pebenito Exp $

IUSE=""

inherit eutils

DESCRIPTION="Gentoo base policy for SELinux"
HOMEPAGE="http://www.gentoo.org/proj/en/hardened/selinux/"
SRC_URI="http://oss.tresys.com/files/refpolicy/refpolicy-${PV}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"

#KEYWORDS="~x86 ~ppc ~sparc ~amd64 ~mips ~alpha"
KEYWORDS="~alpha ~amd64 ~mips ~ppc ~sparc ~x86"

RDEPEND=">=sys-apps/policycoreutils-1.30.30"
DEPEND="${RDEPEND}
	sys-devel/m4
	>=sys-apps/checkpolicy-1.30.12"

S=${WORKDIR}/

src_unpack() {
	[ -z "${POLICY_TYPES}" ] && local POLICY_TYPES="strict targeted"
	MOD_CONF_VER="20070928"

	unpack ${A}

	cd "${S}/refpolicy"
#	epatch ${FILESDIR}/${PN}-${PV}.diff

	for i in ${POLICY_TYPES}; do
		mkdir -p "${S}/${i}/policy"
		cp "${FILESDIR}/modules.conf.${i}.${MOD_CONF_VER}" \
			 "${S}/${i}/policy/modules.conf"
	done
}

src_compile() {
	local OPTS="MONOLITHIC=n DISTRO=gentoo QUIET=y"
	[ -z "${POLICY_TYPES}" ] && local POLICY_TYPES="strict targeted"

	cd "${S}/refpolicy"

	make ${OPTS} generate || die "Failed to create generated module files"

	make ${OPTS} xml || die "XML generation failed."

	for i in ${POLICY_TYPES}; do
#		make ${OPTS} TYPE=${i} NAME=${i} LOCAL_ROOT="${S}/${i}" conf \
#			|| die "${i} modules.conf update failed"

		make ${OPTS} TYPE=${i} NAME=${i} LOCAL_ROOT="${S}/${i}" base \
			|| die "${i} compile failed"
	done
}

src_install() {
	local OPTS="MONOLITHIC=n DISTRO=gentoo QUIET=y DESTDIR=${D}"
	[ -z "${POLICY_TYPES}" ] && local POLICY_TYPES="strict targeted"

	cd "${S}/refpolicy"

	for i in ${POLICY_TYPES}; do
		make ${OPTS} TYPE=${i} NAME=${i} LOCAL_ROOT="${S}/${i}" install \
			|| die "${i} install failed."

		make ${OPTS} TYPE=${i} NAME=${i} install-headers \
			|| die "${i} headers install failed."

		echo "run_init_t" > "${D}/etc/selinux/${i}/contexts/run_init_type"

		echo "textrel_shlib_t" >> "${D}/etc/selinux/${i}/contexts/customizable_types"

		# libsemanage won't make this on its own
		keepdir "/etc/selinux/${i}/policy"
	done

	dodoc doc/Makefile.example doc/example.{te,fc,if}

	insinto /etc/selinux
	doins "${FILESDIR}/config"
}

pkg_postinst() {
	[ -z "${POLICY_TYPES}" ] && local POLICY_TYPES="strict targeted"

	if has "loadpolicy" $FEATURES ; then
		for i in ${POLICY_TYPES}; do
			einfo "Inserting base module into ${i} module store."

			cd "/usr/share/selinux/${i}"
			semodule -s "${i}" -b base.pp
		done
	else
		echo
		echo
		eerror "Policy has not been loaded.  It is strongly suggested"
		eerror "that the policy be loaded before continuing!!"
		echo
		einfo "Automatic policy loading can be enabled by adding"
		einfo "\"loadpolicy\" to the FEATURES in make.conf."
		echo
		echo
		ebeep 4
		epause 4
	fi
}



-- 
gentoo-commits@g.o mailing list