[gentoo-commits] repo/gentoo:master commit in: dev-python/tox/

[Michał Górny]

commit:     d60201e06a3db945baa5a241f614b12c78509d21
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 31 06:36:16 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jan 31 06:36:16 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d60201e0

dev-python/tox: Bump to 4.4.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/tox/Manifest         |  1 +
 dev-python/tox/tox-4.4.3.ebuild | 95 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 2a8ddb7cd9fe..4e821ad42181 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,2 +1,3 @@
 DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B 9896411426f6aebb3efa468c01696ecc5f17ec3e67825672d0efc74c1b1468bc8b8d9c14b6177c181750ba4b9a5e77d616068dd83e21f5641acfc8e2a271cc1f SHA512 64816754e6800661bb564c5c7d21c4139522d540a04fafe3c4591d596072d48d1cbe0ee2abee9c8faf3d5007774f5371431b5a7a8f49912bc879c7b168aab2ca
 DIST tox-4.4.2.gh.tar.gz 303341 BLAKE2B 812394e15996b04138e2a8167b3d332b48217c5ecfb807d8ed77ff106d8ad31cfc6b43e07737dec39e1deba7165aa7778471894823b0dbe795b1ccddd2396602 SHA512 1e5b8f025c93bea5b9071d5cfcb4e4e68f1925e7b70c4c838b9f4ba70f8f077ed752176c2a7349b96d125842312c4fa8ccbd23d79665ba46667f4b408bf58f78
+DIST tox-4.4.3.gh.tar.gz 303758 BLAKE2B 2182ee88ea3fcc1792304c3a0e064f5f6c790f1305c195084b942e8181986c68faa48ad7a85eb52097de5e822351ee0f0e0f076adfa57276e822405927a0d0f1 SHA512 438ce96a6751363f37bfe7ffc42ab3a2349d6b22fa4259642f3a7cbadd4183d7bc065b6b93298b85dd174700a222cde149657e9203f70cbe747e8a84d9adf35a

diff --git a/dev-python/tox/tox-4.4.3.ebuild b/dev-python/tox/tox-4.4.3.ebuild
new file mode 100644
index 000000000000..3f569fd7734b
--- /dev/null
+++ b/dev-python/tox/tox-4.4.3.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2.1[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.5[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=[0-9]\+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+}