[gentoo-commits] gentoo-x86 commit in net-news/liferea: liferea-1.10.3.ebuild ChangeLog

[Victor Ostorga (vostorga)]

vostorga    13/10/28 01:30:36

  Modified:             ChangeLog
  Added:                liferea-1.10.3.ebuild
  Log:
  Version bump to 1.10.3
  
  (Portage version: 2.2.1/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.239                net-news/liferea/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/ChangeLog?rev=1.239&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/ChangeLog?rev=1.239&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/ChangeLog?r1=1.238&r2=1.239

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v
retrieving revision 1.238
retrieving revision 1.239
diff -u -r1.238 -r1.239
--- ChangeLog	1 Aug 2013 13:40:40 -0000	1.238
+++ ChangeLog	28 Oct 2013 01:30:36 -0000	1.239
@@ -1,6 +1,11 @@
 # ChangeLog for net-news/liferea
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.238 2013/08/01 13:40:40 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.239 2013/10/28 01:30:36 vostorga Exp $
+
+*liferea-1.10.3 (27 Oct 2013)
+
+  27 Oct 2013; Víctor Ostorga <vostorga@g.o> +liferea-1.10.3.ebuild:
+  Liferea version bump
 
 *liferea-1.10.1a (01 Aug 2013)
 



1.1                  net-news/liferea/liferea-1.10.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/liferea-1.10.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-news/liferea/liferea-1.10.3.ebuild?rev=1.1&content-type=text/plain

Index: liferea-1.10.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/liferea-1.10.3.ebuild,v 1.1 2013/10/28 01:30:36 vostorga Exp $

EAPI="5"

GCONF_DEBUG="no"

inherit autotools eutils gnome2 pax-utils

MY_P=${P/_rc/-RC}
MY_P=${MY_P/_/-}

S=${WORKDIR}/${MY_P}

DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo feeds"
HOMEPAGE="http://liferea.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

IUSE="ayatana libnotify"

RDEPEND="x11-libs/gtk+:3
	>=dev-libs/glib-2.26.0:2
	dev-libs/json-glib
	>=dev-libs/libpeas-1.0.0[gtk]
	>=net-libs/libsoup-2.28.2:2.4
	dev-libs/libunique:3
	>=dev-libs/libxml2-2.6.27:2
	>=dev-libs/libxslt-1.1.19
	>=dev-db/sqlite-3.7.0:3
	>=gnome-base/gconf-1.1.9:2
	gnome-base/gsettings-desktop-schemas
	>=net-libs/webkit-gtk-1.6.1:3
	>=x11-libs/pango-1.4.0
	ayatana? ( dev-libs/libindicate )
	libnotify? ( >=x11-libs/libnotify-0.3.2 )"

DEPEND="${RDEPEND}
	dev-util/intltool
	virtual/pkgconfig"

DOCS="AUTHORS ChangeLog README"

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-schemas-compile
		$(use_enable ayatana libindicate)
		$(use_enable libnotify)"
}

src_prepare() {
	eautoreconf

	gnome2_src_prepare
}

src_install() {
	gnome2_src_install

	# bug #338213
	# Uses webkit's JIT. Needs mmap('rwx') to generate code in runtime.
	# MPROTECT policy violation. Will sit here until webkit will
	# get optional JIT.
	pax-mark m "${D}"/usr/bin/liferea

	einfo "If you want to enhance the functionality of this package,"
	einfo "you should consider installing:"
	einfo "    dev-libs/dbus-glib"
	einfo "    net-misc/networkmanager"
}