[gentoo-commits] repo/gentoo:master commit in: net-im/signal-desktop-bin/

[Sam James]

commit:     9a1c910c900711455345ac0e6a37c8f8aa8dfbc9
Author:     Robert Siebeck <gentoo.2019 <AT> r123 <DOT> de>
AuthorDate: Wed Dec  1 17:11:26 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Dec  1 17:24:30 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9a1c910c

net-im/signal-desktop-bin: remove old version

Signed-off-by: Robert Siebeck <gentoo.2019 <AT> r123.de>
Closes: https://github.com/gentoo/gentoo/pull/23135
Signed-off-by: Sam James <sam <AT> gentoo.org>

 .../signal-desktop-bin-5.24.0.ebuild               | 100 ---------------------
 1 file changed, 100 deletions(-)

diff --git a/net-im/signal-desktop-bin/signal-desktop-bin-5.24.0.ebuild b/net-im/signal-desktop-bin/signal-desktop-bin-5.24.0.ebuild
deleted file mode 100644
index e6ca382563fa..000000000000
--- a/net-im/signal-desktop-bin/signal-desktop-bin-5.24.0.ebuild
+++ /dev/null
@@ -1,100 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-MY_PN="${PN/-bin/}"
-
-inherit pax-utils unpacker xdg
-
-DESCRIPTION="Allows you to send and receive messages of Signal Messenger on your computer"
-HOMEPAGE="https://signal.org/
-	https://github.com/signalapp/Signal-Desktop"
-SRC_URI="https://updates.signal.org/desktop/apt/pool/main/s/${MY_PN}/${MY_PN}_${PV}_amd64.deb"
-S="${WORKDIR}"
-
-LICENSE="GPL-3 MIT MIT-with-advertising BSD-1 BSD-2 BSD Apache-2.0 ISC openssl ZLIB APSL-2 icu Artistic-2 LGPL-2.1"
-SLOT="0"
-KEYWORDS="-* ~amd64"
-IUSE="+sound"
-RESTRICT="splitdebug"
-
-RDEPEND="
-	app-accessibility/at-spi2-atk:2
-	app-accessibility/at-spi2-core:2
-	dev-libs/atk
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	media-libs/alsa-lib
-	media-libs/mesa[X(+)]
-	net-print/cups
-	sys-apps/dbus[X]
-	x11-libs/gdk-pixbuf:2
-	x11-libs/cairo
-	x11-libs/gtk+:3[X]
-	x11-libs/libdrm
-	x11-libs/libX11
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/libxshmfence
-	x11-libs/pango
-	sound? (
-		|| (
-			media-sound/pulseaudio
-			media-sound/apulse
-		)
-	)
-"
-
-QA_PREBUILT="
-	opt/Signal/chrome-sandbox
-	opt/Signal/libEGL.so
-	opt/Signal/libGLESv2.so
-	opt/Signal/libffmpeg.so
-	opt/Signal/libvk_swiftshader.so
-	opt/Signal/libvulkan.so.1
-	opt/Signal/resources/app.asar.unpacked/node_modules/*
-	opt/Signal/signal-desktop
-	opt/Signal/swiftshader/libEGL.so
-	opt/Signal/swiftshader/libGLESv2.so"
-
-src_prepare() {
-	default
-	sed -e 's| --no-sandbox||g' \
-		-i usr/share/applications/signal-desktop.desktop || die
-	unpack usr/share/doc/signal-desktop/changelog.gz
-
-	rm opt/Signal/resources/app.asar.unpacked/node_modules/{ffi-napi/node_modules/ref-napi/prebuilds/linux-arm64/electron.napi.armv8.node,ffi-napi/node_modules/ref-napi/prebuilds/linux-arm64/node.napi.armv8.node,ffi-napi/prebuilds/linux-arm64/node.napi.uv1.armv8.node,ref-napi/prebuilds/linux-arm64/electron.napi.armv8.node,ref-napi/prebuilds/linux-arm64/node.napi.armv8.node} || die
-}
-
-src_install() {
-	insinto /
-	dodoc changelog
-	doins -r opt
-	insinto /usr/share
-
-	if has_version media-sound/apulse[-sdk] && ! has_version media-sound/pulseaudio; then
-		sed -i 's/Exec=/Exec=apulse /g' usr/share/applications/signal-desktop.desktop || die
-	fi
-
-	doins -r usr/share/applications
-	doins -r usr/share/icons
-	fperms +x /opt/Signal/signal-desktop /opt/Signal/chrome-sandbox
-	fperms u+s /opt/Signal/chrome-sandbox
-	pax-mark m opt/Signal/signal-desktop opt/Signal/chrome-sandbox
-
-	dosym ../../opt/Signal/${MY_PN} /usr/bin/${MY_PN}
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-	elog "For using the tray icon on compatible desktop environments, start Signal with"
-	elog " '--start-in-tray' or '--use-tray-icon'."
-}