[gentoo-commits] repo/gentoo:master commit in: net-p2p/bittornado/, net-p2p/bittornado/files/

[Austin English]

commit:     a7a6f0bc66eef89b21c8b3a7ee31341b11a22223
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Tue May  3 17:07:04 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Tue May  3 17:07:04 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a7a6f0bc

net-p2p/bittornado: use #!/sbin/openrc-run instead of #!/sbin/runscript

Gentoo-Bug: https://bugs.gentoo.org/573846

Package-Manager: portage-2.2.26

 net-p2p/bittornado/bittornado-0.3.18-r4.ebuild | 56 ++++++++++++++++++++++++++
 net-p2p/bittornado/files/bttrack.rc            |  4 +-
 2 files changed, 58 insertions(+), 2 deletions(-)

diff --git a/net-p2p/bittornado/bittornado-0.3.18-r4.ebuild b/net-p2p/bittornado/bittornado-0.3.18-r4.ebuild
new file mode 100644
index 0000000..b66a1e4
--- /dev/null
+++ b/net-p2p/bittornado/bittornado-0.3.18-r4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+# note: wxGTK interface has been removed wrt #391685. this ebuild is only for
+# cmdline tools as is.
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN=BitTornado
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="TheShad0w's experimental BitTorrent client"
+HOMEPAGE="http://www.bittornado.com/"
+SRC_URI="http://download2.bittornado.com/download/${MY_P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE=""
+
+RDEPEND="dev-python/pycrypto[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	>=sys-apps/sed-4.0.5"
+
+S=${WORKDIR}/${MY_PN}-CVS
+PIXMAPLOC=/usr/share/pixmaps/bittornado
+
+python_prepare_all() {
+	# fixes wrong icons path
+	sed -i "s:os.path.abspath(os.path.dirname(os.path.realpath(sys.argv\[0\]))):\"${PIXMAPLOC}/\":" btdownloadgui.py
+	# Needs wxpython-2.6 only, bug #201247
+	eapply "${FILESDIR}"/${P}-wxversion.patch
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# get rid of any reference to the not-installed gui version
+	rm "${ED%/}"/usr/bin/*gui.py || die
+	rm "${ED%/}$(python_get_scriptdir)"/*gui.py || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}"/bttrack.conf bttrack
+	newinitd "${FILESDIR}"/bttrack.rc bttrack
+}

diff --git a/net-p2p/bittornado/files/bttrack.rc b/net-p2p/bittornado/files/bttrack.rc
index d08110f..dcb40f7 100644
--- a/net-p2p/bittornado/files/bttrack.rc
+++ b/net-p2p/bittornado/files/bttrack.rc
@@ -1,5 +1,5 @@
-#!/sbin/runscript
-# Copyright 1999-2004 Gentoo Foundation
+#!/sbin/openrc-run
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$