[gentoo-commits] gentoo-x86 commit in x11-misc/dmenu: ChangeLog dmenu-9999.ebuild

[Jeroen Roovers (jer)]

jer         14/06/30 13:31:15

  Modified:             ChangeLog
  Added:                dmenu-9999.ebuild
  Log:
  Add live ebuild (bug #515856 by Ari Malinen).
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.112                x11-misc/dmenu/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dmenu/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dmenu/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dmenu/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/dmenu/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	22 Jan 2014 14:46:23 -0000	1.111
+++ ChangeLog	30 Jun 2014 13:31:15 -0000	1.112
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/dmenu
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/dmenu/ChangeLog,v 1.111 2014/01/22 14:46:23 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/dmenu/ChangeLog,v 1.112 2014/06/30 13:31:15 jer Exp $
+
+*dmenu-9999 (30 Jun 2014)
+
+  30 Jun 2014; Jeroen Roovers <jer@g.o> +dmenu-9999.ebuild:
+  Add live ebuild (bug #515856 by Ari Malinen).
 
 *dmenu-4.5-r4 (22 Jan 2014)
 



1.1                  x11-misc/dmenu/dmenu-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dmenu/dmenu-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/dmenu/dmenu-9999.ebuild?rev=1.1&content-type=text/plain

Index: dmenu-9999.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/dmenu/dmenu-9999.ebuild,v 1.1 2014/06/30 13:31:15 jer Exp $

EAPI=5
inherit eutils git-r3 savedconfig toolchain-funcs

DESCRIPTION="a generic, highly customizable, and efficient menu for the X Window System"
HOMEPAGE="http://tools.suckless.org/dmenu/"
EGIT_REPO_URI="git://git.suckless.org/dmenu"

LICENSE="MIT"
SLOT="0"
KEYWORDS=""
IUSE="xft xinerama"

RDEPEND="
	x11-libs/libX11
	xft? ( x11-libs/libXft )
	xinerama? ( x11-libs/libXinerama )
"
DEPEND="${RDEPEND}
	xft? ( virtual/pkgconfig )
	xinerama? ( virtual/pkgconfig )
"

src_prepare() {
	# Respect our flags
	sed -i \
		-e '/^CFLAGS/{s|=.*|+= -ansi -pedantic -Wall $(INCS) $(CPPFLAGS)|}' \
		-e '/^LDFLAGS/s|= -s|+=|' \
		config.mk || die
	# Make make verbose
	sed -i \
		-e 's|^	@|	|g' \
		-e '/^	echo/d' \
		Makefile || die

	restore_config config.def.h
	epatch_user
}

src_compile() {
	emake CC=$(tc-getCC) \
		"XFTINC=$( $(tc-getPKG_CONFIG) --cflags xft 2>/dev/null )" \
		"XFTLIBS=$( $(tc-getPKG_CONFIG) --libs xft 2>/dev/null )" \
		"XINERAMAFLAGS=$(
			usex xinerama "-DXINERAMA $(
				$(tc-getPKG_CONFIG) --cflags xinerama 2>/dev/null
			)" ''
		)" \
		"XINERAMALIBS=$(
			usex xinerama "$( $(tc-getPKG_CONFIG) --libs xinerama 2>/dev/null)" ''
		)"
}

src_install() {
	emake DESTDIR="${D}" PREFIX="/usr" install

	save_config config.def.h
}