[gentoo-commits] gentoo-x86 commit in sys-fs/udisks: metadata.xml ChangeLog udisks-1.96.0.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/05/01 16:49:07

  Modified:             metadata.xml ChangeLog
  Added:                udisks-1.96.0.ebuild
  Log:
  Version bump. Optionalize sys-apps/gptfdisk wrt #412801, Comment #1 since it might not work for every arch.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  sys-fs/udisks/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/udisks/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	27 Mar 2012 18:23:26 -0000	1.3
+++ metadata.xml	1 May 2012 16:49:07 -0000	1.4
@@ -6,7 +6,9 @@
     <email>freedesktop-bugs@g.o</email>
   </maintainer>
   <use>
-  	<flag name='remote-access'>Control whether connections from other clients over LAN are allowed</flag>
-	<flag name='introspection'>Use <pkg>dev-libs/gobject-introspection</pkg> for introspection</flag>
+    <flag name='gptfdisk'>Pull in <pkg>sys-apps/gptfdisk</pkg> for sgdisk command as used by partitioning functionality</flag>
+    <flag name='introspection'>Use <pkg>dev-libs/gobject-introspection</pkg> for introspection</flag>
+    <flag name='remote-access'>Control whether connections from other clients over LAN are allowed</flag>
+    <flag name='systemd'>Support <pkg>sys-apps/systemd</pkg>'s logind</flag>
   </use>
 </pkgmetadata>



1.74                 sys-fs/udisks/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/ChangeLog?r1=1.73&r2=1.74

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog	20 Apr 2012 18:49:12 -0000	1.73
+++ ChangeLog	1 May 2012 16:49:07 -0000	1.74
@@ -1,6 +1,13 @@
 # ChangeLog for sys-fs/udisks
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v 1.73 2012/04/20 18:49:12 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/ChangeLog,v 1.74 2012/05/01 16:49:07 ssuominen Exp $
+
+*udisks-1.96.0 (01 May 2012)
+
+  01 May 2012; Samuli Suominen <ssuominen@g.o> +udisks-1.96.0.ebuild,
+  metadata.xml:
+  Version bump. Optionalize sys-apps/gptfdisk wrt #412801, Comment #1 since it
+  might not work for every arch.
 
   20 Apr 2012; Samuli Suominen <ssuominen@g.o> -udisks-1.93.0.ebuild:
   old



1.1                  sys-fs/udisks/udisks-1.96.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/udisks-1.96.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/udisks/udisks-1.96.0.ebuild?rev=1.1&content-type=text/plain

Index: udisks-1.96.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/udisks/udisks-1.96.0.ebuild,v 1.1 2012/05/01 16:49:07 ssuominen Exp $

EAPI=4
inherit eutils bash-completion-r1 linux-info systemd

DESCRIPTION="Daemon providing interfaces to work with storage devices"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/udisks"
SRC_URI="http://udisks.freedesktop.org/releases/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="debug doc crypt +gptfdisk +introspection systemd"

COMMON_DEPEND=">=dev-libs/glib-2.32
	>=sys-auth/polkit-0.104-r1
	>=dev-libs/libatasmart-0.18
	|| ( >=sys-fs/udev-171-r5[gudev] <sys-fs/udev-171[extras] )
	virtual/acl
	introspection? ( >=dev-libs/gobject-introspection-1.30 )
	systemd? ( >=sys-apps/systemd-44 )"
# gptfdisk -> src/udiskslinuxpartition.c -> sgdisk (see also #412801#c1)
# util-linux -> mount, umount, swapon, swapoff
RDEPEND="${COMMON_DEPEND}
	>=sys-apps/util-linux-2.20.1-r2
	>=sys-block/parted-3
	virtual/eject
	crypt? ( sys-fs/cryptsetup )
	gptfdisk? ( >=sys-apps/gptfdisk-0.8 )"
DEPEND="${COMMON_DEPEND}
	app-text/docbook-xsl-stylesheets
	dev-libs/libxslt
	>=dev-util/gdbus-codegen-2.32
	dev-util/intltool
	dev-util/pkgconfig
	doc? (
		dev-util/gtk-doc
		app-text/docbook-xml-dtd:4.1.2
		)"

DOCS="AUTHORS HACKING NEWS README"

pkg_setup() {
	# Listing only major arch's here to avoid tracking kernel's defconfig
	if use amd64 || use arm || use ppc || use ppc64 || use x86; then
		CONFIG_CHECK="~!IDE" #319829
		CONFIG_CHECK+=" ~TMPFS_POSIX_ACL" #412377
		CONFIG_CHECK+=" ~USB_SUSPEND" #331065
		linux-info_pkg_setup
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.x-ntfs-3g.patch

	if ! use systemd; then
		sed -i -e 's:libsystemd-login:&sSuOmInEnWaShErE:' configure || die
	fi
}

src_configure() {
	econf \
		--localstatedir="${EPREFIX}"/var \
		--disable-static \
		$(use_enable debug) \
		$(use_enable doc gtk-doc) \
		$(use_enable introspection) \
		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
		"$(systemd_with_unitdir)"
}

src_install() {
	default

	local htmldir=udisks2
	if [[ -d ${ED}/usr/share/doc/${PF}/html/${htmldir} ]]; then
		dosym /usr/share/doc/${PF}/html/${htmldir} /usr/share/gtk-doc/html/${htmldir}
	fi

	rm -rf "${ED}"/etc/bash_completion.d
	dobashcomp tools/udisksctl-bash-completion.sh

	find "${ED}" -type f -name '*.la' -exec rm -f {} +

	keepdir /media
	keepdir /var/lib/udisks2 #383091
}