[gentoo-commits] gentoo-x86 commit in x11-wm/sawfish: metadata.xml ChangeLog sawfish-1.9.1-r2.ebuild

[Ulrich Mueller (ulm)]

ulm         14/02/10 21:46:34

  Modified:             metadata.xml ChangeLog
  Added:                sawfish-1.9.1-r2.ebuild
  Log:
  Install sawfish mode for Emacs, controlled by USE=emacs, bug 493114.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

Revision  Changes    Path
1.8                  x11-wm/sawfish/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/sawfish/metadata.xml?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/sawfish/metadata.xml?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/sawfish/metadata.xml?r1=1.7&r2=1.8

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/sawfish/metadata.xml,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- metadata.xml	9 Feb 2014 10:41:37 -0000	1.7
+++ metadata.xml	10 Feb 2014 21:46:34 -0000	1.8
@@ -1,5 +1,13 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<maintainer><email>maintainer-needed@g.o</email></maintainer>
+<maintainer>
+  <email>maintainer-needed@g.o</email>
+  <description>This package lacks a primary herd or maintainer.</description>
+</maintainer>
+<maintainer>
+  <email>emacs@g.o</email>
+  <description>Components installed with USE=emacs.
+    Do not assign for anything else.</description>
+</maintainer>
 </pkgmetadata>



1.129                x11-wm/sawfish/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/sawfish/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/sawfish/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/sawfish/ChangeLog?r1=1.128&r2=1.129

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/sawfish/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog	9 Feb 2014 10:41:37 -0000	1.128
+++ ChangeLog	10 Feb 2014 21:46:34 -0000	1.129
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/sawfish
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/sawfish/ChangeLog,v 1.128 2014/02/09 10:41:37 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/sawfish/ChangeLog,v 1.129 2014/02/10 21:46:34 ulm Exp $
+
+*sawfish-1.9.1-r2 (10 Feb 2014)
+
+  10 Feb 2014; Ulrich Müller <ulm@g.o> +sawfish-1.9.1-r2.ebuild,
+  +files/50sawfish-gentoo.el, metadata.xml:
+  Install sawfish mode for Emacs, controlled by USE=emacs, bug 493114.
 
   09 Feb 2014; Pacho Ramos <pacho@g.o> -files/libtool.patch,
   -files/sawfish-1.3.3-cflags.patch, -files/sawfish-1.3.3-parallel-make.patch,



1.1                  x11-wm/sawfish/sawfish-1.9.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/sawfish/sawfish-1.9.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/sawfish/sawfish-1.9.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: sawfish-1.9.1-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/sawfish/sawfish-1.9.1-r2.ebuild,v 1.1 2014/02/10 21:46:34 ulm Exp $

EAPI=5
inherit eutils elisp-common

DESCRIPTION="Extensible window manager using a Lisp-based scripting language"
HOMEPAGE="http://sawfish.wikia.com/"
SRC_URI="http://download.tuxfamily.org/sawfish/${P}.tar.xz"

LICENSE="GPL-2 Artistic-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="emacs nls xinerama"

RDEPEND="emacs? ( !app-emacs/sawfish )
	>=dev-libs/librep-0.92.1
	>=x11-libs/rep-gtk-0.90.7
	|| ( x11-libs/pangox-compat <x11-libs/pango-1.31[X] )
	>=x11-libs/gtk+-2.24.0:2
	x11-libs/libXtst
	nls? ( sys-devel/gettext )
	xinerama? ( x11-libs/libXinerama )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	virtual/pkgconfig"

src_prepare() {
	# Fix firefox resizing problems, bug #462016
	epatch "${FILESDIR}/${P}-firefox.patch"
}

src_configure() {
	set -- \
		$(use_with xinerama) \
		--with-gdk-pixbuf \
		--disable-static

	if ! use nls; then
		# Use a space because configure script reads --enable-linguas="" as
		# "install everything"
		# Don't use --disable-linguas, because that means --enable-linguas="no",
		# which means "install Norwegian translations"
		set -- "$@" --enable-linguas=" "
	elif [[ "${LINGUAS+set}" == "set" ]]; then
		strip-linguas -i po
		set -- "$@" --enable-linguas=" ${LINGUAS} "
	else
		set -- "$@" --enable-linguas=""
	fi

	econf "$@"
}

src_compile() {
	emake
	use emacs && elisp-compile sawfish.el
}

src_install() {
	emake DESTDIR="${D}" install
	prune_libtool_files --modules
	dodoc AUTHORS ChangeLog DOC FAQ NEWS OPTIONS README README.IMPORTANT TODO

	if use emacs; then
		elisp-install ${PN} sawfish.{el,elc}
		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}