[gentoo-commits] gentoo-x86 commit in net-im/silc-server: ChangeLog silc-server-1.1.2.ebuild

[Raul Porcel (armin76)]

armin76     08/03/26 10:58:50

  Modified:             ChangeLog
  Added:                silc-server-1.1.2.ebuild
  Log:
  Version bump
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.31                 net-im/silc-server/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/silc-server/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/silc-server/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/silc-server/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/silc-server/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	14 Feb 2008 21:52:02 -0000	1.30
+++ ChangeLog	26 Mar 2008 10:58:49 -0000	1.31
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/silc-server
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/silc-server/ChangeLog,v 1.30 2008/02/14 21:52:02 coldwind Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/silc-server/ChangeLog,v 1.31 2008/03/26 10:58:49 armin76 Exp $
+
+*silc-server-1.1.2 (26 Mar 2008)
+
+  26 Mar 2008; Raúl Porcel <armin76@g.o> +silc-server-1.1.2.ebuild:
+  Version bump
 
   14 Feb 2008; Santiago M. Mola <coldwind@g.o>
   silc-server-1.1.ebuild:



1.1                  net-im/silc-server/silc-server-1.1.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/silc-server/silc-server-1.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/silc-server/silc-server-1.1.2.ebuild?rev=1.1&content-type=text/plain

Index: silc-server-1.1.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/silc-server/silc-server-1.1.2.ebuild,v 1.1 2008/03/26 10:58:49 armin76 Exp $

inherit eutils autotools flag-o-matic

DESCRIPTION="Server for Secure Internet Live Conferencing"
SRC_URI="http://www.silcnet.org/download/server/sources/${P}.tar.bz2"
HOMEPAGE="http://silcnet.org/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="ipv6 debug"

RDEPEND="!<=net-im/silc-toolkit-0.9.12-r1
	!<=net-im/silc-client-1.0.1"
DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/1.1-execstack.patch
}

src_compile() {
	econf \
		--datadir=/usr/share/${PN} \
		--datarootdir=/usr/share/${PN} \
		--mandir=/usr/share/man \
		--sysconfdir=/etc/silc \
		--with-helpdir=/usr/share/${PN}/help \
		--libdir=/usr/$(get_libdir)/${PN} \
		--docdir=/usr/share/doc/${PF} \
		--disable-optimizations \
		--with-logsdir=/var/log/${PN} \
		--with-silcd-pid-file=/var/run/silcd.pid \
		$(use_enable ipv6) \
		$(use_enable debug) \
		|| die "econf failed"
	emake -j1 || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	insinto /usr/share/doc/${PF}/examples
	doins doc/examples/*.conf

	fperms 600 /etc/silc
	keepdir /var/log/${PN}

	rm -rf \
		"${D}"/usr/libsilc* \
		"${D}"/usr/include \
		"${D}"/etc/silc/silcd.{pub,prv}

	newinitd "${FILESDIR}/silcd.initd" silcd

	sed -i \
		-e 's:10.2.1.6:0.0.0.0:' \
		-e 's:User = "nobody";:User = "silcd";:' \
		"${D}"/etc/silc/silcd.conf
}

pkg_postinst() {
	enewuser silcd

	if [ ! -f "${ROOT}"/etc/silc/silcd.prv ] ; then
		einfo "Creating key pair in /etc/silc"
		silcd -C "${ROOT}"/etc/silc
		chmod 600 "${ROOT}"/etc/silc/silcd.{prv,pub}
	fi
}



-- 
gentoo-commits@l.g.o mailing list