[gentoo-commits] repo/gentoo:master commit in: dev-perl/Emacs-PDE/

[Kent Fredric]

commit:     b4d57be49e68bfaf4134267cc6456c411d12314f
Author:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  7 20:10:26 2020 +0000
Commit:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Fri Aug  7 20:10:53 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b4d57be4

dev-perl/Emacs-PDE: Bump to version 0.2.17

- EAPI7
- Fix LICENSE
- Remove empty/used variable assignments
- Push myconf closer to src_configure as a guard against variables
  being augmented between ebuild sourcing and function execution

Package-Manager: Portage-2.3.103, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl <AT> gentoo.org>

 dev-perl/Emacs-PDE/Emacs-PDE-0.2.17.ebuild | 46 ++++++++++++++++++++++++++++++
 dev-perl/Emacs-PDE/Manifest                |  1 +
 2 files changed, 47 insertions(+)

diff --git a/dev-perl/Emacs-PDE/Emacs-PDE-0.2.17.ebuild b/dev-perl/Emacs-PDE/Emacs-PDE-0.2.17.ebuild
new file mode 100644
index 00000000000..1ebba83a778
--- /dev/null
+++ b/dev-perl/Emacs-PDE/Emacs-PDE-0.2.17.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=YEWENBIN
+DIST_VERSION="v${PV}"
+inherit perl-module elisp-common
+
+DESCRIPTION="Perl Develop Environment in Emacs"
+# Some elisp files are GPL-2+
+# Some templates are FDL-1.1+
+LICENSE="|| ( Artistic GPL-1+ ) GPL-2+ FDL-1.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+RDEPEND=">=app-editors/emacs-23.1:*"
+DEPEND="dev-perl/Module-Build"
+BDEPEND="${RDEPEND}
+	>=dev-perl/Module-Build-0.420.0
+"
+src_configure() {
+	myconf="--elispdir=${D}${SITELISP}/pde"
+	perl-module_src_configure
+}
+src_test() {
+	local MODULES=(
+		"Emacs::PDE ${PV}"
+		"Emacs::PDE::Util"
+	)
+	local failed=()
+	for dep in "${MODULES[@]}"; do
+		ebegin "Compile testing ${dep}"
+			perl -Mblib="${S}" -M"${dep} ()" -e1
+		eend $? || failed+=( "$dep" )
+	done
+	if [[ ${failed[@]} ]]; then
+		echo
+		eerror "One or more modules failed compile:";
+		for dep in "${failed[@]}"; do
+			eerror "  ${dep}"
+		done
+		die "Failing due to module compilation errors";
+	fi
+	perl-module_src_test
+}

diff --git a/dev-perl/Emacs-PDE/Manifest b/dev-perl/Emacs-PDE/Manifest
index 0fe965160fa..79d2049127f 100644
--- a/dev-perl/Emacs-PDE/Manifest
+++ b/dev-perl/Emacs-PDE/Manifest
@@ -1 +1,2 @@
 DIST Emacs-PDE-0.2.16.tar.gz 619372 BLAKE2B 7d9eb5a7e3c61424b58bab4186efbd4426ac6c94a2043ade3a5de2da060e5eca2c2fc8ab20d5b3bcd3458036bdd8db861aef1ef963e0276e1c759c151843f362 SHA512 ab104070c820a618b0ce05a2d658cca56ad9c0d537e98697a98262c4135486cba2284ee597210dfe8c30348a0fadb9f76455453e17a86a0123618ce076b5565b
+DIST Emacs-PDE-v0.2.17.tar.gz 664587 BLAKE2B 3b80a5643f71801e9117fd266c28acebc3dddbbdb07eb50d0b123afc1e54134090ffb1c04c4421938e702969d79b9ee6f8948e5dbefeeefc21f822e6a5c6ec95 SHA512 66c6044f41d81689d66d6c6b478291323790b569f9611cd6847d30fecdbee4447e5bea0efd816f243e6323e8872934e5cc15399e80cf29568edc625f87bf109f