[gentoo-commits] repo/gentoo:master commit in: app-portage/elogviewer/

[Andreas Sturmlechner]

commit:     4c0ae35fb3d4c533fe152a897d246d875d5877f1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu May 10 11:57:38 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu May 10 14:48:41 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4c0ae35f

app-portage/elogviewer: Drop dev-python/pyside and dev-python/PyQt4

Package-Manager: Portage-2.3.36, Repoman-2.3.9

 app-portage/elogviewer/elogviewer-2.7-r2.ebuild | 64 +++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/app-portage/elogviewer/elogviewer-2.7-r2.ebuild b/app-portage/elogviewer/elogviewer-2.7-r2.ebuild
new file mode 100644
index 00000000000..cad621a1469
--- /dev/null
+++ b/app-portage/elogviewer/elogviewer-2.7-r2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+DISABLE_AUTOFORMATTING=true
+
+inherit python-single-r1 eutils readme.gentoo-r1
+
+DESCRIPTION="Elog viewer for Gentoo"
+HOMEPAGE="https://sourceforge.net/projects/elogviewer"
+SRC_URI="https://github.com/Synss/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~sparc x86 ~x86-fbsd"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	|| (
+		>=sys-apps/portage-2.1[${PYTHON_USEDEP}]
+		sys-apps/portage-mgorny[${PYTHON_USEDEP}]
+	)
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python2_7)
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+DOC_CONTENTS="In order to use this software, you need to activate
+Portage's elog features.  Required is
+	PORTAGE_ELOG_SYSTEM=\"save\"
+and at least one of
+	PORTAGE_ELOG_CLASSES=\"warn error info log qa\"
+More information on the elog system can be found in
+/usr/share/portage/config/make.conf.example
+
+To operate properly this software needs the directory
+${PORT_LOGDIR:-/var/log/portage}/elog created, belonging to group portage.
+To start the software as a user, add yourself to the portage group."
+
+src_compile() {
+	rm -f Makefile
+}
+
+src_install() {
+	python_newscript elogviewer.py elogviewer
+
+	make_desktop_entry ${PN} ${PN} ${PN} System
+
+	doman elogviewer.1
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	ewarn "The elogviewer's configuration file is now saved in:"
+	ewarn "~/.config/elogviewer/ (was ~/.config/Mathias\ Laurin/)."
+	ewarn "Please migrate any user specific settings to the new config file."
+}