[gentoo-commits] gentoo-x86 commit in dev-libs/weston: metadata.xml weston-1.4.0.ebuild ChangeLog

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    14/01/30 12:24:40

  Modified:             metadata.xml ChangeLog
  Added:                weston-1.4.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.3                  dev-libs/weston/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/weston/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/weston/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/weston/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/weston/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	29 Jul 2013 14:35:47 -0000	1.2
+++ metadata.xml	30 Jan 2014 12:24:40 -0000	1.3
@@ -11,6 +11,7 @@
 	<flag name='fbdev'>Enable fbdev compositor support</flag>
 	<flag name='gles2'>Use GLESv2 cairo instead of full GL</flag>
 	<flag name='headless'>Headless backend and a noop renderer, mainly for testing purposes</flag>
+	<flag name='launch'>Install weston-launch utility</flag>
 	<flag name='rdp'>Enable Remote Desktop Protocol compositor support</flag>
 	<flag name='resize-optimization'>Increase performance, allocate more RAM. Recommended to disable on Raspberry Pi</flag>
 	<flag name='rpi'>Raspberry Pi GPU support</flag>



1.6                  dev-libs/weston/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/weston/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/weston/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/weston/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/weston/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	25 Aug 2013 16:39:48 -0000	1.5
+++ ChangeLog	30 Jan 2014 12:24:40 -0000	1.6
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/weston
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/weston/ChangeLog,v 1.5 2013/08/25 16:39:48 chithanh Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/weston/ChangeLog,v 1.6 2014/01/30 12:24:40 chithanh Exp $
+
+*weston-1.4.0 (30 Jan 2014)
+
+  30 Jan 2014; Chí-Thanh Christopher Nguyễn <chithanh@g.o>
+  +weston-1.4.0.ebuild, metadata.xml:
+  Version bump.
 
 *weston-1.2.1 (25 Aug 2013)
 



1.1                  dev-libs/weston/weston-1.4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/weston/weston-1.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/weston/weston-1.4.0.ebuild?rev=1.1&content-type=text/plain

Index: weston-1.4.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/weston/weston-1.4.0.ebuild,v 1.1 2014/01/30 12:24:40 chithanh Exp $

EAPI=5

if [[ ${PV} = 9999* ]]; then
	EGIT_REPO_URI="git://anongit.freedesktop.org/git/wayland/${PN}"
	GIT_ECLASS="git-r3"
	EXPERIMENTAL="true"
fi
VIRTUALX_REQUIRED="test"
RESTRICT="test"

inherit autotools readme.gentoo toolchain-funcs virtualx $GIT_ECLASS

DESCRIPTION="Wayland reference compositor"
HOMEPAGE="http://wayland.freedesktop.org/"

if [[ $PV = 9999* ]]; then
	SRC_URI="${SRC_PATCHES}"
	KEYWORDS=""
else
	SRC_URI="http://wayland.freedesktop.org/releases/${P}.tar.xz"
	KEYWORDS="~arm ~amd64 ~x86 ~arm-linux"
fi

LICENSE="MIT CC-BY-SA-3.0"
SLOT="0"
IUSE="colord +drm dbus +egl editor examples fbdev gles2 headless +opengl rdp +resize-optimization rpi +launch static-libs +suid systemd test unwind view wayland-compositor +X xwayland"

REQUIRED_USE="
	drm? ( egl )
	egl? ( || ( gles2 opengl ) )
	gles2? ( !opengl )
	test? ( X )
	wayland-compositor? ( egl )
"

RDEPEND="
	>=dev-libs/wayland-1.4.0
	media-libs/lcms:2
	media-libs/libpng:=
	virtual/jpeg
	>=x11-libs/cairo-1.11.3[gles2(-)?,opengl?]
	>=x11-libs/libdrm-2.4.30
	x11-libs/libxkbcommon
	x11-libs/pixman
	x11-misc/xkeyboard-config
	fbdev? (
		>=sys-libs/mtdev-1.1.0
		>=virtual/udev-136
	)
	colord? ( >=x11-misc/colord-0.1.27 )
	dbus? ( sys-apps/dbus )
	drm? (
		media-libs/mesa[gbm]
		>=sys-libs/mtdev-1.1.0
		>=virtual/udev-136
	)
	egl? (
		media-libs/glu
		media-libs/mesa[gles2,wayland]
	)
	editor? ( x11-libs/pango )
	gles2? (
		media-libs/mesa[wayland]
	)
	opengl? (
		media-libs/mesa[wayland]
	)
	view? (
		app-text/poppler:=[cairo]
		dev-libs/glib:2
	)
	rdp? ( >=net-misc/freerdp-1.1.0_beta1_p20130710 )
	rpi? (
		>=sys-libs/mtdev-1.1.0
		>=virtual/udev-136
	)
	systemd? (
		sys-auth/pambase[systemd]
		sys-apps/systemd[pam]
	)
	launch? ( sys-auth/pambase )
	unwind? ( sys-libs/libunwind )
	X? (
		x11-libs/libxcb
		x11-libs/libX11
	)
	xwayland? (
		x11-libs/cairo[xcb]
		x11-libs/libxcb
		x11-libs/libXcursor
	)
"
DEPEND="${RDEPEND}
	gnome-base/librsvg
	virtual/pkgconfig
"

src_prepare() {
	if [[ ${PV} = 9999* ]]; then
		eautoreconf
	fi
}

src_configure() {
	local myconf
	if use examples || use gles2 || use test; then
		myconf="--enable-simple-clients
			$(use_enable egl simple-egl-clients)"
	else
		myconf="--disable-simple-clients
			--disable-simple-egl-clients"
	fi

	if use gles2; then
		myconf+=" --with-cairo=glesv2"
	elif use opengl; then
		myconf+=" --with-cairo=gl"
	else
		myconf+=" --with-cairo=image"
	fi

	econf \
		$(use_enable fbdev fbdev-compositor) \
		$(use_enable dbus) \
		$(use_enable drm drm-compositor) \
		$(use_enable headless headless-compositor) \
		$(use_enable rdp rdp-compositor) \
		$(use_enable rpi rpi-compositor) \
		$(use_enable wayland-compositor) \
		$(use_enable X x11-compositor) \
		$(use_enable launch weston-launch) \
		$(use_enable colord) \
		$(use_enable egl) \
		$(use_enable unwind libunwind) \
		$(use_enable resize-optimization) \
		$(use_enable suid setuid-install) \
		$(use_enable xwayland) \
		$(use_enable xwayland xwayland-test) \
		${myconf}
}

src_test() {
	export XDG_RUNTIME_DIR="${T}/runtime-dir"
	mkdir "${XDG_RUNTIME_DIR}" || die
	chmod 0700 "${XDG_RUNTIME_DIR}" || die

	cd "${BUILD_DIR}" || die
	Xemake check
}

src_install() {
	default

	readme.gentoo_src_install

	pushd clients || die

	if use opengl && use egl && use !gles2; then
		dobin weston-gears
	fi
	if use editor; then
		dobin weston-editor
	fi
	if use view; then
		dobin weston-view
	fi
	if use examples; then
		use egl && dobin weston-simple-egl
		dobin \
			weston-calibrator \
			weston-clickdot \
			weston-cliptest \
			weston-dnd \
			weston-eventdemo \
			weston-flower \
			weston-fullscreen \
			weston-image \
			weston-resizor \
			weston-simple-shm \
			weston-simple-touch \
			weston-smoke \
			weston-transformed
	fi
	popd

}