[gentoo-commits] repo/gentoo:master commit in: x11-libs/libfakekey/

[Andreas Sturmlechner]

commit:     fec1848c871caea335f7651f5898ce476b81ca90
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat May 30 08:36:17 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat May 30 08:37:45 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fec1848c

x11-libs/libfakekey: --disable-static

Closes: https://bugs.gentoo.org/726146
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 x11-libs/libfakekey/libfakekey-0.3-r1.ebuild | 48 ++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/x11-libs/libfakekey/libfakekey-0.3-r1.ebuild b/x11-libs/libfakekey/libfakekey-0.3-r1.ebuild
new file mode 100644
index 00000000000..ba84cd53b00
--- /dev/null
+++ b/x11-libs/libfakekey/libfakekey-0.3-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Helper library for the x11-misc/matchbox-keyboard package"
+HOMEPAGE="https://www.yoctoproject.org/tools-resources/projects/matchbox"
+SRC_URI="https://git.yoctoproject.org/cgit/cgit.cgi/${PN}/snapshot/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ~hppa ppc ~ppc64 x86"
+IUSE="debug doc"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+DEPEND="x11-libs/libXtst"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${P}-ac.patch" ) # Allow configure to use libtool-2
+
+src_prepare() {
+	default
+
+	# Fix underlinking bug #367595
+	sed -i -e 's/^fakekey_test_LDADD=/fakekey_test_LDADD=-lX11 /' \
+		tests/Makefile.am || die 'Cannot sed Makefile.am'
+	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		# --with/without-x is ignored by configure script and X is used.
+		--with-x
+		--disable-static
+		$(use_enable debug)
+		$(use_enable doc doxygen-docs)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}