[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/

[Mart Raudsepp]

commit:     ec63c4848a38caec269d4b44504501a820898018
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Jan  9 10:26:12 2021 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Jan  9 10:37:17 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec63c484

gnome-extra/evolution-data-server: bump to 3.38.3

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/evolution-data-server/Manifest         |   1 +
 .../evolution-data-server-3.38.3.ebuild            | 152 +++++++++++++++++++++
 2 files changed, 153 insertions(+)

diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 9f53ff9fd7b..f858134ad6d 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1,2 +1,3 @@
 DIST evolution-data-server-3.36.5.tar.xz 4636800 BLAKE2B 5708ec1f064b723cb5421dad50145d2377c2c683ef37fe82d24b6f27a895b89e43c55ae6c900797d477b1af052e0cc6381649c790744d8591010d928822917f1 SHA512 65ec23a665e3a547b10ad6a6be5f0533db269406c3e8db64a63cffb8e1b410e83b9c39bd7cd5dac5ecd5cf61ef96dc529ba1bd00ad0a09b3bf2c4e98f3d156e3
 DIST evolution-data-server-3.38.2.tar.xz 4662216 BLAKE2B 7c1cf2d921d1f1b656c972ec0a1d91673684f9a27ba5474a9f736b7f34b883bc921a10e986a40bced2d61d8cff81d7537d7ea76dfdc32bbc796ccb72127857e8 SHA512 6db1943a5b31ccd6bd6b4e5845c083973c9e436a9c48f876f446ef130c2d8fe9b2ba3452fd64774061fb368248bfcdd4285dad22b7053459767ca958312d64d5
+DIST evolution-data-server-3.38.3.tar.xz 4662120 BLAKE2B df126b275e59963bd965fd741f9d516f998e304d42afb3eeff56df038464cd5492c590320305d58b9cb26c3c877dd9fdab486387d8a48057e4e7bdeebdc282a0 SHA512 08f8a3c85370ac195bd42b4dce2d65be06b7d43d7d19ea784ef62234b339315137560fcdf9808be5c6629687e5b244b59455cd702e994d5ff890d829248fa6b9

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.38.3.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.38.3.ebuild
new file mode 100644
index 00000000000..517bce512d6
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.38.3.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit cmake db-use flag-o-matic gnome2 systemd vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/62-25-20" # subslot = libcamel-1.2/libedataserver-1.2/libebook-1.2.so soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ipv6 ldap kerberos oauth vala +weather"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# gdata-0.17.7 soft required for new gdata_feed_get_next_page_token API to handle more than 100 google tasks
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+gdata_depend=">=dev-libs/libgdata-0.17.7:="
+RDEPEND="
+	>=app-crypt/gcr-3.4
+	>=app-crypt/libsecret-0.5[crypt]
+	>=dev-db/sqlite-3.7.17:=
+	>=dev-libs/glib-2.46:2
+	>=dev-libs/libical-3.0.8:=[glib,introspection?]
+	>=dev-libs/libxml2-2
+	>=dev-libs/nspr-4.4:=
+	>=dev-libs/nss-3.9:=
+	>=net-libs/libsoup-2.58:2.4
+
+	dev-libs/icu:=
+	sys-libs/zlib:=
+	virtual/libiconv
+
+	berkdb? ( >=sys-libs/db-4:= )
+	gtk? (
+		>=app-crypt/gcr-3.4[gtk]
+		>=x11-libs/gtk+-3.10:3
+		>=media-libs/libcanberra-0.25[gtk3]
+	)
+	oauth? (
+		>=dev-libs/json-glib-1.0.4
+		>=net-libs/webkit-gtk-2.28.0:4
+		${gdata_depend}
+	)
+	gnome-online-accounts? (
+		>=net-libs/gnome-online-accounts-3.8:=
+		${gdata_depend} )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	kerberos? ( virtual/krb5:= )
+	ldap? ( >=net-nds/openldap-2:= )
+	weather? ( >=dev-libs/libgweather-3.10:2= )
+"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend)
+		net-libs/libsoup:2.4[vala]
+		dev-libs/libical[vala]
+	)
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/gperf
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+	use vala && vala_src_prepare
+	cmake_src_prepare
+	gnome2_src_prepare
+
+	eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
+
+	# Make CMakeLists versioned vala enabled
+	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+		-e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+		-i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	# /usr/include/db.h is always db-1 on FreeBSD
+	# so include the right dir in CPPFLAGS
+	use berkdb && append-cppflags "-I$(db_includedir)"
+
+	local google_enable
+	if use oauth || use gnome-online-accounts; then
+		google_enable="ON"
+	else
+		google_enable="OFF"
+	fi
+
+	# phonenumber does not exist in tree
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DENABLE_GTK_DOC=$(usex gtk-doc)
+		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+		-DENABLE_SCHEMAS_COMPILE=OFF
+		-DENABLE_INTROSPECTION=$(usex introspection)
+		-DWITH_KRB5=$(usex kerberos)
+		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+		-DWITH_OPENLDAP=$(usex ldap)
+		-DWITH_PHONENUMBER=OFF
+		-DENABLE_SMIME=ON
+		-DENABLE_GTK=$(usex gtk)
+		-DENABLE_CANBERRA=$(usex gtk)
+		-DENABLE_OAUTH2=$(usex oauth)
+		-DENABLE_EXAMPLES=OFF
+		-DENABLE_GOA=$(usex gnome-online-accounts)
+		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+		# ENABLE_BACKTRACES requires libdwarf ?
+		-DENABLE_IPV6=$(usex ipv6)
+		-DENABLE_WEATHER=$(usex weather)
+		-DENABLE_GOOGLE=${google_enable}
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_VALA_BINDINGS=$(usex vala)
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use ldap; then
+		insinto /etc/openldap/schema
+		doins "${FILESDIR}"/calentry.schema
+		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+	fi
+}