[gentoo-commits] repo/gentoo:master commit in: net-analyzer/nsat/

[Andreas Hüttel]

commit:     3e087566f12985f32416c815e864d7bff867059d
Author:     Andreas K. Hüttel <dilfridge <AT> gentoo <DOT> org>
AuthorDate: Fri Mar  2 22:22:00 2018 +0000
Commit:     Andreas Hüttel <dilfridge <AT> gentoo <DOT> org>
CommitDate: Fri Mar  2 22:22:30 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3e087566

net-analyzer/nsat: Remove libtirpc automagic and depend on it instead

Bug: https://bugs.gentoo.org/371025
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 net-analyzer/nsat/nsat-1.5-r5.ebuild | 75 ++++++++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)

diff --git a/net-analyzer/nsat/nsat-1.5-r5.ebuild b/net-analyzer/nsat/nsat-1.5-r5.ebuild
new file mode 100644
index 00000000000..87d30b46c18
--- /dev/null
+++ b/net-analyzer/nsat/nsat-1.5-r5.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Network Security Analysis Tool, an application-level network security scanner"
+HOMEPAGE="http://nsat.sourceforge.net/"
+SRC_URI="mirror://sourceforge/nsat/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="X"
+
+RDEPEND="
+	dev-libs/libmix
+	net-libs/libnsl:0=
+	net-libs/libpcap
+	net-libs/libtirpc
+	net-libs/rpcsvc-proto
+	X? (
+		dev-lang/tk:*
+		x11-libs/libX11
+	)
+"
+DEPEND="$RDEPEND"
+S="${WORKDIR}/${PN}"
+PATCHES=(
+	"${FILESDIR}"/${P}-configure.patch
+	"${FILESDIR}"/${P}-lvalue-gcc4.patch
+	"${FILESDIR}"/${P}-strip.patch
+	"${FILESDIR}"/${P}-misc.patch
+	"${FILESDIR}"/${P}-va_list.patch
+	"${FILESDIR}"/${P}-libtirpc.patch
+	"${FILESDIR}"/${P}-amd64-compat.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s:^#CGIFile /usr/local/share/nsat/nsat.cgi$:#CGIFile /usr/share/nsat/nsat.cgi:g" \
+		nsat.conf || die
+	sed -i -e "s:/usr/local:/usr:g" tools/xnsat || die
+	sed -i \
+		-e "s:/usr/local/share/nsat/nsat.conf:/etc/nsat/nsat.conf:g" \
+		-e "s:/usr/local/share/nsat/nsat.cgi:/usr/share/nsat/nsat.cgi:g" \
+		src/lang.h || die
+
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+	econf $(use_with X x)
+}
+
+src_compile() {
+	emake MIXOBJ=-lmix++
+}
+
+src_install () {
+	dobin nsat smb-ns
+	use X && dobin tools/xnsat
+
+	insinto /usr/share/nsat
+	doins nsat.cgi
+
+	insinto /etc/nsat
+	doins nsat.conf
+
+	dodoc README doc/CHANGES
+	doman doc/nsat.8
+}