[gentoo-commits] gentoo-x86 commit in media-libs/vigra: vigra-1.10.0.ebuild vigra-1.9.0.ebuild ChangeLog

[Matthias Maier (tamiko)]

tamiko      14/10/31 00:06:54

  Modified:             vigra-1.9.0.ebuild ChangeLog
  Added:                vigra-1.10.0.ebuild
  Log:
  version bump, bug 494214 ; original patches and ebuild modifications by J. M. Gottfried
  
  (Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key BD3A97A3)

Revision  Changes    Path
1.4                  media-libs/vigra/vigra-1.9.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/vigra/vigra-1.9.0.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/vigra/vigra-1.9.0.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/vigra/vigra-1.9.0.ebuild?r1=1.3&r2=1.4

Index: vigra-1.9.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/vigra/vigra-1.9.0.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- vigra-1.9.0.ebuild	16 Sep 2013 09:42:55 -0000	1.3
+++ vigra-1.9.0.ebuild	31 Oct 2014 00:06:54 -0000	1.4
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/vigra/vigra-1.9.0.ebuild,v 1.3 2013/09/16 09:42:55 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/vigra/vigra-1.9.0.ebuild,v 1.4 2014/10/31 00:06:54 tamiko Exp $
 
 EAPI=5
 



1.64                 media-libs/vigra/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/vigra/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/vigra/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/vigra/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/vigra/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	16 Sep 2013 09:42:55 -0000	1.63
+++ ChangeLog	31 Oct 2014 00:06:54 -0000	1.64
@@ -1,6 +1,15 @@
 # ChangeLog for media-libs/vigra
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/vigra/ChangeLog,v 1.63 2013/09/16 09:42:55 scarabeus Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/vigra/ChangeLog,v 1.64 2014/10/31 00:06:54 tamiko Exp $
+
+*vigra-1.10.0 (31 Oct 2014)
+
+  31 Oct 2014; Matthias Maier <tamiko@g.o>
+  +files/vigra-1.10.0-automagicness.patch,
+  +files/vigra-1.10.0-cmake-scripts.patch, +files/vigra-1.10.0-mpi-fixes.patch,
+  +vigra-1.10.0.ebuild, vigra-1.9.0.ebuild:
+  version bump, bug 494214 ; original patches and ebuild modifications by J. M.
+  Gottfried
 
   16 Sep 2013; Tomáš Chvátal <scarabeus@g.o> vigra-1.9.0.ebuild:
   Subslot dep on boost is must to trigger rebuilds properly.



1.1                  media-libs/vigra/vigra-1.10.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/vigra/vigra-1.10.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/vigra/vigra-1.10.0.ebuild?rev=1.1&content-type=text/plain

Index: vigra-1.10.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/vigra/vigra-1.10.0.ebuild,v 1.1 2014/10/31 00:06:54 tamiko Exp $

EAPI=5
MY_P=${P}-src-with-docu
MY_V=${PV//\./-}
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="threads,xml"
inherit cmake-utils python-r1

DESCRIPTION="C++ computer vision library with emphasize on customizable algorithms and data structures"
HOMEPAGE="http://hci.iwr.uni-heidelberg.de/vigra/"
SRC_URI="https://github.com/ukoethe/vigra/releases/download/Version-${MY_V}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="doc +fftw +hdf5 +jpeg mpi openexr +png +python test +tiff"

# runtime dependency on python:2.7 is required by the vigra-config script
RDEPEND="
	dev-lang/python:2.7
	>=dev-libs/boost-1.52.0-r6:=[python?,${PYTHON_USEDEP}]
	fftw? ( sci-libs/fftw:3.0 )
	hdf5? ( >=sci-libs/hdf5-1.8.0[mpi?] )
	jpeg? ( virtual/jpeg )
	openexr? ( media-libs/openexr:= )
	png? ( media-libs/libpng:0= )
	python? ( ${PYTHON_DEPS} dev-python/numpy[${PYTHON_USEDEP}] )
	tiff? ( media-libs/tiff:0= )"

DEPEND="${RDEPEND}
	doc? (
		app-doc/doxygen
		python? ( >=dev-python/sphinx-1.1.3-r5[${PYTHON_USEDEP}] )
	)
	test? ( >=dev-python/nose-1.1.2-r1[${PYTHON_USEDEP}] )"

REQUIRED_USE="
	doc? ( hdf5 fftw )
	python? ( hdf5 ${PYTHON_REQUIRED_USE} )
	test? ( hdf5 python fftw )"

PATCHES=(
	"${FILESDIR}/${P}-automagicness.patch"
	"${FILESDIR}/${P}-cmake-scripts.patch"
	"${FILESDIR}/${P}-mpi-fixes.patch"
)
DOCS=( README.md )

pkg_setup() {
	use python && python_setup
}

src_prepare() {
	einfo "Removing shipped doc, Win32 dependencies and VCS files"
	rm -rf doc
	rm vigra-dependencies-win32-vs8.zip
	rm .git* .hg* .travis.yml

	cmake-utils_src_prepare

	# Don't use python_fix_shebang because we can't put this behind USE="python"
	sed -i -e '/env/s:python:python2:' config/vigra-config.in || die
}

src_configure() {
	vigra_configure() {
		local libdir="$(get_libdir)"

		local mycmakeargs=(
			-DAUTOEXEC_TESTS=OFF
			-DDOCDIR="${BUILD_DIR}/doc"
			-DDOCINSTALL="share/doc/${PV}"
			-DLIBDIR_SUFFIX="${libdir/lib}"
			-DWITH_VALGRIND=OFF
			$(cmake-utils_use_enable doc DOC)
			$(cmake-utils_use_with fftw FFTW3)
			$(cmake-utils_use_with hdf5 HDF5)
			$(cmake-utils_use_with jpeg JPEG)
			$(cmake-utils_use_with mpi MPI)
			$(cmake-utils_use_with png PNG)
			$(cmake-utils_use_with openexr OPENEXR)
			$(cmake-utils_use_with python VIGRANUMPY)
			$(cmake-utils_use_with tiff TIFF)
			$(cmake-utils_use_build test TESTING)
			$(cmake-utils_use test CREATE_CTEST_TARGETS)
			$(cmake-utils_use test AUTOBUILD_TESTS)
		)
		cmake-utils_src_configure
	}

	if use python; then
		python_foreach_impl vigra_configure
	else
		# required for docdir
		_check_build_dir init
		vigra_configure
	fi
}

src_compile() {
	local VIGRA_BUILD_DIR
	vigra_compile() {
		cmake-utils_src_compile
		VIGRA_BUILD_DIR="${BUILD_DIR}"
	}
	if use python; then
		python_foreach_impl vigra_compile
	else
		vigra_compile
	fi

	if use doc; then
		einfo "Generating Documentation"
		# use build dir from last compile command
		BUILD_DIR="${VIGRA_BUILD_DIR}" cmake-utils_src_make doc
	fi
}

src_install() {
	if use python; then
		python_foreach_impl cmake-utils_src_install
		python_optimize
	else
		cmake-utils_src_install
	fi
}

src_test() {
	# perhaps disable tests (see #390447)
	vigra_test() {
		PYTHONPATH="${BUILD_DIR}/vigranumpy/vigra" cmake-utils_src_test
	}
	if use python; then
		python_foreach_impl vigra_test
	else
		vigra_test
	fi
}