[gentoo-commits] gentoo-x86 commit in sci-physics/hoomd-blue: hoomd-blue-1.0.2.ebuild metadata.xml Manifest ChangeLog

[Christoph Junghans (ottxor)]

ottxor      15/03/01 05:10:07

  Added:                hoomd-blue-1.0.2.ebuild metadata.xml Manifest
                        ChangeLog
  Log:
  initial commit
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key C2000586)

Revision  Changes    Path
1.1                  sci-physics/hoomd-blue/hoomd-blue-1.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hoomd-blue/hoomd-blue-1.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hoomd-blue/hoomd-blue-1.0.2.ebuild?rev=1.1&content-type=text/plain

Index: hoomd-blue-1.0.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/hoomd-blue/hoomd-blue-1.0.2.ebuild,v 1.1 2015/03/01 05:10:07 ottxor Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit cmake-utils cuda python-single-r1

DESCRIPTION="a general-purpose particle simulation toolkit"
HOMEPAGE="http://codeblue.umich.edu/hoomd-blue/"

if [[ ${PV} = 9999 ]]; then
	EGIT_REPO_URI="https://bitbucket.org/glotzer/${PN}.git"
	inherit git-r3
	KEYWORDS=
else
	inherit vcs-snapshot
	SRC_URI="https://bitbucket.org/glotzer/${PN}/get/v${PV}.tar.bz2 -> ${P}.tar.bz2"
	KEYWORDS="~amd64"
fi

LICENSE="hoomd-blue"
SLOT="0"
IUSE="cuda doc test mpi +zlib"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="${PYTHON_DEPS}
	mpi? ( virtual/mpi )
	cuda? ( dev-util/nvidia-cuda-sdk )
	zlib? ( sys-libs/zlib )
	dev-libs/boost:=[threads,python,mpi,${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

src_prepare() {
	use cuda && cuda_src_prepare

	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_enable mpi MPI)
		$(cmake-utils_use_enable doc DOXYGEN)
		$(cmake-utils_use_enable cuda CUDA)
		$(cmake-utils_use_enable zlib ZLIB)
		$(cmake-utils_use_build test BUILD_TESTING)
		-DPYTHON_SITEDIR=$(python_get_sitedir)
	)
	cmake-utils_src_configure
}

src_install() {
	use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/hoomd-*doc* )
	cmake-utils_src_install

	sed -i "s/^python/${EPYTHON}/" "${ED}"/usr/bin/hoomd || die
}



1.1                  sci-physics/hoomd-blue/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hoomd-blue/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hoomd-blue/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>sci-chemistry</herd>
  <maintainer>
    <email>ottxor@g.o</email>
    <name>Christoph Junghans</name>
  </maintainer>
  <use>
    <flag name="cuda">Enable cuda non-bonded kernels</flag>
  </use>
</pkgmetadata>



1.1                  sci-physics/hoomd-blue/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hoomd-blue/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hoomd-blue/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
DIST hoomd-blue-1.0.2.tar.bz2 2755462 SHA256 bca7d377fa152b5f99047c5701db0fecb244f56a7861c35eef0ded6106c520d1 SHA512 f9042e3afacc14e62490802d16a13a77592195befa61837703a39aeedf679e81f31aaafb377384d3b0a2f0e9e40dbce7ddd8b2673086706ba223fe265a2dff27 WHIRLPOOL b72c12a88941899c7a51a0a8e78783bf8c108b85f3969663453b2048a9a9c43ab8d4fd3fbcefa0a6d3add47ac880a2462d92760dc9efc5dd7a822be0252bce19
EBUILD hoomd-blue-1.0.2.ebuild 1424 SHA256 76b352fbefe8e8a177b0545bd8f929223de077ed7cb314879116d5d1f81f67de SHA512 aca246a2355b6708f5eae4527139bb89259870d75a9130103b504f341cbfe1c88fa1444010e76f23bea01f467d4dd82bedd1cc1c2843eeda11f4fc9e4b3ca247 WHIRLPOOL 3c6f8ac77a208583093ddfc0d4a01a36365e6d18b651941e6fb9bcbdae5184a38ac642ccddbef4692ed2e0650f77fb500e1cd30e1b5a6f21ceb74919b2ce2589
MISC metadata.xml 349 SHA256 7963a3bcdbac28de0111504b026c8224398120e0e7571a23dcce9fbdd84d86a9 SHA512 d111b78e604b1cc87dc331eaeaf85ec0f5bbefe959a0bc4f52911a13129761a9cffb25dc40bb53ef7b70db6b8d16c9f042400f3928258722dc2eb00153956eca WHIRLPOOL c22b8e5d28b8e1af8c43b5722e7539018d8906cf6dd0371652f1bfb5d17945cae1e22bfa88e2c7bdf4c1541dedb6da955971f8ed96168264aae9b57d07078fc7



1.1                  sci-physics/hoomd-blue/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hoomd-blue/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/hoomd-blue/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sci-physics/hoomd-blue
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/hoomd-blue/ChangeLog,v 1.1 2015/03/01 05:10:07 ottxor Exp $

*hoomd-blue-1.0.2 (01 Mar 2015)

  01 Mar 2015; Christoph Junghans <ottxor@g.o> +hoomd-blue-1.0.2.ebuild,
  +metadata.xml:
  initial commit