[gentoo-commits] gentoo-x86 commit in games-puzzle/sgt-puzzles: sgt-puzzles-9023.ebuild ChangeLog

[Michael Sterrett (mr_bones_)]

mr_bones_    10/11/28 05:52:31

  Modified:             ChangeLog
  Added:                sgt-puzzles-9023.ebuild
  Log:
  version bump (bug #346831)
  
  (Portage version: 2.1.9.24/cvs/Linux i686)

Revision  Changes    Path
1.8                  games-puzzle/sgt-puzzles/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	21 Sep 2010 20:31:58 -0000	1.7
+++ ChangeLog	28 Nov 2010 05:52:31 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for games-puzzle/sgt-puzzles
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v 1.7 2010/09/21 20:31:58 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v 1.8 2010/11/28 05:52:31 mr_bones_ Exp $
+
+*sgt-puzzles-9023 (28 Nov 2010)
+
+  28 Nov 2010; Michael Sterrett <mr_bones_@g.o>
+  +sgt-puzzles-9023.ebuild, +files/sgt-puzzles-9023-gentoo.patch:
+  version bump (bug #346831)
 
   21 Sep 2010; Markos Chandras <hwoarang@g.o>
   sgt-puzzles-8972.ebuild:



1.1                  games-puzzle/sgt-puzzles/sgt-puzzles-9023.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-9023.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-9023.ebuild?rev=1.1&content-type=text/plain

Index: sgt-puzzles-9023.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-9023.ebuild,v 1.1 2010/11/28 05:52:31 mr_bones_ Exp $

EAPI=2
inherit eutils toolchain-funcs games
if [[ ${PV} == "99999999" ]] ; then
	ESVN_REPO_URI="svn://svn.tartarus.org/sgt/puzzles"
	inherit subversion
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-r${PV}.tar.gz"
	S=${WORKDIR}/puzzles-r${PV}
	KEYWORDS="~amd64 ~x86"
fi

DESCRIPTION="Simon Tatham's Portable Puzzle Collection"
HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"

LICENSE="MIT"
SLOT="0"
IUSE="doc"

RDEPEND="x11-libs/gtk+:2"
DEPEND="${RDEPEND}
	dev-lang/perl
	dev-util/pkgconfig
	doc? ( >=app-doc/halibut-1.0 )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	./mkfiles.pl
	sed -i \
		-e 's:= -O2 -Wall -Werror -ansi -pedantic -g:= $(CPPFLAGS):' \
		-e '/LDFLAGS/s:=:=$(LDFLAGS) :' \
		Makefile || die
}

src_compile() {
	emake CC="$(tc-getCC)" || die
	if use doc ; then
		halibut --text --html --info --pdf --ps puzzles.but
	fi
}

src_install() {
	dodir "${GAMES_BINDIR}"
	emake DESTDIR="${D}" gamesdir="${GAMES_BINDIR}" install || die
	dodoc README HACKING

	local file name
	for file in *.R ; do
		[[ ${file} == "nullgame.R" ]] && continue
		name=$(sed -n 's/^[a-z]*\.exe://p' "${file}")
		file=${file%.R}
		if [[ ${PV} -lt 99999999 ]] ; then
			newicon icons/${file}-48d24.png ${PN}-${file}.png || die
			make_desktop_entry "${GAMES_BINDIR}/${file}" "${name}" "${PN}-${file}"
		else
			# No icons with the live version
			make_desktop_entry "${GAMES_BINDIR}/${file}" "${name}"
		fi
	done

	dodoc puzzles.txt puzzles.chm
	if use doc ; then
		dohtml *.html
		doinfo puzzles.info
		dodoc puzzles.pdf puzzles.ps
	fi

	prepgamesdirs
}