[gentoo-commits] gentoo-x86 commit in net-libs/webkit-gtk: ChangeLog webkit-gtk-1.1.10.ebuild

[Romain Perier (mrpouet)]

mrpouet     09/06/19 17:26:25

  Modified:             ChangeLog
  Added:                webkit-gtk-1.1.10.ebuild
  Log:
  Bump to 1.1.10, bug #274445, thanks to Priit Laes <amd@×××××××.com>
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.34                 net-libs/webkit-gtk/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	3 Jun 2009 17:29:12 -0000	1.33
+++ ChangeLog	19 Jun 2009 17:26:25 -0000	1.34
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/webkit-gtk
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v 1.33 2009/06/03 17:29:12 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v 1.34 2009/06/19 17:26:25 mrpouet Exp $
+
+*webkit-gtk-1.1.10 (19 Jun 2009)
+
+  19 Jun 2009; <mrpouet@g.o> +webkit-gtk-1.1.10.ebuild:
+  Bump to 1.1.10, bug #274445, thanks to Priit Laes <amd@×××××××.com>
 
   03 Jun 2009; Nirbheek Chauhan <nirbheek@g.o>
   webkit-gtk-1.1.8.ebuild:



1.1                  net-libs/webkit-gtk/webkit-gtk-1.1.10.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.1.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.1.10.ebuild?rev=1.1&content-type=text/plain

Index: webkit-gtk-1.1.10.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.1.10.ebuild,v 1.1 2009/06/19 17:26:25 mrpouet Exp $

EAPI="2"

inherit autotools

MY_P="webkit-${PV}"
DESCRIPTION="Open source web browser engine"
HOMEPAGE="http://www.webkitgtk.org/"
SRC_URI="http://www.webkitgtk.org/${MY_P}.tar.gz"

LICENSE="LGPL-2 LGPL-2.1 BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
# geoclue
IUSE="coverage debug doc gnome-keyring +gstreamer pango"

# use sqlite, svg by default
RDEPEND="
	dev-libs/libxml2
	dev-libs/libxslt
	media-libs/jpeg
	media-libs/libpng
	x11-libs/cairo

	>=x11-libs/gtk+-2.10
	>=dev-libs/icu-3.8.1-r1
	>=net-libs/libsoup-2.25.90
	>=dev-db/sqlite-3
	>=app-text/enchant-0.22

	gnome-keyring? ( >=gnome-base/gnome-keyring-2.26.0 )
	gstreamer? (
		media-libs/gstreamer:0.10
		media-libs/gst-plugins-base:0.10 )
	pango? ( x11-libs/pango )
	!pango? (
		media-libs/freetype:2
		media-libs/fontconfig )
"
DEPEND="${RDEPEND}
	sys-devel/gettext
	dev-util/gperf
	dev-util/pkgconfig
	doc? ( >=dev-util/gtk-doc-1.10 )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# Make it libtool-1 compatible
	rm -v autotools/lt* autotools/libtool.m4 || die "removing libtool macros failed"
	# Don't force -O2
	sed -i 's/-O2//g' "${S}"/configure.ac || die "sed failed"
	# Prevent maintainer mode from being triggered during make
	AT_M4DIR=autotools eautoreconf
}

src_configure() {
	# It doesn't compile on alpha without this in LDFLAGS
	use alpha && append-ldflags "-Wl,--no-relax"

	local myconf

	myconf="
		$(use_enable gnome-keyring gnomekeyring)
		$(use_enable gstreamer video)
		$(use_enable debug)
		$(use_enable coverage)
		--enable-filters
		"

	# USE-flag controlled font backend because upstream default is freetype
	# Remove USE-flag once font-backend becomes pango upstream
	if use pango; then
		ewarn "You have enabled the incomplete pango backend"
		ewarn "Please file any and all bugs *upstream*"
		myconf="${myconf} --with-font-backend=pango"
	else
		myconf="${myconf} --with-font-backend=freetype"
	fi

	econf ${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed"
	dodoc WebKit/gtk/{NEWS,ChangeLog} || die "dodoc failed"
}