[gentoo-commits] gentoo-x86 commit in sys-cluster/vzctl: ChangeLog vzctl-3.0.24.1-r1.ebuild vzctl-3.0.24.1.ebuild

[Peter Volkov (pva)]

pva         10/08/30 11:55:45

  Modified:             ChangeLog
  Added:                vzctl-3.0.24.1-r1.ebuild
  Removed:              vzctl-3.0.24.1.ebuild
  Log:
  Fixed type in vzpostup patch, thank Kir Kolyshkin for review.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.72                 sys-cluster/vzctl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	30 Jul 2010 10:29:50 -0000	1.71
+++ ChangeLog	30 Aug 2010 11:55:45 -0000	1.72
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/vzctl
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/ChangeLog,v 1.71 2010/07/30 10:29:50 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/ChangeLog,v 1.72 2010/08/30 11:55:45 pva Exp $
+
+*vzctl-3.0.24.1-r1 (30 Aug 2010)
+
+  30 Aug 2010; Peter Volkov <pva@g.o> -vzctl-3.0.24.1.ebuild,
+  +vzctl-3.0.24.1-r1.ebuild, files/vzctl-3.0.24.1-vzpostup.patch:
+  Fixed type in vzpostup patch, thank Kir Kolyshkin for review.
 
 *vzctl-3.0.24.1 (30 Jul 2010)
 



1.1                  sys-cluster/vzctl/vzctl-3.0.24.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/vzctl-3.0.24.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/vzctl-3.0.24.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: vzctl-3.0.24.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/vzctl-3.0.24.1-r1.ebuild,v 1.1 2010/08/30 11:55:45 pva Exp $

EAPI="2"

inherit bash-completion eutils

DESCRIPTION="OpenVZ ConTainers control utility"
HOMEPAGE="http://openvz.org/"
SRC_URI="http://download.openvz.org/utils/${PN}/${PV}/src/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc64 ~sparc ~x86"
IUSE="bash-completion"

RDEPEND="
	net-firewall/iptables
	sys-apps/ed
	sys-apps/iproute2
	sys-fs/vzquota
	virtual/cron"

DEPEND="${RDEPEND}"

src_prepare() {
	# Set default OSTEMPLATE on gentoo
	sed -e 's:=redhat-:=gentoo-:' -i etc/dists/default || die
	epatch "${FILESDIR}/${P}-vzpostup.patch"
}

src_configure() {
	econf \
		--localstatedir=/var \
		--enable-cron \
		--enable-udev \
		$(use_enable bash-completion bashcomp) \
		--enable-logrotate
}

src_install() {
	make DESTDIR="${D}" install install-gentoo || die "make install failed"

	# install the bash-completion script into the right location
	rm -rf "${D}"/etc/bash_completion.d
	dobashcompletion "${S}"/etc/bash_completion.d/vzctl.sh vzctl

	# We need to keep some dirs
	keepdir /vz/{dump,lock,root,private,template/cache}
	keepdir /etc/vz/names /var/lib/vzctl/veip
}

pkg_postinst() {
	bash-completion_pkg_postinst
	local conf_without_OSTEMPLATE
	for file in \
		$(find "${ROOT}/etc/vz/conf/" \( -name *.conf -a \! -name 0.conf \)); do
		if ! grep '^OSTEMPLATE' $file > /dev/null; then
			conf_without_OSTEMPLATE+=" $file"
		fi
	done

	if [[ -n ${conf_without_OSTEMPLATE} ]]; then
		ewarn
		ewarn "OSTEMPLATE default was changed from redhat-like to gentoo."
		ewarn "This means that any VEID.conf files without explicit or correct"
		ewarn "OSTEMPLATE set will use gentoo scripts instead of redhat."
		ewarn "Please check the following configs:"
		for file in ${conf_without_OSTEMPLATE}; do
			ewarn "${file}"
		done
		ewarn
	fi

	ewarn "To avoid loosing network to CTs on iface down/up, please, add the"
	ewarn "following code to /etc/conf.d/net:"
	ewarn " postup() {"
	ewarn "     /usr/sbin/vzifup-post \${IFACE}"
	ewarn " }"

	elog "NOTE: Starting with vzctl-3.0.22 the mechanism for choosing the"
	elog "interfaces to send ARP requests to has been improved (see description"
	elog "of NEIGHBOUR_DEVS in vz.conf(5) man page). In case CT IP addresses"
	elog "are not on the same subnet as HN IPs, it may lead to such CTs being"
	elog "unreachable from the outside world."
	elog
	elog "The solution is to set up a device route(s) for the network your CTs are"
	elog "in. For more details, see http://bugzilla.openvz.org/show_bug.cgi?id=771#c1"
	elog
	elog "The old vzctl behavior can be restored by setting NEIGHBOUR_DEVS to any"
	elog 'value other than "detect" in /etc/vz/vz.conf.'
}