| 1 |
solar 08/05/05 18:50:23 |
| 2 |
|
| 3 |
Modified: ChangeLog |
| 4 |
Added: uclibc-0.9.28.3-r6.ebuild |
| 5 |
Removed: uclibc-0.9.28-r1.ebuild uclibc-0.9.28.3-r4.ebuild |
| 6 |
uclibc-0.9.28.3-r1.ebuild uclibc-0.9.28.3-r2.ebuild |
| 7 |
uclibc-0.9.28.ebuild uclibc-0.9.28.1.ebuild |
| 8 |
uclibc-0.9.28-r2.ebuild uclibc-0.9.28.3-r5.ebuild |
| 9 |
Log: |
| 10 |
- little cleanup and add the realpath patch from bug 125701 to address the sandbox problem with coreutils |
| 11 |
(Portage version: 2.1.3.19) |
| 12 |
|
| 13 |
Revision Changes Path |
| 14 |
1.34 sys-libs/uclibc/ChangeLog |
| 15 |
|
| 16 |
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/uclibc/ChangeLog?rev=1.34&view=markup |
| 17 |
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/uclibc/ChangeLog?rev=1.34&content-type=text/plain |
| 18 |
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/uclibc/ChangeLog?r1=1.33&r2=1.34 |
| 19 |
|
| 20 |
Index: ChangeLog |
| 21 |
=================================================================== |
| 22 |
RCS file: /var/cvsroot/gentoo-x86/sys-libs/uclibc/ChangeLog,v |
| 23 |
retrieving revision 1.33 |
| 24 |
retrieving revision 1.34 |
| 25 |
diff -u -r1.33 -r1.34 |
| 26 |
--- ChangeLog 4 May 2008 18:54:21 -0000 1.33 |
| 27 |
+++ ChangeLog 5 May 2008 18:50:22 -0000 1.34 |
| 28 |
@@ -1,6 +1,16 @@ |
| 29 |
# ChangeLog for sys-libs/uclibc |
| 30 |
# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2 |
| 31 |
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/uclibc/ChangeLog,v 1.33 2008/05/04 18:54:21 solar Exp $ |
| 32 |
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/uclibc/ChangeLog,v 1.34 2008/05/05 18:50:22 solar Exp $ |
| 33 |
+ |
| 34 |
+*uclibc-0.9.28.3-r6 (05 May 2008) |
| 35 |
+ |
| 36 |
+ 05 May 2008; <solar@g.o> -uclibc-0.9.28.ebuild, |
| 37 |
+ -uclibc-0.9.28-r1.ebuild, -uclibc-0.9.28-r2.ebuild, |
| 38 |
+ -uclibc-0.9.28.1.ebuild, -uclibc-0.9.28.3-r1.ebuild, |
| 39 |
+ -uclibc-0.9.28.3-r2.ebuild, -uclibc-0.9.28.3-r4.ebuild, |
| 40 |
+ -uclibc-0.9.28.3-r5.ebuild, +uclibc-0.9.28.3-r6.ebuild: |
| 41 |
+ - little cleanup and add the realpath patch from bug 125701 to address the |
| 42 |
+ sandbox problem with coreutils |
| 43 |
|
| 44 |
*uclibc-0.9.28.3-r5 (04 May 2008) |
| 45 |
|
| 46 |
|
| 47 |
|
| 48 |
|
| 49 |
1.1 sys-libs/uclibc/uclibc-0.9.28.3-r6.ebuild |
| 50 |
|
| 51 |
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/uclibc/uclibc-0.9.28.3-r6.ebuild?rev=1.1&view=markup |
| 52 |
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/uclibc/uclibc-0.9.28.3-r6.ebuild?rev=1.1&content-type=text/plain |
| 53 |
|
| 54 |
Index: uclibc-0.9.28.3-r6.ebuild |
| 55 |
=================================================================== |
| 56 |
# Copyright 1999-2008 Gentoo Foundation |
| 57 |
# Distributed under the terms of the GNU General Public License v2 |
| 58 |
# $Header: /var/cvsroot/gentoo-x86/sys-libs/uclibc/uclibc-0.9.28.3-r6.ebuild,v 1.1 2008/05/05 18:50:22 solar Exp $ |
| 59 |
|
| 60 |
#ESVN_REPO_URI="svn://uclibc.org/trunk/uClibc" |
| 61 |
#inherit subversion |
| 62 |
inherit eutils flag-o-matic toolchain-funcs |
| 63 |
|
| 64 |
export CBUILD=${CBUILD:-${CHOST}} |
| 65 |
export CTARGET=${CTARGET:-${CHOST}} |
| 66 |
if [[ ${CTARGET} == ${CHOST} ]] ; then |
| 67 |
if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then |
| 68 |
export CTARGET=${CATEGORY/cross-} |
| 69 |
fi |
| 70 |
fi |
| 71 |
# Handle the case where we want uclibc on glibc ... |
| 72 |
if [[ ${CTARGET} == ${CHOST} ]] && [[ ${CHOST} != *-uclibc ]] ; then |
| 73 |
export UCLIBC_AND_GLIBC="sitting in a tree" |
| 74 |
export CTARGET=${CHOST%%-*}-pc-linux-uclibc |
| 75 |
fi |
| 76 |
|
| 77 |
MY_P=uClibc-${PV} |
| 78 |
SVN_VER="" |
| 79 |
PATCH_VER="1.7" |
| 80 |
DESCRIPTION="C library for developing embedded Linux systems" |
| 81 |
HOMEPAGE="http://www.uclibc.org/" |
| 82 |
SRC_URI="mirror://kernel/linux/libs/uclibc/${MY_P}.tar.bz2 |
| 83 |
http://uclibc.org/downloads/${MY_P}.tar.bz2 |
| 84 |
nls? ( !userlocales? ( pregen? ( |
| 85 |
x86? ( http://www.uclibc.org/downloads/uClibc-locale-030818.tgz ) |
| 86 |
) ) )" |
| 87 |
[[ -z ${SVN_VER} ]] || \ |
| 88 |
SRC_URI="${SRC_URI} mirror://gentoo/${MY_P}-svn-update-${SVN_VER}.patch.bz2" |
| 89 |
[[ -z ${PATCH_VER} ]] || \ |
| 90 |
SRC_URI="${SRC_URI} mirror://gentoo/${MY_P}-patches-${PATCH_VER}.tar.bz2" |
| 91 |
|
| 92 |
LICENSE="LGPL-2" |
| 93 |
[[ ${CTARGET} != ${CHOST} ]] \ |
| 94 |
&& SLOT="${CTARGET}" \ |
| 95 |
|| SLOT="0" |
| 96 |
KEYWORDS="-* ~arm ~m68k -mips ~ppc ~sh ~sparc ~x86" |
| 97 |
IUSE="build uclibc-compat debug hardened iconv ipv6 minimal nls pregen savedconfig userlocales wordexp" |
| 98 |
RESTRICT="strip" |
| 99 |
|
| 100 |
RDEPEND="" |
| 101 |
if [[ ${CTARGET} == ${CHOST} ]] ; then |
| 102 |
DEPEND="virtual/os-headers app-misc/pax-utils" |
| 103 |
PROVIDE="virtual/libc" |
| 104 |
else |
| 105 |
DEPEND="" |
| 106 |
fi |
| 107 |
|
| 108 |
S=${WORKDIR}/${MY_P} |
| 109 |
|
| 110 |
alt_build_kprefix() { |
| 111 |
if [[ ${CBUILD} == ${CHOST} && ${CTARGET} == ${CHOST} ]] \ |
| 112 |
|| [[ -n ${UCLIBC_AND_GLIBC} ]] |
| 113 |
then |
| 114 |
echo /usr |
| 115 |
else |
| 116 |
echo /usr/${CTARGET}/usr |
| 117 |
fi |
| 118 |
} |
| 119 |
just_headers() { |
| 120 |
use crosscompile_opts_headers-only && [[ ${CHOST} != ${CTARGET} ]] |
| 121 |
} |
| 122 |
|
| 123 |
uclibc_endian() { |
| 124 |
# XXX: this wont work for a toolchain which is bi-endian, but we |
| 125 |
# dont have any such thing at the moment, so not a big deal |
| 126 |
touch "${T}"/endian.s |
| 127 |
$(tc-getAS ${CTARGET}) "${T}"/endian.s -o "${T}"/endian.o |
| 128 |
case $(file "${T}"/endian.o) in |
| 129 |
*" MSB "*) echo "big";; |
| 130 |
*" LSB "*) echo "little";; |
| 131 |
*) echo "NFC";; |
| 132 |
esac |
| 133 |
rm -f "${T}"/endian.{s,o} |
| 134 |
} |
| 135 |
|
| 136 |
pkg_setup() { |
| 137 |
just_headers && return 0 |
| 138 |
has_version ${CATEGORY}/uclibc || return 0 |
| 139 |
[[ -n ${UCLIBC_AND_GLIBC} ]] && return 0 |
| 140 |
[[ ${ROOT} != "/" ]] && return 0 |
| 141 |
[[ ${CATEGORY} == cross-* ]] && return 0 |
| 142 |
|
| 143 |
if ! built_with_use --missing false ${CATEGORY}/uclibc nls && use nls && ! use pregen ; then |
| 144 |
eerror "You previously built uclibc with USE=-nls." |
| 145 |
eerror "You cannot generate locale data with this" |
| 146 |
eerror "system. Please rerun emerge with USE=pregen." |
| 147 |
die "host cannot support locales" |
| 148 |
elif built_with_use --missing false ${CATEGORY}/uclibc nls && ! use nls ; then |
| 149 |
eerror "You previously built uclibc with USE=nls." |
| 150 |
eerror "Rebuilding uClibc with USE=-nls will prob" |
| 151 |
eerror "destroy your system." |
| 152 |
die "switching from nls is baaaad" |
| 153 |
fi |
| 154 |
} |
| 155 |
|
| 156 |
PIE_STABLE="arm mips ppc x86" |
| 157 |
|
| 158 |
CPU_ALPHA="" |
| 159 |
CPU_AMD64="" |
| 160 |
CPU_ARM="GENERIC_ARM ARM{610,710,720T,920T,922T,926T,_{SA110,SA1100,XSCALE}}" |
| 161 |
CPU_IA64="" |
| 162 |
CPU_M68K="" |
| 163 |
CPU_MIPS="MIPS_ISA_{1,2,3,4,MIPS{32,64}}" |
| 164 |
CPU_PPC="" |
| 165 |
CPU_SH="SH{2,3,4,5}" |
| 166 |
CPU_SPARC="" |
| 167 |
CPU_X86="GENERIC_386 {3,4,5,6}86 586MMX PENTIUM{II,III,4} K{6,7} ELAN CRUSOE WINCHIP{C6,2} CYRIXIII NEHEMIAH" |
| 168 |
IUSE_UCLIBC_CPU="${CPU_ARM} ${CPU_MIPS} ${CPU_PPC} ${CPU_SH} ${CPU_SPARC} ${CPU_X86}" |
| 169 |
|
| 170 |
check_cpu_opts() { |
| 171 |
local cpu_var="CPU_$(echo $(tc-arch) | tr [a-z] [A-Z])" |
| 172 |
[[ -z ${!cpu_var} ]] && return 0 |
| 173 |
|
| 174 |
if [[ -z ${UCLIBC_CPU} ]] ; then |
| 175 |
ewarn "You really should consider setting UCLIBC_CPU" |
| 176 |
ewarn "Otherwise, the build will be generic (read: slow)." |
| 177 |
ewarn "Available CPU options:" |
| 178 |
UCLIBC_CPU=$(eval echo ${!cpu_var}) |
| 179 |
echo ${UCLIBC_CPU} |
| 180 |
case ${CTARGET} in |
| 181 |
mips[1234]*) export UCLIBC_CPU="MIPS_ISA_${CTARGET:4:1}";; |
| 182 |
sh[2345]*) export UCLIBC_CPU="SH${CTARGET:2:1}";; |
| 183 |
i[456]86*) export UCLIBC_CPU="${CTARGET:1:1}86";; |
| 184 |
*) export UCLIBC_CPU=${UCLIBC_CPU%% *};; |
| 185 |
esac |
| 186 |
else |
| 187 |
local cpu found=0 |
| 188 |
for cpu in $(eval echo ${!cpu_var}) ; do |
| 189 |
[[ ${UCLIBC_CPU} == "${cpu}" ]] && found=1 && break |
| 190 |
done |
| 191 |
if [[ ${found} -eq 0 ]] ; then |
| 192 |
ewarn "UCLIBC_CPU choice '${UCLIBC_CPU}' not supported" |
| 193 |
ewarn "Valid choices:" |
| 194 |
eval echo ${!cpu_var} |
| 195 |
die "pick a supported cpu type" |
| 196 |
fi |
| 197 |
fi |
| 198 |
} |
| 199 |
|
| 200 |
src_unpack() { |
| 201 |
[[ -n ${ESVN_REPO_URI} ]] \ |
| 202 |
&& subversion_src_unpack \ |
| 203 |
|| unpack ${A} |
| 204 |
cd "${S}" |
| 205 |
|
| 206 |
check_cpu_opts |
| 207 |
|
| 208 |
echo |
| 209 |
einfo "Runtime Prefix: /" |
| 210 |
einfo "Devel Prefix: /usr" |
| 211 |
einfo "Kernel Prefix: $(alt_build_kprefix)" |
| 212 |
einfo "CBUILD: ${CBUILD}" |
| 213 |
einfo "CHOST: ${CHOST}" |
| 214 |
einfo "CTARGET: ${CTARGET}" |
| 215 |
einfo "CPU: ${UCLIBC_CPU:-default}" |
| 216 |
einfo "ENDIAN: $(uclibc_endian)" |
| 217 |
echo |
| 218 |
|
| 219 |
########## PATCHES ########## |
| 220 |
|
| 221 |
[[ -n ${SVN_VER} ]] && \ |
| 222 |
epatch "${WORKDIR}"/${MY_P}-cvs-update-${SVN_VER}.patch |
| 223 |
|
| 224 |
if [[ -n ${PATCH_VER} ]] ; then |
| 225 |
unpack ${MY_P}-patches-${PATCH_VER}.tar.bz2 |
| 226 |
EPATCH_SUFFIX="patch" |
| 227 |
epatch "${WORKDIR}"/patch |
| 228 |
# math functions (sinf,cosf,tanf,atan2f,powf,fabsf,copysignf,scalbnf,rem_pio2f) |
| 229 |
cp "${WORKDIR}"/patch/math/libm/* "${S}"/libm/ || die |
| 230 |
epatch "${WORKDIR}"/patch/math |
| 231 |
fi |
| 232 |
|
| 233 |
########## CPU SELECTION ########## |
| 234 |
|
| 235 |
local target config_target |
| 236 |
case $(tc-arch) in |
| 237 |
alpha) target="alpha"; config_target="no cpu-specific options";; |
| 238 |
amd64) target="x86_64"; config_target="no cpu-specific options";; |
| 239 |
arm) target="arm"; config_target="GENERIC_ARM";; |
| 240 |
ia64) target="ia64"; config_target="no cpu-specific options";; |
| 241 |
m68k) target="m68k"; config_target="no cpu-specific options";; |
| 242 |
mips) target="mips"; config_target="MIPS_ISA_1";; |
| 243 |
ppc) target="powerpc"; config_target="no cpu-specific options";; |
| 244 |
sh) target="sh"; config_target="SH4";; |
| 245 |
sparc) target="sparc"; config_target="no cpu-specific options";; |
| 246 |
x86) target="i386"; config_target="GENERIC_386";; |
| 247 |
*) die "$(tc-arch) lists no defaults :/";; |
| 248 |
esac |
| 249 |
sed -i -e "s:default TARGET_i386:default TARGET_${target}:" \ |
| 250 |
extra/Configs/Config.in |
| 251 |
sed -i -e "s:default CONFIG_${config_target}:default CONFIG_${UCLIBC_CPU:-${config_target}}:" \ |
| 252 |
extra/Configs/Config.${target} |
| 253 |
|
| 254 |
########## CONFIG SETUP ########## |
| 255 |
|
| 256 |
make defconfig >/dev/null || die "could not config" |
| 257 |
|
| 258 |
for def in DO{DEBUG{,_PT},ASSERTS} SUPPORT_LD_DEBUG{,_EARLY} ; do |
| 259 |
sed -i -e "s:${def}=y:# ${def} is not set:" .config |
| 260 |
done |
| 261 |
if use debug ; then |
| 262 |
#echo "SUPPORT_LD_DEBUG_EARLY=y" >> .config |
| 263 |
echo "SUPPORT_LD_DEBUG=y" >> .config |
| 264 |
echo "DODEBUG=y" >> .config |
| 265 |
#echo "DODEBUG_PT=y" >> .config |
| 266 |
fi |
| 267 |
|
| 268 |
sed -i -e '/ARCH_.*_ENDIAN/d' .config |
| 269 |
echo "ARCH_$(uclibc_endian | tr [a-z] [A-Z])_ENDIAN=y" >> .config |
| 270 |
|
| 271 |
if [[ $(tc-is-softfloat) != "no" ]] ; then |
| 272 |
sed -i -e '/^HAS_FPU=y$/d' .config |
| 273 |
echo 'HAS_FPU=n' >> .config |
| 274 |
fi |
| 275 |
|
| 276 |
local moredefs="DL_FINI_CRT_COMPAT" |
| 277 |
# We need todo this for a few months. .28 is a major upgrade. |
| 278 |
# Don't do it from cross-compiling case though |
| 279 |
if ! use uclibc-compat ; then |
| 280 |
if [[ -z ${UCLIBC_AND_GLIBC} ]] && [[ -z ${UCLIBC_SCANNED_COMPAT} ]] && \ |
| 281 |
! just_headers && [[ ${CHOST} == ${CTARGET} ]] ; then |
| 282 |
local fnames="" |
| 283 |
einfo "Doing a scanelf in paths for bins containing the __uClibc_start_main symbol" |
| 284 |
fnames=$(scanelf -pyqs__uClibc_start_main -F%F#s) |
| 285 |
if [[ -z ${fnames} ]] ; then |
| 286 |
einfo "This system is clean." |
| 287 |
einfo "To prevent the scanning of files again in the future you can export UCLIBC_SCANNED_COMPAT=1" |
| 288 |
moredefs="" |
| 289 |
else |
| 290 |
ewarn "You need to remerge the packages that contain the following files before you can remerge ${P} without USE=uclibc-compat enabled." |
| 291 |
ewarn "qfile ${fnames}" |
| 292 |
echo |
| 293 |
ewarn "Leaving on ${moredefs}" |
| 294 |
fi |
| 295 |
else |
| 296 |
moredefs="" |
| 297 |
fi |
| 298 |
fi |
| 299 |
for def in ${moredefs} MALLOC_GLIBC_COMPAT DO_C99_MATH UCLIBC_HAS_{RPC,CTYPE_CHECKED,WCHAR,HEXADECIMAL_FLOATS,GLIBC_CUSTOM_PRINTF,FOPEN_EXCLUSIVE_MODE,GLIBC_CUSTOM_STREAMS,PRINTF_M_SPEC,FTW} ; do |
| 300 |
sed -i -e "s:# ${def} is not set:${def}=y:" .config |
| 301 |
done |
| 302 |
echo "UCLIBC_HAS_FULL_RPC=y" >> .config |
| 303 |
echo "PTHREADS_DEBUG_SUPPORT=y" >> .config |
| 304 |
echo "UCLIBC_HAS_TZ_FILE_READ_MANY=n" >> .config |
| 305 |
|
| 306 |
if use iconv ; then |
| 307 |
sed -i -e "s:# UCLIBC_HAS_LOCALE is not set:UCLIBC_HAS_LOCALE=y:" .config |
| 308 |
echo "UCLIBC_HAS_XLOCALE=n" >> .config |
| 309 |
echo "UCLIBC_HAS_GLIBC_DIGIT_GROUPING=y" >> .config |
| 310 |
echo "UCLIBC_HAS_SCANF_LENIENT_DIGIT_GROUPING=y" >> .config |
| 311 |
|
| 312 |
if use nls ; then |
| 313 |
echo "UCLIBC_HAS_GETTEXT_AWARENESS=y" >> .config |
| 314 |
else |
| 315 |
echo "UCLIBC_HAS_GETTEXT_AWARENESS=n" >> .config |
| 316 |
fi |
| 317 |
|
| 318 |
if use pregen ; then |
| 319 |
echo "UCLIBC_PREGENERATED_LOCALE_DATA=y" >> .config |
| 320 |
echo "UCLIBC_DOWNLOAD_PREGENERATED_LOCALE_DATA=y" >> .config |
| 321 |
if use userlocales ; then |
| 322 |
cp "${DISTDIR}"/${MY_P}-user-locale.tar.gz \ |
| 323 |
extra/locale/uClibc-locale-030818.tgz \ |
| 324 |
|| die "could not copy ${MY_P}-user-locale.tar.gz" |
| 325 |
else |
| 326 |
cp "${DISTDIR}"/${MY_P}-$(tc-arch)-full-locale.tar.gz \ |
| 327 |
extra/locale/uClibc-locale-030818.tgz \ |
| 328 |
|| die "could not copy locale" |
| 329 |
fi |
| 330 |
else |
| 331 |
echo "UCLIBC_PREGENERATED_LOCALE_DATA=n" >> .config |
| 332 |
fi |
| 333 |
else |
| 334 |
echo "UCLIBC_HAS_LOCALE=n" >> .config |
| 335 |
fi |
| 336 |
|
| 337 |
use ipv6 && sed -i -e "s:# UCLIBC_HAS_IPV6 is not set:UCLIBC_HAS_IPV6=y:" .config |
| 338 |
|
| 339 |
# uncomment if you miss wordexp (alsa-lib) |
| 340 |
use wordexp && sed -i -e "s:# UCLIBC_HAS_WORDEXP is not set:UCLIBC_HAS_WORDEXP=y:" .config |
| 341 |
|
| 342 |
# we need to do it independently of hardened to get ssp.c built into libc |
| 343 |
sed -i -e "s:# UCLIBC_SECURITY.*:UCLIBC_SECURITY=y:" .config |
| 344 |
echo "UCLIBC_HAS_SSP=y" >> .config |
| 345 |
echo "SSP_USE_ERANDOM=n" >> .config |
| 346 |
echo "PROPOLICE_BLOCK_ABRT=n" >> .config |
| 347 |
if use debug ; then |
| 348 |
echo "PROPOLICE_BLOCK_SEGV=y" >> .config |
| 349 |
echo "PROPOLICE_BLOCK_KILL=n" >> .config |
| 350 |
else |
| 351 |
echo "PROPOLICE_BLOCK_SEGV=n" >> .config |
| 352 |
echo "PROPOLICE_BLOCK_KILL=y" >> .config |
| 353 |
fi |
| 354 |
|
| 355 |
# arm/mips do not emit PT_GNU_STACK, but if we enable this here |
| 356 |
# it will be emitted as RWE, ppc has to be checked, x86 needs it |
| 357 |
# this option should be used independently of hardened |
| 358 |
# relro could be also moved out of hardened |
| 359 |
if has $(tc-arch) x86 ; then |
| 360 |
echo "UCLIBC_BUILD_NOEXECSTACK=y" >> .config |
| 361 |
else |
| 362 |
echo "UCLIBC_BUILD_NOEXECSTACK=n" >> .config |
| 363 |
fi |
| 364 |
echo "UCLIBC_BUILD_RELRO=y" >> .config |
| 365 |
if use hardened ; then |
| 366 |
if has $(tc-arch) ${PIE_STABLE} ; then |
| 367 |
echo "UCLIBC_BUILD_PIE=y" >> .config |
| 368 |
else |
| 369 |
echo "UCLIBC_BUILD_PIE=n" >> .config |
| 370 |
fi |
| 371 |
echo "SSP_QUICK_CANARY=n" >> .config |
| 372 |
echo "UCLIBC_BUILD_SSP=y" >> .config |
| 373 |
echo "UCLIBC_BUILD_NOW=y" >> .config |
| 374 |
else |
| 375 |
echo "UCLIBC_BUILD_PIE=n" >> .config |
| 376 |
echo "SSP_QUICK_CANARY=y" >> .config |
| 377 |
echo "UCLIBC_BUILD_SSP=n" >> .config |
| 378 |
echo "UCLIBC_BUILD_NOW=n" >> .config |
| 379 |
fi |
| 380 |
|
| 381 |
# Allow users some custom control over the config |
| 382 |
if use savedconfig ; then |
| 383 |
for conf in ${PN}-${PV}-${PR} ${PN}-${PV} ${PN}; do |
| 384 |
configfile=${ROOT}/etc/${PN}/${CTARGET}/${conf}.config |
| 385 |
einfo "Checking existence of ${configfile} ..." |
| 386 |
[[ -r ${configfile} ]] || configfile=/etc/${PN}/${CHOST}/${conf}.config |
| 387 |
if [[ -r ${configfile} ]] ; then |
| 388 |
cp "${configfile}" "${S}"/.config |
| 389 |
einfo "Found your ${configfile} and using it." |
| 390 |
einfo "Note that this feature is *totally unsupported*." |
| 391 |
break |
| 392 |
fi |
| 393 |
done |
| 394 |
fi |
| 395 |
|
| 396 |
# setup build and run paths |
| 397 |
local cross=${CTARGET}- |
| 398 |
type -p ${cross}ar > /dev/null || cross="" |
| 399 |
sed -i \ |
| 400 |
-e "/^CROSS_COMPILER_PREFIX/s:=.*:=\"${cross}\":" \ |
| 401 |
-e "/^KERNEL_SOURCE/s:=.*:=\"$(alt_build_kprefix)\":" \ |
| 402 |
-e "/^SHARED_LIB_LOADER_PREFIX/s:=.*:=\"/$(get_libdir)\":" \ |
| 403 |
-e "/^DEVEL_PREFIX/s:=.*:=\"/usr\":" \ |
| 404 |
-e "/^RUNTIME_PREFIX/s:=.*:=\"/\":" \ |
| 405 |
.config || die |
| 406 |
|
| 407 |
yes "" 2> /dev/null | make -s oldconfig > /dev/null || die "could not make oldconfig" |
| 408 |
|
| 409 |
cp .config myconfig |
| 410 |
|
| 411 |
emake -s clean > /dev/null || die "could not clean" |
| 412 |
} |
| 413 |
|
| 414 |
setup_locales() { |
| 415 |
cd "${S}"/extra/locale |
| 416 |
if use userlocales && [[ -f ${ROOT}/etc/locales.build ]] ; then |
| 417 |
:; |
| 418 |
elif use minimal ; then |
| 419 |
find ./charmaps -name ASCII.pairs > codesets.txt |
| 420 |
find ./charmaps -name ISO-8859-1.pairs >> codesets.txt |
| 421 |
cat <<-EOF > locales.txt |
| 422 |
@euro e |
| 423 |
UTF-8 yes |
| 424 |
8-bit yes |
| 425 |
en_US ISO-8859-1 |
| 426 |
en_US.UTF-8 UTF-8 |
| 427 |
EOF |
| 428 |
else |
| 429 |
find ./charmaps -name '*.pairs' > codesets.txt |
| 430 |
cp LOCALES locales.txt |
| 431 |
fi |
| 432 |
cd - |
| 433 |
} |
| 434 |
|
| 435 |
src_compile() { |
| 436 |
cp myconfig .config |
| 437 |
|
| 438 |
emake headers || die "make headers failed" |
| 439 |
just_headers && return 0 |
| 440 |
|
| 441 |
if use iconv && ! use pregen ; then |
| 442 |
cd extra/locale |
| 443 |
make clean || die "make locale clean failed" |
| 444 |
setup_locales |
| 445 |
emake || die "make locales failed" |
| 446 |
cd ../.. |
| 447 |
fi |
| 448 |
|
| 449 |
emake || die "make failed" |
| 450 |
if [[ ${CTARGET} != ${CHOST} ]] ; then |
| 451 |
emake -C utils hostutils || die "make hostutils failed" |
| 452 |
elif [[ ${CHOST} == *-uclibc ]] ; then |
| 453 |
emake utils || die "make utils failed" |
| 454 |
fi |
| 455 |
} |
| 456 |
|
| 457 |
src_test() { |
| 458 |
[[ ${CHOST} != ${CTARGET} ]] && return 0 |
| 459 |
[[ ${CBUILD} != ${CHOST} ]] && return 0 |
| 460 |
|
| 461 |
# assert test fails on pax/grsec enabled kernels - normal |
| 462 |
# vfork test fails in sandbox (both glibc/uclibc) |
| 463 |
make UCLIBC_ONLY=1 check || die "test failed" |
| 464 |
} |
| 465 |
|
| 466 |
src_install() { |
| 467 |
local sysroot=${D} |
| 468 |
[[ ${CHOST} != ${CTARGET} ]] && sysroot="${sysroot}/usr/${CTARGET}" |
| 469 |
|
| 470 |
local target="install" |
| 471 |
just_headers && target="install_dev" |
| 472 |
emake DESTDIR="${sysroot}" ${target} || die "install failed" |
| 473 |
|
| 474 |
# remove files coming from kernel-headers |
| 475 |
rm -rf "${sysroot}"/usr/include/{linux,asm*} |
| 476 |
|
| 477 |
# Make sure we install the sys-include symlink so that when |
| 478 |
# we build a 2nd stage cross-compiler, gcc finds the target |
| 479 |
# system headers correctly. See gcc/doc/gccinstall.info |
| 480 |
if [[ ${CTARGET} != ${CHOST} ]] ; then |
| 481 |
dosym usr/include /usr/${CTARGET}/sys-include |
| 482 |
newbin utils/ldconfig.host ${CTARGET}-ldconfig || die |
| 483 |
newbin utils/ldd.host ${CTARGET}-ldd || die |
| 484 |
return 0 |
| 485 |
fi |
| 486 |
|
| 487 |
if [[ ${CHOST} == *-uclibc ]] ; then |
| 488 |
make DESTDIR="${D}" install_utils || die "install-utils failed" |
| 489 |
dobin extra/scripts/getent |
| 490 |
fi |
| 491 |
|
| 492 |
if ! use build ; then |
| 493 |
dodoc Changelog* README TODO docs/*.txt DEDICATION.mjn3 |
| 494 |
doman docs/man/*.[1-9] |
| 495 |
fi |
| 496 |
} |
| 497 |
|
| 498 |
pkg_postinst() { |
| 499 |
[[ ${CTARGET} != ${CHOST} ]] && return 0 |
| 500 |
[[ ${CHOST} != *-uclibc ]] && return 0 |
| 501 |
|
| 502 |
if [[ ! -e ${ROOT}/etc/TZ ]] ; then |
| 503 |
ewarn "Please remember to set your timezone in /etc/TZ" |
| 504 |
[[ ! -d ${ROOT}/etc ]] && mkdir -p "${ROOT}"/etc |
| 505 |
echo "UTC" > "${ROOT}"/etc/TZ |
| 506 |
fi |
| 507 |
|
| 508 |
if [[ ${ROOT} == "/" ]] ; then |
| 509 |
# update cache before reloading init |
| 510 |
/sbin/ldconfig |
| 511 |
# reload init ... |
| 512 |
[[ -x /sbin/telinit ]] && /sbin/telinit U &> /dev/null |
| 513 |
fi |
| 514 |
} |
| 515 |
|
| 516 |
|
| 517 |
|
| 518 |
-- |
| 519 |
gentoo-commits@l.g.o mailing list |
Archives