[gentoo-commits] gentoo-x86 commit in dev-libs/xerces-c: ChangeLog xerces-c-3.0.1-r1.ebuild xerces-c-3.1.0.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    10/02/07 11:21:09

  Modified:             ChangeLog xerces-c-3.0.1-r1.ebuild
  Added:                xerces-c-3.1.0.ebuild
  Log:
  Added thread-test-disabling patch (thanks to Andreas Schürch, bug #280613). Version bump (which solves bug #277703 as well).
  (Portage version: 2.2_rc61/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.83                 dev-libs/xerces-c/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	27 Sep 2009 14:45:43 -0000	1.82
+++ ChangeLog	7 Feb 2010 11:21:08 -0000	1.83
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/xerces-c
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v 1.82 2009/09/27 14:45:43 nixnut Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v 1.83 2010/02/07 11:21:08 dev-zero Exp $
+
+*xerces-c-3.1.0 (07 Feb 2010)
+
+  07 Feb 2010; Tiziano Müller <dev-zero@g.o>
+  +files/3.0.1-disable-thread-tests.patch, xerces-c-3.0.1-r1.ebuild,
+  +xerces-c-3.1.0.ebuild:
+  Added thread-test-disabling patch (thanks to Andreas Schürch, bug
+  #280613). Version bump (which solves bug #277703 as well).
 
   27 Sep 2009; nixnut <nixnut@g.o> xerces-c-3.0.1-r1.ebuild:
   ppc stable #280613



1.5                  dev-libs/xerces-c/xerces-c-3.0.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.1-r1.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.1-r1.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.1-r1.ebuild?r1=1.4&r2=1.5

Index: xerces-c-3.0.1-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.1-r1.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- xerces-c-3.0.1-r1.ebuild	7 Dec 2009 18:20:31 -0000	1.4
+++ xerces-c-3.0.1-r1.ebuild	7 Feb 2010 11:21:08 -0000	1.5
@@ -1,6 +1,6 @@
-# Copyright 1999-2009 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.1-r1.ebuild,v 1.4 2009/12/07 18:20:31 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.1-r1.ebuild,v 1.5 2010/02/07 11:21:08 dev-zero Exp $
 
 EAPI="2"
 
@@ -12,9 +12,9 @@
 LICENSE="Apache-2.0"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 hppa ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="curl debug doc iconv icu libwww threads elibc_Darwin elibc_FreeBSD"
+IUSE="curl debug doc iconv icu libwww test threads elibc_Darwin elibc_FreeBSD"
 
-RDEPEND="icu? ( dev-libs/icu )
+RDEPEND="icu? ( >=dev-libs/icu-4.2 )
 	curl? ( net-misc/curl )
 	libwww? ( net-libs/libwww )
 	virtual/libiconv"
@@ -35,8 +35,16 @@
 		-e 's|$(prefix)/msg|$(DESTDIR)/$(prefix)/share/xerces-c/msg|' \
 		src/xercesc/util/MsgLoaders/MsgCatalog/Makefile.in || die "sed failed"
 
-	epatch "${FILESDIR}/${P}-CVE-2009-2625.patch"
-	epatch "${FILESDIR}/${P}-libicu.patch"
+	epatch \
+		"${FILESDIR}/${P}-CVE-2009-2625.patch" \
+		"${FILESDIR}/${P}-libicu.patch"
+
+	if use test && ! use threads ; then
+		epatch "${FILESDIR}/${PV}-disable-thread-tests.patch"
+		sed -i \
+			-e 's|ThreadTest$(EXEEXT) XSerializerTest$(EXEEXT)|XSerializerTest$(EXEEXT)|g' \
+			tests/Makefile.in || die "sed failed"
+	fi
 }
 
 src_configure() {



1.1                  dev-libs/xerces-c/xerces-c-3.1.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-3.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-3.1.0.ebuild?rev=1.1&content-type=text/plain

Index: xerces-c-3.1.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-3.1.0.ebuild,v 1.1 2010/02/07 11:21:08 dev-zero Exp $

EAPI="2"

inherit eutils

DESCRIPTION="A validating XML parser written in a portable subset of C++."
HOMEPAGE="http://xerces.apache.org/xerces-c/"
SRC_URI="mirror://apache/xerces/c/3/sources/${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="curl doc iconv icu libwww sse2 static-libs threads elibc_Darwin elibc_FreeBSD"

RDEPEND="icu? ( >=dev-libs/icu-4.2 )
	curl? ( net-misc/curl )
	libwww? ( net-libs/libwww )
	virtual/libiconv"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

pkg_setup() {
	export ICUROOT="/usr"

	if use iconv && use icu ; then
		ewarn "This package can use iconv or icu for loading messages"
		ewarn "and transcoding, but not both. ICU will precede."
	fi
}

src_prepare() {
	sed -i \
		-e 's|$(prefix)/msg|$(DESTDIR)/$(prefix)/share/xerces-c/msg|' \
		src/xercesc/util/MsgLoaders/MsgCatalog/Makefile.in || die "sed failed"
}

src_configure() {
	local mloader="inmemory"
	use iconv && mloader="iconv"
	use icu && mloader="icu"

	local transcoder="gnuiconv"
	use elibc_FreeBSD && transcoder="iconv"
	use elibc_Darwin && transcoder="macosunicodeconverter"
	use icu && transcoder="icu"
	# for interix maybe: transcoder="windows"

	# 'cfurl' is only available on OSX and 'socket' isn't supposed to work.
	# But the docs aren't clear about it, so we would need some testing...
	local netaccessor="socket"
	use elibc_Darwin && netaccessor="cfurl"
	use libwww && netaccessor="libwww"
	use curl && netaccessor="curl"

	econf \
		--disable-pretty-make \
		$(use_enable static-libs static) \
		$(use_enable threads) \
		--enable-msgloader-${mloader} \
		--enable-netaccessor-${netaccessor} \
		--enable-transcoder-${transcoder} \
		$(use_enable sse2)
}

src_compile() {
	default

	if use doc ; then
		cd "${S}/doc"
		doxygen || die "making docs failed"
	fi
}

src_install () {
	emake DESTDIR="${D}" install || die "emake failed"

	use static-libs || rm "${D}"/lib*/*.la

	# To make sure an appropriate NLS msg file is around when using the iconv msgloader
	# ICU has the messages compiled in.
	if use iconv && ! use icu ; then
		doenvd "${FILESDIR}/50xerces-c"
	fi

	if use doc; then
		insinto /usr/share/doc/${PF}
		rm -rf samples/Makefile* samples/runConfigure samples/src/*/Makefile* samples/.libs
		doins -r samples
		dohtml -r doc/html/*
	fi

	dodoc CREDITS KEYS NOTICE README version.incl
}