[gentoo-commits] repo/gentoo:master commit in: dev-ruby/bcat/

[Hans de Graaff]

commit:     9944fd678900ad16b7522ffa8d5f646563ab4207
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 25 07:23:10 2018 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Sun Mar 25 07:23:10 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9944fd67

fidev-ruby/bcat: x dev-ruby/rack dependency

Closes: https://bugs.gentoo.org/651110
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 dev-ruby/bcat/bcat-0.6.2-r3.ebuild | 43 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/dev-ruby/bcat/bcat-0.6.2-r3.ebuild b/dev-ruby/bcat/bcat-0.6.2-r3.ebuild
new file mode 100644
index 00000000000..7cb16e2a1ed
--- /dev/null
+++ b/dev-ruby/bcat/bcat-0.6.2-r3.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+USE_RUBY="ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_TASK_DOC="man"
+RUBY_FAKEGEM_EXTRADOC="README"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Pipe to browser utility for use at the shell and within editors"
+HOMEPAGE="https://github.com/rtomayko/bcat"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+# Collides on /usr/bin/bcat, bug 418301
+RDEPEND="${RDEPEND} !!<app-accessibility/speech-tools-2.1-r3"
+
+ruby_add_bdepend "doc? ( app-text/ronn )
+	test? ( dev-ruby/test-unit:2 )"
+
+ruby_add_rdepend "=dev-ruby/rack-1*:*"
+
+each_ruby_prepare() {
+	sed -i -e "s/a2h/#{ENV['RUBY']} -S a2h/" test/test_bcat_a2h.rb || die
+}
+
+each_ruby_test() {
+	# The Rakefile uses weird trickery with load path that causes gems
+	# not to be found. Run tests directly instead and do the trickery
+	# here to support popen calls for the bins in this package.
+	RUBY=${RUBY} RUBYLIB=lib:${RUBYLIB} PATH=bin:${PATH} ${RUBY} -S testrb-2 test/test_*.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	doman man/*.1
+}