[gentoo-commits] gentoo-x86 commit in media-video/gxine: metadata.xml ChangeLog gxine-0.5.905.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/04/06 10:31:54

  Modified:             metadata.xml ChangeLog
  Added:                gxine-0.5.905.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  media-video/gxine/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/gxine/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/gxine/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/gxine/metadata.xml?r1=1.6&r2=1.7

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/gxine/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml	10 Jan 2007 21:31:28 -0000	1.6
+++ metadata.xml	6 Apr 2010 10:31:54 -0000	1.7
@@ -5,4 +5,7 @@
 <maintainer>
   <email>media-video@g.o</email>
 </maintainer>
+<use>
+  <flag name="udev">Use <pkg>sys-fs/udev</pkg> for autodiscovery of sound devices; this replaces the deprecated <pkg>sys-apps/hal</pkg> autodiscovery code.</flag>
+</use>
 </pkgmetadata>



1.98                 media-video/gxine/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/gxine/ChangeLog?rev=1.98&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/gxine/ChangeLog?rev=1.98&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/gxine/ChangeLog?r1=1.97&r2=1.98

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/gxine/ChangeLog,v
retrieving revision 1.97
retrieving revision 1.98
diff -u -r1.97 -r1.98
--- ChangeLog	17 May 2009 18:01:29 -0000	1.97
+++ ChangeLog	6 Apr 2010 10:31:54 -0000	1.98
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/gxine
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/gxine/ChangeLog,v 1.97 2009/05/17 18:01:29 nixnut Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/gxine/ChangeLog,v 1.98 2010/04/06 10:31:54 ssuominen Exp $
+
+*gxine-0.5.905 (06 Apr 2010)
+
+  06 Apr 2010; Samuli Suominen <ssuominen@g.o> +gxine-0.5.905.ebuild,
+  +files/gxine-0.5.905-desktop.patch:
+  Version bump.
 
   17 May 2009; nixnut <nixnut@g.o> gxine-0.5.903.ebuild:
   ppc stable #260644



1.1                  media-video/gxine/gxine-0.5.905.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/gxine/gxine-0.5.905.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/gxine/gxine-0.5.905.ebuild?rev=1.1&content-type=text/plain

Index: gxine-0.5.905.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/gxine/gxine-0.5.905.ebuild,v 1.1 2010/04/06 10:31:54 ssuominen Exp $

EAPI=2
inherit autotools eutils fdo-mime gnome2-utils multilib nsplugins

DESCRIPTION="GTK+ Front-End for libxine"
HOMEPAGE="http://xine.sourceforge.net/"
SRC_URI="mirror://sourceforge/xine/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="gnome lirc nls nsplugin udev xcb xinerama"

RDEPEND=">=media-libs/xine-lib-1.1.17
	>=x11-libs/gtk+-2.8:2
	>=dev-libs/glib-2.10:2
	>=x11-libs/pango-1.12
	>=dev-lang/spidermonkey-1.7.0
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXrender
	gnome? ( dev-libs/dbus-glib
		gnome-extra/gnome-screensaver )
	lirc? ( app-misc/lirc )
	nls? ( virtual/libintl )
	nsplugin? ( dev-libs/nspr )
	udev? ( >=sys-fs/udev-143[extras] )
	xcb? ( x11-libs/libxcb )
	xinerama? ( x11-libs/libXinerama )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-libs/libXt
	nls? ( sys-devel/gettext )
	nsplugin? ( x11-libs/libXaw )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-desktop.patch

	# need to disable calling of xine-list when running without
	# userpriv, otherwise we get sandbox violations (bug #233847)
	if [[ ${EUID} == "0" ]]; then
		sed -i 's:^XINE_LIST=.*$:XINE_LIST=:' "${S}/configure.ac"
	fi

	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		$(use_enable lirc) \
		--enable-watchdog \
		$(use_with xcb) \
		--with-spidermonkey=/usr/include/js \
		$(use_with nsplugin browser-plugin) \
		$(use_with udev gudev) \
		--without-hal \
		$(use_with gnome dbus) \
		$(use_with xinerama)
}

src_install() {
	emake DESTDIR="${D}" \
		docdir=/usr/share/doc/${PF} \
		docsdir=/usr/share/doc/${PF} \
		install || die

	dodoc AUTHORS BUGS ChangeLog NEWS README{,.{cs,de},_l10n} TODO
	use nsplugin && inst_plugin /usr/$(get_libdir)/gxine/gxineplugin.so
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}