[gentoo-commits] gentoo-x86 commit in sci-mathematics/fricas: ChangeLog fricas-1.2.6.ebuild fricas-1.2.4.ebuild

[Andrey Grozin (grozin)]

grozin      15/06/29 11:01:25

  Modified:             ChangeLog
  Added:                fricas-1.2.6.ebuild
  Removed:              fricas-1.2.4.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.20/cvs/Linux i686, signed Manifest commit with key 0x3AFFCE974D34BD8C!)

Revision  Changes    Path
1.25                 sci-mathematics/fricas/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-mathematics/fricas/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	7 Mar 2015 12:54:14 -0000	1.24
+++ ChangeLog	29 Jun 2015 11:01:25 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for sci-mathematics/fricas
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/fricas/ChangeLog,v 1.24 2015/03/07 12:54:14 grozin Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/fricas/ChangeLog,v 1.25 2015/06/29 11:01:25 grozin Exp $
+
+*fricas-1.2.6 (29 Jun 2015)
+
+  29 Jun 2015; Andrey Grozin <grozin@g.o> -fricas-1.2.4.ebuild,
+  +fricas-1.2.6.ebuild:
+  Version bump
 
 *fricas-1.2.5 (07 Mar 2015)
 



1.1                  sci-mathematics/fricas/fricas-1.2.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/fricas-1.2.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/fricas-1.2.6.ebuild?rev=1.1&content-type=text/plain

Index: fricas-1.2.6.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/fricas/fricas-1.2.6.ebuild,v 1.1 2015/06/29 11:01:25 grozin Exp $
EAPI=5
inherit multilib elisp-common

DESCRIPTION="FriCAS is a fork of Axiom computer algebra system"
HOMEPAGE="http://${PN}.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}-full.tar.bz2"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

# Supported lisps, number 0 is the default
LISPS=( sbcl cmucl     gcl ecls   clisp clozurecl )
# command name: . means just ${LISP}
COMS=(  .    lisp      .   ecl    .     ccl       )

IUSE="${LISPS[*]} X emacs gmp"
RDEPEND="X? ( x11-libs/libXpm x11-libs/libICE )
	emacs? ( virtual/emacs )
	gmp? ( dev-libs/gmp )"

# Generating lisp deps
n=${#LISPS[*]}
for ((n--; n > 0; n--)); do
	LISP=${LISPS[$n]}
	RDEPEND="${RDEPEND} ${LISP}? ( dev-lisp/${LISP}:= ) !${LISP}? ("
done
RDEPEND="${RDEPEND} dev-lisp/${LISPS[0]}:="
n=${#LISPS[*]}
for ((n--; n > 0; n--)); do
	RDEPEND="${RDEPEND} )"
done

DEPEND="${RDEPEND}"

# necessary for clisp and gcl
RESTRICT="strip"

src_configure() {
	local LISP n
	LISP=sbcl
	n=${#LISPS[*]}
	for ((n--; n > 0; n--)); do
		if use ${LISPS[$n]}; then
			LISP=${COMS[$n]}
			if [ "${LISP}" = "." ]; then
				LISP=${LISPS[$n]}
			fi
		fi
	done
	einfo "Using lisp: ${LISP}"

	# aldor is not yet in portage
	econf --disable-aldor --with-lisp=${LISP} $(use_with X x) $(use_with gmp)
}

src_compile() {
	# bug #300132
	emake -j1
}

src_test() {
	emake -j1 all-input
}

src_install() {
	emake -j1 DESTDIR="${D}" install
	dodoc README FAQ

	if use emacs; then
		sed -e "s|(setq load-path (cons (quote \"/usr/$(get_libdir)/fricas/emacs\") load-path)) ||" \
			-i "${D}"/usr/bin/efricas \
			|| die "sed efricas failed"
		elisp-install ${PN} "${D}"/usr/$(get_libdir)/${PN}/emacs/*.el
		elisp-site-file-install "${FILESDIR}"/64${PN}-gentoo.el
	else
		rm "${D}"/usr/bin/efricas || die "rm efricas failed"
	fi
	rm -r "${D}"/usr/$(get_libdir)/${PN}/emacs || die "rm -r emacs failed"
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}