[gentoo-commits] gentoo-x86 commit in games-fps/alienarena: alienarena-20090616.ebuild ChangeLog

[Tristan Heaven (nyhm)]

nyhm        09/06/21 09:29:31

  Modified:             ChangeLog
  Added:                alienarena-20090616.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc33/cvs/Linux i686)

Revision  Changes    Path
1.13                 games-fps/alienarena/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	22 Dec 2008 17:20:30 -0000	1.12
+++ ChangeLog	21 Jun 2009 09:29:31 -0000	1.13
@@ -1,6 +1,12 @@
 # ChangeLog for games-fps/alienarena
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v 1.12 2008/12/22 17:20:30 nyhm Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/ChangeLog,v 1.13 2009/06/21 09:29:31 nyhm Exp $
+
+*alienarena-20090616 (21 Jun 2009)
+
+  21 Jun 2009; Tristan Heaven <nyhm@g.o> +alienarena-20090616.ebuild,
+  +files/alienarena-20090616-path-overflows.patch:
+  Version bump
 
 *alienarena-20081016 (22 Dec 2008)
 



1.1                  games-fps/alienarena/alienarena-20090616.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/alienarena-20090616.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alienarena/alienarena-20090616.ebuild?rev=1.1&content-type=text/plain

Index: alienarena-20090616.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/alienarena/alienarena-20090616.ebuild,v 1.1 2009/06/21 09:29:31 nyhm Exp $

EAPI=2
inherit eutils toolchain-funcs games

MY_PN=${PN}${PV:0:4}
DESCRIPTION="Fast-paced multiplayer deathmatch game"
HOMEPAGE="http://red.planetarena.org/"
SRC_URI="http://icculus.org/${PN}/Files/${MY_PN}-linux${PV}.zip"

LICENSE="GPL-2 free-noncomm"
SLOT="0"
KEYWORDS="" # ~amd64 ~x86
IUSE="dedicated opengl"

UIRDEPEND="media-libs/jpeg
	media-libs/openal
	media-libs/libvorbis
	virtual/glu
	virtual/opengl
	x11-libs/libXxf86dga
	x11-libs/libXxf86vm"
RDEPEND="opengl? ( ${UIRDEPEND} )
	!opengl? ( !dedicated? ( ${UIRDEPEND} ) )
	net-misc/curl"
UIDEPEND="x11-proto/xf86dgaproto
	x11-proto/xf86vidmodeproto"
DEPEND="${RDEPEND}
	opengl? ( ${UIDEPEND} )
	!opengl? ( !dedicated? ( ${UIDEPEND} ) )
	dev-util/pkgconfig
	app-arch/unzip"

S=${WORKDIR}/${MY_PN}/source

src_prepare() {
	rm -f ../*/*.so
	epatch "${FILESDIR}"/${P}-path-overflows.patch
}

src_compile() {
	emake \
		ARCH="unknown" \
		OSTYPE="linux" \
		CC="$(tc-getCC)" \
		OPTIMIZED_CFLAGS=no \
		WITH_DATADIR=yes \
		WITH_LIBDIR=yes \
		DATADIR="${GAMES_DATADIR}"/${PN} \
		LIBDIR="$(games_get_libdir)"/${PN} \
		$(use opengl && ! use dedicated && echo BUILD=CLIENT) \
		$(! use opengl && use dedicated && echo BUILD=DEDICATED) \
		$(use opengl && use dedicated && echo BUILD=ALL) \
		$(use opengl || use dedicated || echo BUILD=CLIENT) \
		|| die "emake failed"
}

src_install() {
	cd release
	exeinto "$(games_get_libdir)"/${PN}
	doexe game.so || die "doexe failed"
	dosym . "$(games_get_libdir)"/${PN}/arena
	dosym . "$(games_get_libdir)"/${PN}/data1

	if use opengl || ! use dedicated ; then
		newgamesbin crx ${PN} || die "newgamesbin crx failed"
		make_desktop_entry ${PN} "Alien Arena"
	fi

	if use dedicated ; then
		newgamesbin crded ${PN}-ded || die "newgamesbin crded failed"
	fi

	cd "${WORKDIR}"/${MY_PN}
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r arena botinfo data1 || die "doins failed"
	newicon aa.png ${PN}.png || die "newicon failed"
	dodoc docs/README.txt

	prepgamesdirs
}