[gentoo-commits] repo/gentoo:master commit in: net-misc/remmina/

[David Seifert]

commit:     17ec02e29d2521bb13c4799cd0d535ddeca19c9c
Author:     Diogo Pereira <sir.suriv <AT> gmail <DOT> com>
AuthorDate: Fri Dec 23 16:28:04 2016 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Thu Dec 29 14:38:30 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=17ec02e2

net-misc/remmina: depend on a fixed version of freerdp

FreeRDP 2 does not yet have a stable API, so we need to depend on a
fixed version of FreeRDP to ensure that version bumps don't break
Remmina.

Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/3226

 net-misc/remmina/remmina-1.2.0_rc16-r1.ebuild | 84 +++++++++++++++++++++++++++
 1 file changed, 84 insertions(+)

diff --git a/net-misc/remmina/remmina-1.2.0_rc16-r1.ebuild b/net-misc/remmina/remmina-1.2.0_rc16-r1.ebuild
new file mode 100644
index 00000000..579c65b
--- /dev/null
+++ b/net-misc/remmina/remmina-1.2.0_rc16-r1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils eutils gnome2-utils
+
+MY_PV="${PV//_rc/-rcgit.}"
+
+DESCRIPTION="A GTK+ RDP, VNC, XDMCP and SSH client"
+HOMEPAGE="http://remmina.org/"
+SRC_URI="https://github.com/FreeRDP/Remmina/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ayatana crypt freerdp gnome-keyring nls spice ssh telepathy webkit zeroconf"
+
+RDEPEND="
+	dev-libs/glib:2
+	net-libs/libvncserver
+	x11-libs/libxkbfile
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	virtual/freedesktop-icon-theme
+	ayatana? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	freerdp? ( ~net-misc/freerdp-2.0.0_pre20160722 )
+	gnome-keyring? ( app-crypt/libsecret )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( net-dns/avahi[gtk3] )
+"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+DOCS=( README.md )
+
+S="${WORKDIR}/Remmina-${MY_PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex ayatana)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_FREERDP=$(usex freerdp)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_SURVEY=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DGTK_VERSION=3
+	)
+	cmake-utils_src_configure
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}