[gentoo-commits] gentoo-x86 commit in app-misc/pax-utils: pax-utils-1.0.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      15/03/02 09:50:16

  Modified:             ChangeLog
  Added:                pax-utils-1.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.170                app-misc/pax-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/pax-utils/ChangeLog?rev=1.170&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/pax-utils/ChangeLog?rev=1.170&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/pax-utils/ChangeLog?r1=1.169&r2=1.170

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/pax-utils/ChangeLog,v
retrieving revision 1.169
retrieving revision 1.170
diff -u -r1.169 -r1.170
--- ChangeLog	20 Nov 2014 01:36:28 -0000	1.169
+++ ChangeLog	2 Mar 2015 09:50:16 -0000	1.170
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/pax-utils
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/pax-utils/ChangeLog,v 1.169 2014/11/20 01:36:28 vapier Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/pax-utils/ChangeLog,v 1.170 2015/03/02 09:50:16 vapier Exp $
+
+*pax-utils-1.0 (02 Mar 2015)
+
+  02 Mar 2015; Mike Frysinger <vapier@g.o> +pax-utils-1.0.ebuild:
+  Version bump.
 
 *pax-utils-0.9.2 (20 Nov 2014)
 



1.1                  app-misc/pax-utils/pax-utils-1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/pax-utils/pax-utils-1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/pax-utils/pax-utils-1.0.ebuild?rev=1.1&content-type=text/plain

Index: pax-utils-1.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/pax-utils/pax-utils-1.0.ebuild,v 1.1 2015/03/02 09:50:16 vapier Exp $

EAPI="4"

inherit eutils toolchain-funcs unpacker

DESCRIPTION="ELF related utils for ELF 32/64 binaries that can check files for security relevant properties"
HOMEPAGE="http://hardened.gentoo.org/pax-utils.xml"
SRC_URI="mirror://gentoo/pax-utils-${PV}.tar.xz
	http://dev.gentoo.org/~solar/pax/pax-utils-${PV}.tar.xz
	http://dev.gentoo.org/~vapier/dist/pax-utils-${PV}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
IUSE="caps python"

RDEPEND="caps? ( sys-libs/libcap )
	python? ( dev-python/pyelftools )"
DEPEND="${RDEPEND}
	app-arch/xz-utils"

_emake() {
	emake \
		USE_CAP=$(usex caps) \
		USE_PYTHON=$(usex python) \
		"$@"
}

src_configure() {
	# Avoid slow configure+gnulib+make if on an up-to-date Linux system
	if use prefix || ! use kernel_linux || \
	   has_version '<sys-libs/glibc-2.10'
	then
		econf $(use_with caps) $(use_with python)
	else
		tc-export CC
	fi
}

src_compile() {
	_emake
}

src_test() {
	_emake check
}

src_install() {
	_emake DESTDIR="${ED}" PKGDOCDIR='$(DOCDIR)'/${PF} install
}