[gentoo-commits] gentoo-x86 commit in games-util/pyfa: ChangeLog pyfa-1.2.0.ebuild pyfa-9999.ebuild pyfa-1.1.21.ebuild pyfa-1.1.22.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    14/06/04 13:56:31

  Modified:             ChangeLog pyfa-9999.ebuild
  Added:                pyfa-1.2.0.ebuild
  Removed:              pyfa-1.1.21.ebuild pyfa-1.1.22.ebuild
  Log:
  Version bump for Kronos; lots of improvements, see https://github.com/DarkFenX/Pyfa/releases/tag/v1.2.0 for the announcement. Remove obsolete.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

Revision  Changes    Path
1.28                 games-util/pyfa/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	17 Mar 2014 01:08:46 -0000	1.27
+++ ChangeLog	4 Jun 2014 13:56:31 -0000	1.28
@@ -1,6 +1,14 @@
 # ChangeLog for games-util/pyfa
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v 1.27 2014/03/17 01:08:46 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v 1.28 2014/06/04 13:56:31 tetromino Exp $
+
+*pyfa-1.2.0 (04 Jun 2014)
+
+  04 Jun 2014; Alexandre Rostovtsev <tetromino@g.o> -pyfa-1.1.21.ebuild,
+  -pyfa-1.1.22.ebuild, +pyfa-1.2.0.ebuild, pyfa-9999.ebuild:
+  Version bump for Kronos; lots of improvements, see
+  https://github.com/DarkFenX/Pyfa/releases/tag/v1.2.0 for the announcement.
+  Remove obsolete.
 
 *pyfa-1.1.22 (17 Mar 2014)
 



1.3                  games-util/pyfa/pyfa-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-9999.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-9999.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-9999.ebuild?r1=1.2&r2=1.3

Index: pyfa-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-util/pyfa/pyfa-9999.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- pyfa-9999.ebuild	5 Feb 2014 06:17:45 -0000	1.2
+++ pyfa-9999.ebuild	4 Jun 2014 13:56:31 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/pyfa-9999.ebuild,v 1.2 2014/02/05 06:17:45 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/pyfa-9999.ebuild,v 1.3 2014/06/04 13:56:31 tetromino Exp $
 
 EAPI="5"
 PYTHON_COMPAT=( python{2_6,2_7} )
@@ -18,7 +18,7 @@
 	inherit git-2
 	KEYWORDS=""
 else
-	SRC_URI="https://github.com/DarkFenX/Pyfa/releases/download/v${PV}/${P}-rubicon-1.1-src.zip"
+	SRC_URI="https://github.com/DarkFenX/Pyfa/releases/download/v${PV}/${P}-kronos-1.0-src.zip"
 	KEYWORDS="~amd64 ~arm ~x86"
 fi
 IUSE="+graph"



1.1                  games-util/pyfa/pyfa-1.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-1.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-1.2.0.ebuild?rev=1.1&content-type=text/plain

Index: pyfa-1.2.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/pyfa-1.2.0.ebuild,v 1.1 2014/06/04 13:56:31 tetromino Exp $

EAPI="5"
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="sqlite,threads"

inherit eutils gnome2-utils python-r1

DESCRIPTION="Python Fitting Assistant - a ship fitting application for EVE Online"
HOMEPAGE="https://github.com/DarkFenX/Pyfa"

LICENSE="GPL-3+ LGPL-2.1+ CC-BY-2.5 free-noncomm"
SLOT="0"
if [[ ${PV} = 9999 ]]; then
	EGIT_REPO_URI="https://github.com/DarkFenX/Pyfa.git"
	inherit git-2
	KEYWORDS=""
else
	SRC_URI="https://github.com/DarkFenX/Pyfa/releases/download/v${PV}/${P}-kronos-1.0-src.zip"
	KEYWORDS="~amd64 ~arm ~x86"
fi
IUSE="+graph"

RDEPEND="dev-python/sqlalchemy[${PYTHON_USEDEP}]
	dev-python/wxpython:2.8[${PYTHON_USEDEP}]
	graph? (
		dev-python/matplotlib[wxwidgets,${PYTHON_USEDEP}]
		dev-python/numpy[${PYTHON_USEDEP}] )
	${PYTHON_DEPS}"
DEPEND="app-arch/unzip"

S=${WORKDIR}/${PN}

src_prepare() {
	# get rid of CRLF line endings introduced in 1.1.10 so patches work
	edos2unix config.py pyfa.py service/settings.py

	# make staticPath settable from configforced again
	epatch "${FILESDIR}/${PN}-1.1.20-staticPath.patch"

	# do not try to save exported html to python sitedir
	epatch "${FILESDIR}/${PN}-1.1.8-html-export-path.patch"

	# fix import path in the main script for systemwide installation
	epatch "${FILESDIR}/${PN}-1.1.11-import-pyfa.patch"
	touch __init__.py

	pyfa_make_configforced() {
		mkdir -p "${BUILD_DIR}" || die
		sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
			-e "s:%%EPREFIX%%:${EPREFIX}:" \
			"${FILESDIR}/configforced.py" > "${BUILD_DIR}/configforced.py"
		sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
			pyfa.py > "${BUILD_DIR}/pyfa"
	}
	python_foreach_impl pyfa_make_configforced
}

src_install() {
	pyfa_py_install() {
		local packagedir=$(python_get_sitedir)/${PN}
		insinto "${packagedir}"
		doins -r eos gui icons service config*.py __init__.py gpl.txt
		[[ -e info.py ]] && doins info.py # only in zip releases
		doins "${BUILD_DIR}/configforced.py"
		python_doscript "${BUILD_DIR}/pyfa"
		python_optimize
	}
	python_foreach_impl pyfa_py_install

	insinto /usr/share/${PN}
	doins -r staticdata
	dodoc readme.txt
	insinto /usr/share/icons/hicolor/32x32/apps
	doins icons/pyfa.png
	insinto /usr/share/icons/hicolor/64x64/apps
	newins icons/pyfa64.png pyfa.png
	domenu "${FILESDIR}/${PN}.desktop"
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}