[gentoo-commits] repo/gentoo:master commit in: app-emulation/runc/

[Manuel Rüger]

commit:     13a596864392907dd399a93bf66cab2b0d5f49f9
Author:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 11 19:32:20 2019 +0000
Commit:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Mon Feb 11 19:32:20 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=13a59686

app-emulation/runc: Backport fix

Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Manuel Rüger <mrueg <AT> gentoo.org>

 .../runc/runc-1.0.0_rc5_p20180509-r1.ebuild        | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/app-emulation/runc/runc-1.0.0_rc5_p20180509-r1.ebuild b/app-emulation/runc/runc-1.0.0_rc5_p20180509-r1.ebuild
new file mode 100644
index 00000000000..2aca18c8e96
--- /dev/null
+++ b/app-emulation/runc/runc-1.0.0_rc5_p20180509-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN="github.com/opencontainers/${PN}"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit golang-build golang-vcs
+else
+	MY_PV="${PV/_/-}"
+	EGIT_COMMIT="v${MY_PV}"
+	RUNC_COMMIT="69663f0bd4b60df09991c08812a60108003fa340" # Change this when you update the ebuild
+	SRC_URI="https://${EGO_PN}/archive/${RUNC_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64"
+	inherit golang-build golang-vcs-snapshot
+fi
+
+DESCRIPTION="runc container cli tools"
+HOMEPAGE="http://runc.io"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+ambient apparmor hardened +seccomp"
+
+RDEPEND="
+	apparmor? ( sys-libs/libapparmor )
+	seccomp? ( sys-libs/libseccomp )
+	!app-emulation/docker-runc
+"
+
+PATCHES=( "${FILESDIR}"/runc-fix-cve.patch )
+
+src_prepare() {
+	pushd src/${EGO_PN} || die
+	default
+	popd || die
+}
+
+src_compile() {
+	# Taken from app-emulation/docker-1.7.0-r1
+	export CGO_CFLAGS="-I${ROOT}/usr/include"
+	export CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')
+		-L${ROOT}/usr/$(get_libdir)"
+
+	# build up optional flags
+	local options=(
+		$(usex ambient 'ambient')
+		$(usex apparmor 'apparmor')
+		$(usex seccomp 'seccomp')
+	)
+
+	GOPATH="${S}"\
+		emake BUILDTAGS="${options[*]}" \
+		COMMIT="${RUNC_COMMIT}" -C src/${EGO_PN}
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin runc
+	dodoc README.md PRINCIPLES.md
+	popd || die
+}