[gentoo-commits] gentoo-x86 commit in app-arch/libarchive: ChangeLog libarchive-2.6.2.ebuild libarchive-2.5.5.ebuild

[Diego Petteno (flameeyes)]

flameeyes    09/02/27 09:59:57

  Modified:             ChangeLog
  Added:                libarchive-2.6.2.ebuild
  Removed:              libarchive-2.5.5.ebuild
  Log:
  Version bump, remove old version.
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.43                 app-arch/libarchive/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	1 Feb 2009 20:47:26 -0000	1.42
+++ ChangeLog	27 Feb 2009 09:59:57 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/libarchive
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.42 2009/02/01 20:47:26 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.43 2009/02/27 09:59:57 flameeyes Exp $
+
+*libarchive-2.6.2 (27 Feb 2009)
+
+  27 Feb 2009; Diego E. Pettenò <flameeyes@g.o>
+  -libarchive-2.5.5.ebuild, +libarchive-2.6.2.ebuild:
+  Version bump, remove old version.
 
   01 Feb 2009; Markus Meier <maekke@g.o> libarchive-2.6.0.ebuild:
   amd64/x86 stable, bug #257165



1.1                  app-arch/libarchive/libarchive-2.6.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.6.2.ebuild?rev=1.1&content-type=text/plain

Index: libarchive-2.6.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-2.6.2.ebuild,v 1.1 2009/02/27 09:59:57 flameeyes Exp $

EAPI=1

inherit eutils libtool toolchain-funcs

DESCRIPTION="BSD tar command"
HOMEPAGE="http://people.freebsd.org/~kientzle/libarchive"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz
	http://people.freebsd.org/~kientzle/libarchive/src/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="static acl xattr kernel_linux +bzip2 +lzma +zlib"

COMPRESS_LIBS_DEPEND="lzma? ( app-arch/lzma-utils )
		bzip2? ( app-arch/bzip2 )
		zlib? ( sys-libs/zlib )"

RDEPEND="!dev-libs/libarchive
	kernel_linux? (
		acl? ( sys-apps/acl )
		xattr? ( sys-apps/attr )
	)
	!static? ( ${COMPRESS_LIBS_DEPEND} )"
DEPEND="${RDEPEND}
	${COMPRESS_LIBS_DEPEND}
	kernel_linux? ( sys-fs/e2fsprogs
		virtual/os-headers )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	elibtoolize
	epunt_cxx
}

src_compile() {
	local myconf

	if ! use static ; then
		myconf="--enable-bsdtar=shared --enable-bsdcpio=shared"
	fi

	econf --bindir=/bin \
		--enable-bsdtar --enable-bsdcpio \
		$(use_enable acl) $(use_enable xattr) \
		$(use_with zlib) \
		$(use_with bzip2 bz2lib) $(use_with lzma lzmadec) \
		${myconf} \
		--disable-dependency-tracking || die "econf failed."

	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."

	# Create tar symlink for FreeBSD
	if [[ ${CHOST} == *-freebsd* ]]; then
		dosym bsdtar /bin/tar
		dosym bsdtar.1 /usr/share/man/man1/tar.1
		# We may wish to switch to symlink bsdcpio to cpio too one day
	fi

	dodoc NEWS README
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)
	gen_usr_ldscript libarchive.so
}