[gentoo-commits] gentoo-x86 commit in media-libs/glew: ChangeLog glew-1.8.0.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/07/30 21:41:35

  Modified:             ChangeLog
  Added:                glew-1.8.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha116/cvs/Linux x86_64)

Revision  Changes    Path
1.79                 media-libs/glew/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?rev=1.79&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?rev=1.79&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/ChangeLog?r1=1.78&r2=1.79

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v
retrieving revision 1.78
retrieving revision 1.79
diff -u -r1.78 -r1.79
--- ChangeLog	29 May 2012 13:57:44 -0000	1.78
+++ ChangeLog	30 Jul 2012 21:41:35 -0000	1.79
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/glew
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v 1.78 2012/05/29 13:57:44 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/ChangeLog,v 1.79 2012/07/30 21:41:35 ssuominen Exp $
+
+*glew-1.8.0 (30 Jul 2012)
+
+  30 Jul 2012; Samuli Suominen <ssuominen@g.o> +glew-1.8.0.ebuild:
+  Version bump.
 
   29 May 2012; Alexis Ballier <aballier@g.o> glew-1.7.0.ebuild:
   build it the linux way (PIC and so on) on freebsd and keyword ~amd64-fbsd



1.1                  media-libs/glew/glew-1.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/glew-1.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glew/glew-1.8.0.ebuild?rev=1.1&content-type=text/plain

Index: glew-1.8.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/glew/glew-1.8.0.ebuild,v 1.1 2012/07/30 21:41:35 ssuominen Exp $

EAPI=4
inherit multilib toolchain-funcs

DESCRIPTION="The OpenGL Extension Wrangler Library"
HOMEPAGE="http://glew.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"

LICENSE="BSD MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="doc static-libs"

RDEPEND="virtual/glu
	virtual/opengl
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXi
	x11-libs/libXmu"
DEPEND=${RDEPEND}

pkg_setup() {
	myglewopts=(
		AR="$(tc-getAR)"
		STRIP=true
		CC="$(tc-getCC)"
		LD="$(tc-getCC) ${LDFLAGS}"
		M_ARCH=""
		LDFLAGS.EXTRA=""
		POPT="${CFLAGS}"
	)
}

src_prepare() {
	sed -i \
		-e '/INSTALL/s:-s::' \
		-e '/$(CC) $(CFLAGS) -o/s:$(CFLAGS):$(CFLAGS) $(LDFLAGS):' \
		Makefile || die

	if ! use static-libs ; then
		sed -i \
			-e '/glew.lib:/s|lib/$(LIB.STATIC) ||' \
			-e '/glew.lib.mx:/s|lib/$(LIB.STATIC.MX) ||' \
			-e '/INSTALL.*LIB.STATIC/d' \
			Makefile || die
	fi

	# don't do stupid Solaris specific stuff that won't work in Prefix
	cp config/Makefile.linux config/Makefile.solaris || die
	# and let freebsd be built as on linux too
	cp config/Makefile.linux config/Makefile.freebsd || die
}

src_compile(){
	emake "${myglewopts[@]}"
}

src_install() {
	emake \
		GLEW_DEST="${ED}/usr" \
		LIBDIR="${ED}/usr/$(get_libdir)" \
		"${myglewopts[@]}" \
		install.all

	dodoc TODO.txt
	use doc && dohtml doc/*
}