[gentoo-commits] gentoo-x86 commit in kde-base/krossruby: krossruby-4.12.2.ebuild ChangeLog

[Andreas HAttel (dilfridge)]

dilfridge    14/02/06 23:20:25

  Modified:             ChangeLog
  Added:                krossruby-4.12.2.ebuild
  Log:
  Version bump KDE SC 4.12.2
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key EBE6A336BE19039C!)

Revision  Changes    Path
1.156                kde-base/krossruby/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/krossruby/ChangeLog?rev=1.156&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/krossruby/ChangeLog?rev=1.156&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/krossruby/ChangeLog?r1=1.155&r2=1.156

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/krossruby/ChangeLog,v
retrieving revision 1.155
retrieving revision 1.156
diff -u -r1.155 -r1.156
--- ChangeLog	20 Jan 2014 14:59:41 -0000	1.155
+++ ChangeLog	6 Feb 2014 23:20:25 -0000	1.156
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/krossruby
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/krossruby/ChangeLog,v 1.155 2014/01/20 14:59:41 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/krossruby/ChangeLog,v 1.156 2014/02/06 23:20:25 dilfridge Exp $
+
+*krossruby-4.12.2 (06 Feb 2014)
+
+  06 Feb 2014; Andreas K. Huettel <dilfridge@g.o>
+  +krossruby-4.12.2.ebuild:
+  Version bump KDE SC 4.12.2
 
   20 Jan 2014; Michael Palimaka <kensington@g.o>
   -krossruby-4.12.0.ebuild:



1.1                  kde-base/krossruby/krossruby-4.12.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/krossruby/krossruby-4.12.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/krossruby/krossruby-4.12.2.ebuild?rev=1.1&content-type=text/plain

Index: krossruby-4.12.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/krossruby/krossruby-4.12.2.ebuild,v 1.1 2014/02/06 23:20:25 dilfridge Exp $

EAPI=5

KMNAME="kross-interpreters"
KMMODULE="ruby"

USE_RUBY="ruby19"
# Only one ruby version is supported:
# 1) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
# 2) the ebuild can only be installed for one ruby variant, otherwise the compiled
#    files with identical path+name will overwrite each other - difficult :(

inherit kde4-meta ruby-ng

DESCRIPTION="Kross scripting framework: Ruby interpreter"
KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug"

DEPEND=""
RDEPEND=""

pkg_setup() {
	ruby-ng_pkg_setup
	kde4-meta_pkg_setup
}

src_unpack() {
	local S="${WORKDIR}/${P}"
	kde4-meta_src_unpack

	cd "${WORKDIR}"
	mkdir all
	mv ${P} all/ || die "Could not move sources"
}

all_ruby_prepare() {
	kde4-meta_src_prepare
}

each_ruby_configure() {
	local CMAKE_USE_DIR=${S}
	local mycmakeargs=(
		-DRUBY_LIBRARY=$(ruby_get_libruby)
		-DRUBY_INCLUDE_DIR=$(ruby_get_hdrdir)
		-DRUBY_EXECUTABLE=${RUBY}
	)
	kde4-meta_src_configure
}

each_ruby_compile() {
	local CMAKE_USE_DIR=${S}
	kde4-meta_src_compile
}

each_ruby_install() {
	local CMAKE_USE_DIR=${S}
	kde4-meta_src_install
}