[gentoo-commits] gentoo-x86 commit in media-libs/libsndfile: libsndfile-1.0.22.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    10/10/05 18:28:52

  Modified:             ChangeLog
  Added:                libsndfile-1.0.22.ebuild
  Log:
  Version bump, minor bug fixes. Bump libvorbis dependency, remove unused libtool eclass, update to EAPI=3, use src_prepare instead of src_unpack, and use src_configure instead of src_compile.
  
  (Portage version: 2.2_rc88/cvs/Linux x86_64)

Revision  Changes    Path
1.115                media-libs/libsndfile/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsndfile/ChangeLog?rev=1.115&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsndfile/ChangeLog?rev=1.115&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsndfile/ChangeLog?r1=1.114&r2=1.115

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libsndfile/ChangeLog,v
retrieving revision 1.114
retrieving revision 1.115
diff -u -r1.114 -r1.115
--- ChangeLog	5 Sep 2010 09:26:49 -0000	1.114
+++ ChangeLog	5 Oct 2010 18:28:51 -0000	1.115
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libsndfile
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/ChangeLog,v 1.114 2010/09/05 09:26:49 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/ChangeLog,v 1.115 2010/10/05 18:28:51 radhermit Exp $
+
+*libsndfile-1.0.22 (05 Oct 2010)
+
+  05 Oct 2010; Tim Harder <radhermit@g.o> +libsndfile-1.0.22.ebuild:
+  Version bump, minor bug fixes. Bump libvorbis dependency, remove unused
+  libtool eclass, update to EAPI=3, use src_prepare instead of src_unpack,
+  and use src_configure instead of src_compile.
 
 *libsndfile-1.0.21-r1 (05 Sep 2010)
 



1.1                  media-libs/libsndfile/libsndfile-1.0.22.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsndfile/libsndfile-1.0.22.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsndfile/libsndfile-1.0.22.ebuild?rev=1.1&content-type=text/plain

Index: libsndfile-1.0.22.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/libsndfile-1.0.22.ebuild,v 1.1 2010/10/05 18:28:51 radhermit Exp $

EAPI=3
inherit eutils autotools

MY_P=${P/_pre/pre}

DESCRIPTION="A C library for reading and writing files containing sampled sound"
HOMEPAGE="http://www.mega-nerd.com/libsndfile"
if [[ "${MY_P}" == "${P}" ]]; then
	SRC_URI="http://www.mega-nerd.com/libsndfile/files/${P}.tar.gz"
else
	SRC_URI="http://www.mega-nerd.com/tmp/${MY_P}b.tar.gz"
fi

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="alsa minimal sqlite"

RDEPEND="!minimal? ( >=media-libs/flac-1.2.1
		>=media-libs/libogg-1.1.3
		>=media-libs/libvorbis-1.2.3 )
	alsa? ( media-libs/alsa-lib )
	sqlite? ( >=dev-db/sqlite-3.2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

src_prepare() {
	sed -i -e "s/noinst_PROGRAMS/check_PROGRAMS/" "${S}/tests/Makefile.am" \
		"${S}/examples/Makefile.am" || die "sed failed"

	epatch "${FILESDIR}"/${PN}-1.0.17-regtests-need-sqlite.patch

	rm M4/libtool.m4 M4/lt*.m4 || die "rm failed"

	AT_M4DIR=M4 eautoreconf
	epunt_cxx
}

src_configure() {
	econf $(use_enable sqlite) \
		$(use_enable alsa) \
		$(use_enable !minimal external-libs) \
		--disable-octave \
		--disable-gcc-werror \
		--disable-gcc-pipe \
		--disable-dependency-tracking
}

src_install() {
	emake DESTDIR="${D}" htmldocdir="/usr/share/doc/${PF}/html" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README
}