[gentoo-commits] gentoo-x86 commit in net-misc/stunnel: stunnel-4.35.ebuild ChangeLog metadata.xml

[Lance Albertson (ramereth)]

ramereth    11/03/02 06:16:12

  Modified:             ChangeLog metadata.xml
  Added:                stunnel-4.35.ebuild
  Log:
  Version bump, resolves #344117
  
  (Portage version: 2.1.9.25/cvs/Linux x86_64)

Revision  Changes    Path
1.115                net-misc/stunnel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.115&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.115&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?r1=1.114&r2=1.115

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v
retrieving revision 1.114
retrieving revision 1.115
diff -u -r1.114 -r1.115
--- ChangeLog	7 Jul 2010 05:41:40 -0000	1.114
+++ ChangeLog	2 Mar 2011 06:16:12 -0000	1.115
@@ -1,6 +1,16 @@
 # ChangeLog for net-misc/stunnel
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.114 2010/07/07 05:41:40 ramereth Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.115 2011/03/02 06:16:12 ramereth Exp $
+
+*stunnel-4.35 (02 Mar 2011)
+
+  02 Mar 2011; Lance Albertson <ramereth@g.o>
+  +files/stunnel-4.34-listen-queue.diff, +stunnel-4.35.ebuild,
+  +files/stunnel-4.35-libwrap.patch,
+  +files/stunnel-4.35-xforwarded-for.diff, metadata.xml:
+  Version bump, resolves #344117
+
+  Thanks to Stefan Behte for contributing new patches/ebuild.
 
   07 Jul 2010; Lance Albertson <ramereth@g.o> stunnel-4.33.ebuild:
   Fix missing xforward patch, resolves bug #324997



1.5                  net-misc/stunnel/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/stunnel/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	7 Mar 2010 21:36:28 -0000	1.4
+++ metadata.xml	2 Mar 2011 06:16:12 -0000	1.5
@@ -15,5 +15,6 @@
 	</longdescription>
 	<use>
 		<flag name="xforward">Enable X-Forwarded-For support for Stunnel</flag>
+		<flag name="listen-queue">Enable Listen Queue support for Stunnel</flag>
 	</use>
 </pkgmetadata>



1.1                  net-misc/stunnel/stunnel-4.35.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/stunnel-4.35.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/stunnel-4.35.ebuild?rev=1.1&content-type=text/plain

Index: stunnel-4.35.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/stunnel-4.35.ebuild,v 1.1 2011/03/02 06:16:12 ramereth Exp $

EAPI="2"

inherit autotools ssl-cert eutils

DESCRIPTION="TLS/SSL - Port Wrapper"
HOMEPAGE="http://stunnel.mirt.net/"
SRC_URI="ftp://ftp.stunnel.org/stunnel/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="ipv6 selinux tcpd xforward listen-queue"

DEPEND="tcpd? ( sys-apps/tcp-wrappers )
	>=dev-libs/openssl-0.9.8k"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-stunnel )"

pkg_setup() {
	enewgroup stunnel
	enewuser stunnel -1 -1 -1 stunnel
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-4.35-libwrap.patch"
	use xforward && epatch "${FILESDIR}/stunnel-4.35-xforwarded-for.diff"
	use listen-queue && epatch "${FILESDIR}/stunnel-4.34-listen-queue.diff"
	eautoreconf

	# Hack away generation of certificate
	sed -i -e "s/^install-data-local:/do-not-run-this:/" \
		tools/Makefile.in || die "sed failed"
}

src_configure() {
	econf $(use_enable ipv6) \
		$(use_enable tcpd libwrap) || die "econf died"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	rm -rf "${D}"/usr/share/doc/${PN}
	rm -f "${D}"/etc/stunnel/stunnel.conf-sample "${D}"/usr/bin/stunnel3 \
		"${D}"/usr/share/man/man8/stunnel.{fr,pl}.8

	# The binary was moved to /usr/bin with 4.21,
	# symlink for backwards compatibility
	dosym ../bin/stunnel /usr/sbin/stunnel

	dodoc AUTHORS BUGS CREDITS PORTS README TODO ChangeLog
	dohtml doc/stunnel.html doc/en/VNC_StunnelHOWTO.html tools/ca.html \
		tools/importCA.html

	insinto /etc/stunnel
	doins "${FILESDIR}"/stunnel.conf
	newinitd "${FILESDIR}"/stunnel.initd stunnel

	keepdir /var/run/stunnel
	fowners stunnel:stunnel /var/run/stunnel
}

pkg_postinst() {
	if [ ! -f "${ROOT}"/etc/stunnel/stunnel.key ]; then
		install_cert /etc/stunnel/stunnel
		chown stunnel:stunnel "${ROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
		chmod 0640 "${ROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
	fi

	einfo "If you want to run multiple instances of stunnel, create a new config"
	einfo "file ending with .conf in /etc/stunnel/. **Make sure** you change "
	einfo "\'pid= \' with a unique filename."
}